SCClassLibrary/Common/Audio/Splay.sc

   1 Splay : UGen {
   2
   3         *new1 { arg rate, spread = 1, level = 1, center = 0.0, levelComp = true ... inArray;
   4
   5                 var n = max(2, inArray.size);
   6                 var n1 = n - 1;
   7                 var positions = ((0 .. n1) * (2 / n1) - 1) * spread + center;
   8
   9                 if (levelComp) {
  10                         if(rate == \audio) {
  11                                 level = level * n.reciprocal.sqrt
  12                         } {
  13                                 level = level / n
  14                         }
  15                  };
  16
  17                 ^Pan2.perform(this.methodSelectorForRate(rate), inArray, positions).sum * level;
  18         }
  19
  20         *kr { arg inArray, spread = 1, level = 1, center = 0.0, levelComp = true;
  21                 ^this.multiNewList([\control, spread, level, center, levelComp] ++ inArray)
  22
  23         }
  24
  25         *ar { arg inArray, spread = 1, level = 1, center = 0.0, levelComp = true;
  26                 ^this.multiNewList([\audio, spread, level, center, levelComp] ++ inArray)
  27         }
  28
  29         /*
  30
  31         *ar { arg inArray, spread = 1, level = 1, center = 0.0, levelComp = true;
  32
  33                 var n = inArray.size.max(2);
  34                 var n1 = n-1;
  35
  36                 if (levelComp) { level = level * n.reciprocal.sqrt };
  37
  38                 ^Pan2.ar(
  39                         inArray,
  40                         ((0 .. n1) * (2 / n1) - 1) * spread + center
  41                 ).sum * level;
  42         }
  43
  44         */
  45
  46         *arFill { arg n, function, spread = 1, level = 1, center = 0.0, levelComp = true;
  47                 ^this.ar((function ! n), spread, level, center, levelComp)
  48         }
  49 }
  50
  51
  52
  53 SplayAz : UGen {
  54         *kr { arg numChans = 4, inArray, spread = 1, level = 1, width = 2, center = 0.0,
  55                         orientation = 0.5, levelComp = true;
  56
  57                 var n = max(1, inArray.size);
  58
  59                 var pos = [ center - spread, center + spread ].resamp1(n);
  60
  61                 if (levelComp) {
  62                         level = level / n
  63                 };
  64
  65                 ^(PanAz.kr(numChans, inArray, pos, level, width, orientation).flop.collect(_.sum))
  66         }
  67
  68         *ar { arg numChans = 4, inArray, spread = 1, level = 1, width = 2, center = 0.0,
  69                         orientation = 0.5, levelComp = true;
  70
  71                 var n = max(1, inArray.size);
  72
  73                 var pos = [ center - spread, center + spread ].resamp1(n);
  74
  75                 if (levelComp) {
  76                         level = level * n.reciprocal.sqrt
  77                 };
  78
  79                 ^(PanAz.ar(numChans, inArray, pos, level, width, orientation).flop.collect(_.sum))
  80         }
  81
  82         *arFill { arg numChans = 4, n, function, spread = 1, level = 1, width = 2, center = 0.0,
  83                 orientation = 0.5, levelComp = true;
  84                 ^this.ar(numChans, function ! n, spread, level, width, center,
  85                         orientation, levelComp)
  86         }
  87 }
  88
  89
  90
  91 SplayZ {
  92         *ar { arg numChans = 4, inArray, spread = 1, level = 1, width = 2, center = 0.0,
  93                         orientation = 0.5, levelComp = true;
  94
  95                 var n = inArray.size.max(2);
  96                 var n1 = n - 1;
  97
  98                 if (levelComp) { level = level * n.reciprocal.sqrt };
  99
 100                 "SplayZ is deprecated, because its geometry is wrong.
 101                 Please convert to SplayAz.".inform;
 102
 103                 ^PanAz.ar(
 104                         numChans,
 105                         inArray,
 106                         ((0 .. n1) * (2 / n1) - 1) * spread + center,
 107                         1,
 108                         width,
 109                         orientation
 110                 ).sum * level;
 111         }
 112
 113         *arFill { arg numChans = 4, n, function, spread = 1, level = 1, width = 2, center = 0.0,
 114                 orientation = 0.5, levelComp = true;
 115                 ^this.ar(numChans, function ! n, spread, level, width, center,
 116                 orientation, levelComp)
 117         }
 118 }