HelpSource/Classes/FreeVerb.schelp

   1 class:: FreeVerb
   2 summary:: A reverb
   3 categories:: UGens>Reverbs
   4 related:: Classes/FreeVerb2, Classes/GVerb
   5
   6 description::
   7 Coded from experiments with faust.
   8
   9 classmethods::
  10
  11 method:: ar
  12 argument:: in
  13 input signal.
  14 argument:: mix
  15 dry/wet balance. range 0..1.
  16 argument:: room
  17 room size. rage 0..1.
  18 argument:: damp
  19 Reverb HF damp. range 0..1.
  20 argument:: mul
  21 argument:: add
  22
  23 discussion::
  24 Valid parameter range from 0 to 1. Values outside this range are clipped by the UGen.
  25
  26 examples::
  27 code::
  28 Server.default = s = Server.internal;
  29 s.boot;
  30
  31 // FreeVerb - 1x1 ugen
  32 (
  33 z = SynthDef(\src, {|mix = 0.25, room = 0.15, damp = 0.5|
  34         Out.ar(0,
  35                 FreeVerb.ar(
  36                         Decay.ar(Impulse.ar(1), 0.25, LFCub.ar(1200, 0, 0.1)), // mono src
  37                         mix, // mix 0-1
  38                         room, // room 0-1
  39                         damp // damp 0-1 duh
  40                 ) ! 2 // fan out...
  41         );
  42 }).play
  43 )
  44 z.set(\room, 0.7)
  45 z.set(\mix, 0.4)
  46 z.set(\damp, 0.2)
  47
  48 z.free
  49
  50 // it expands as any ugen does
  51 (
  52 z = SynthDef(\src, {|mix = 0.25, room = 0.15, damp = 0.5|
  53         Out.ar(0,
  54                 FreeVerb.ar(
  55                         Pan2.ar(
  56                                 Decay.ar(Impulse.ar(1), 0.25, LFCub.ar(1200, 0, 0.1)),
  57                                 LFNoise1.ar(1).range(-1, 1)
  58                         ),
  59                         mix,
  60                         room,
  61                         damp
  62                 )
  63         );
  64 }).play
  65 )
  66 z.set(\room, 0.7)
  67 z.set(\mix, 0.4)
  68 z.set(\damp, 0.2)
  69
  70 z.free
  71 ::