HelpSource/Classes/TGrains.schelp

   1 class:: TGrains
   2 summary:: Buffer granulator.
   3 categories::  UGens>Buffer, UGens>Generators>Granular
   4
   5 Description::
   6 Triggers generate grains from a buffer. Each grain has a Hanning envelope
   7 code::
   8 (sin2(x) for x from 0 to π)
   9 ::
  10 and is panned between two channels of multiple outputs.
  11
  12 classmethods::
  13
  14 method::ar
  15
  16 argument::numChannels
  17 Number of output channels.
  18
  19 argument::trigger
  20 At each trigger, the following arguments are sampled and used as
  21 the arguments of a new grain. A trigger occurs when a signal
  22 changes from non-positive to positive value.
  23
  24 If the trigger is audio rate then the grains will start with
  25 sample accuracy.
  26
  27 argument::bufnum
  28 The index of the buffer to use. It must be a one channel (mono)
  29 buffer.
  30
  31 argument::rate
  32 1.0 is normal, 2.0 is one octave up, 0.5 is one octave down -1.0
  33 is backwards normal rate… etc.
  34
  35 argument::centerPos
  36 The position in the buffer in seconds at which the grain envelope
  37 will reach maximum amplitude.
  38
  39 argument::dur
  40 Duration of the grain in seconds.
  41
  42 argument::pan
  43 A value from -1 to 1. Determines where to pan the output in the
  44 same manner as
  45 link::Classes/PanAz:: .
  46
  47 argument::amp
  48 Amplitude of the grain.
  49
  50 argument::interp
  51 1, 2, or 4. Determines whether the grain uses (1) no
  52 interpolation, (2) linear interpolation, or (4) cubic
  53 interpolation.
  54
  55
  56 Examples::
  57
  58 code::
  59 (
  60 s = Server.internal;
  61 Server.default = s;
  62 s.boot;
  63 )
  64
  65
  66 b = Buffer.read(s, Platform.resourceDir +/+ "sounds/a11wlk01.wav");
  67
  68 (
  69 {
  70         var trate, dur, rate;
  71         trate = MouseY.kr(2,200,1);
  72         dur = 4 / trate;
  73         rate = Dseq([10, 1, 1, 0.5, 0.5, 0.2, 0.1], inf);
  74         TGrains.ar(2, Impulse.ar(trate), b, rate, MouseX.kr(0,BufDur.kr(b)), dur, Dseq([-1, 1], inf), 0.1, 2);
  75 }.scope(zoom: 4);
  76 )
  77
  78 (
  79 {
  80         var trate, dur, clk, pos, pan;
  81         trate = MouseY.kr(8,120,1);
  82         dur = 12 / trate;
  83         clk = Impulse.kr(trate);
  84         pos = MouseX.kr(0,BufDur.kr(b)) + TRand.kr(0, 0.01, clk);
  85         pan = WhiteNoise.kr(0.6);
  86         TGrains.ar(2, clk, b, 1, pos, dur, pan, 0.1);
  87 }.scope(zoom: 4);
  88 )
  89
  90 // 4 channels
  91 (
  92 {
  93         var trate, dur, clk, pos, pan;
  94         trate = MouseY.kr(8,120,1);
  95         dur = 12 / trate;
  96         clk = Impulse.kr(trate);
  97         pos = MouseX.kr(0,BufDur.kr(b)) + TRand.kr(0, 0.01, clk);
  98         pan = WhiteNoise.kr(0.6);
  99         TGrains.ar(4, clk, b, 1, pos, dur, pan, 0.1);
 100 }.scope(4, zoom: 4);
 101 )
 102
 103 (
 104 {
 105         var trate, dur, clk, pos, pan;
 106         trate = MouseY.kr(8,120,1);
 107         dur = 4 / trate;
 108         clk = Dust.kr(trate);
 109         pos = MouseX.kr(0,BufDur.kr(b)) + TRand.kr(0, 0.01, clk);
 110         pan = WhiteNoise.kr(0.6);
 111         TGrains.ar(2, clk, b, 1, pos, dur, pan, 0.1);
 112 }.scope(zoom: 4);
 113 )
 114
 115
 116
 117 (
 118 {
 119         var trate, dur, clk, pos, pan;
 120         trate = LinExp.kr(LFTri.kr(MouseY.kr(0.1,2,1)),-1,1,8,120);
 121         dur = 12 / trate;
 122         clk = Impulse.ar(trate);
 123         pos = MouseX.kr(0,BufDur.kr(b));
 124         pan = WhiteNoise.kr(0.6);
 125         TGrains.ar(2, clk, b, 1, pos, dur, pan, 0.1);
 126 }.scope(zoom: 4);
 127 )
 128
 129
 130 (
 131 {
 132         var trate, dur, clk, pos, pan;
 133         trate = 12;
 134         dur = MouseY.kr(0.2,24,1) / trate;
 135         clk = Impulse.kr(trate);
 136         pos = MouseX.kr(0,BufDur.kr(b)) + TRand.kr(0, 0.01, clk);
 137         pan = WhiteNoise.kr(0.6);
 138         TGrains.ar(2, clk, b, 1, pos, dur, pan, 0.1);
 139 }.scope(zoom: 4);
 140 )
 141
 142 (
 143 {
 144         var trate, dur, clk, pos, pan;
 145         trate = 100;
 146         dur = 8 / trate;
 147         clk = Impulse.kr(trate);
 148         pos = Integrator.kr(BrownNoise.kr(0.001));
 149         pan = WhiteNoise.kr(0.6);
 150         TGrains.ar(2, clk, b, 1, pos, dur, pan, 0.1);
 151 }.scope(zoom: 4);
 152 )
 153
 154 (
 155 {
 156         var trate, dur, clk, pos, pan;
 157         trate = MouseY.kr(1,400,1);
 158         dur = 8 / trate;
 159         clk = Impulse.kr(trate);
 160         pos = MouseX.kr(0,BufDur.kr(b));
 161         pan = WhiteNoise.kr(0.8);
 162         TGrains.ar(2, clk, b, 2 ** WhiteNoise.kr(2), pos, dur, pan, 0.1);
 163 }.scope(zoom: 4);
 164 )
 165
 166
 167 (
 168 {
 169         var trate, dur;
 170         trate = MouseY.kr(2,120,1);
 171         dur = 1.2 / trate;
 172         TGrains.ar(2, Impulse.ar(trate), b, (1.2 ** WhiteNoise.kr(3).round(1)), MouseX.kr(0,BufDur.kr(b)), dur, WhiteNoise.kr(0.6), 0.1);
 173 }.scope(zoom: 4);
 174 )
 175
 176
 177 // demand ugens as inputs
 178 (
 179 {
 180         var trate, dur, z, d;
 181         trate = MouseX.kr(1, 100, 1);
 182         d = { Dwhite(0.1, 0.2, 1) };
 183         z = {
 184                 Drand([Dgeom(0.1, 1 + d.value, Diwhite(20, 40)), Dgeom(1, 1 - d.value, Diwhite(20, 40))])
 185         };
 186         TGrains.ar(2,
 187                 Impulse.ar(trate),
 188                 bufnum: 10,
 189                 rate: Dseq([1, 1, z.value, 0.5, 0.5, 0.2, 0.1, 0.1, 0.1, 0.1], inf) * 2 + 1,
 190                 centerPos: Dseq(z.dup(8), inf),
 191                 dur: Dseq([1, d.value, 1, z.value, 0.5, 0.5, 0.1, z.value] * 2, inf) / trate,
 192                 pan: Dseq([1, 1, 1, 0.5, 0.2, 0.1, 0, 0, 0], inf) * 2 - 1,
 193                 amp: Dseq([1, 0, z.value, 0, 2, 1.0, 1, 0.1, 0.1], inf)
 194         );
 195 }.scope(zoom: 4);
 196 )
 197
 198 b.free
 199
 200 ::