HelpSource/Classes/Warp1.schelp

   1 class:: Warp1
   2 summary:: Warp a buffer with a time pointer
   3 categories:: UGens>Buffer, UGens>Generators>Granular
   4
   5 description::
   6 Inspired by Chad Kirby's SuperCollider2 Warp1 class, which was inspired by Richard Karpen's sndwarp for CSound. A granular time strecher and pitchshifter.
   7
   8 classmethods::
   9 private:: categories
  10
  11 method:: ar
  12 argument::numChannels
  13 the number of channels in the soundfile used in bufnum.
  14
  15 argument::bufnum
  16 the buffer number of a mono soundfile.
  17
  18 argument::pointer
  19 the position in the buffer.  The value should be between 0 and 1, with 0 being the begining
  20 of the buffer, and 1 the end.
  21
  22 argument::freqScale
  23 the amount of frequency shift. 1.0 is normal, 0.5 is one octave down, 2.0 is one octave up.
  24 Negative values play the soundfile backwards.
  25
  26 argument::windowSize
  27 the size of each grain window.
  28
  29 argument::envbufnum
  30 the buffer number containing a singal to use for the grain envelope. -1 uses a built-in
  31 Hanning envelope.
  32
  33 argument::overlaps
  34 the number of overlaping windows.
  35
  36 argument::windowRandRatio
  37 the amount of randomness to the windowing function.  Must be between 0 (no
  38 randomness) to 1.0 (probably to random actually)
  39
  40 argument::interp
  41 the interpolation method used for pitchshifting grains. 1 = no interpolation. 2 = linear.
  42                 4 = cubic interpolation (more computationally intensive).
  43
  44 Examples::
  45 code::
  46 s.boot;
  47
  48 (
  49 var winenv;
  50 // a custom envelope - not a very good one, but you can hear the difference between this
  51 // and the default
  52 winenv = Env([0, 1, 0], [0.5, 0.5], [8, -8]);
  53 b = Buffer.read(s, Help.dir +/+ "sounds/a11wlk01-44_1.aiff");
  54 z = Buffer.sendCollection(s, winenv.discretize, 1);
  55
  56 SynthDef(\warp, {arg buffer = 0, envbuf = -1;
  57         var out, pointer, filelength, pitch, env, dir;
  58         // pointer - move from beginning to end of soundfile over 15 seconds
  59         pointer = Line.kr(0, 1, 15);
  60         // control pitch with MouseX
  61         pitch = MouseX.kr(0.5, 2);
  62         env = EnvGen.kr(Env([0.001, 1, 1, 0.001], [0.1, 14, 0.9], 'exp'), doneAction: 2);
  63         out = Warp1.ar(1, buffer, pointer, pitch, 0.1, envbuf, 8, 0.1, 2);
  64         Out.ar(0, out * env);
  65 }).send(s);
  66
  67 )
  68
  69 // use built-in env
  70 x = Synth(\warp, [\buffer, b, \envbuf, -1])
  71
  72 // switch to the custom env
  73 x.set(\envbuf, z)
  74 x.set(\envbuf, -1);
  75
  76 x.free;
  77 ::
  78