HelpSource/Tutorials/A-Practical-Guide/PG_06b_Time_Based_Patterns.schelp

   1 title:: PG_06b_Time_Based_Patterns
   2 summary:: Patterns using time as the basis for their evaluation
   3 related:: Tutorials/A-Practical-Guide/PG_06a_Repetition_Contraint_Patterns, Tutorials/A-Practical-Guide/PG_06c_Composition_of_Patterns
   4 categories:: Streams-Patterns-Events>A-Practical-Guide
   5
   6 section::Time-based patterns
   7
   8 "Time-based patterns" here are value patterns that use time as part of their calculation. Event patterns are naturally time-driven when played on a clock. (Technically it's possible to request events from an event stream without running it in an EventStreamPlayer, but this is not typical usage.)
   9
  10 Most of these patterns work by remembering the clock's current time at the moment the pattern is embedded into a value stream. The time value used for calculation is, then, the clock's time at the moment of evaluation minus the starting time -- that is, the number of beats elapsed since the patterns started embedding. If the pattern is embedded several times, the starting time is also reset so that the pattern begins again from the beginning.
  11
  12 There is nothing to prevent using these patterns outside of a scheduling context. In these documents, that context would be an event pattern played on a clock, but streams made from these patterns can be used in scheduled routines or functions as well. Only a scheduling context can ensure precise timing of requests for values.
  13
  14 definitionList::
  15 ## code::Ptime(repeats):: || Returns the amount of time elapsed since embedding. One nice trick with this pattern is to stop a value stream/pattern after a certain amount of time.
  16
  17 This link::Classes/Pif:: pattern uses Ptime to get values from the true branch for exactly 4 beats after the first value is requested. After that, the condition will be false and Pif reverts to the false branch, which is nil. That causes the stream to stop. (This is like link::Classes/Pfindur:: for event patterns, but Pif/Ptime works for value patterns as well.)
  18
  19 code::
  20 // This is a really useful trick: like Pfindur but for value patterns
  21 (
  22 p = Pbind(
  23         \degree, Pif(Ptime(inf) < 4.0, Pwhite(-4, 11, inf)),
  24         \dur, 0.25
  25 ).play;
  26 )
  27 ::
  28
  29 ## code::Pstep(levels, durs, repeats):: || Repeat a code::level:: value for its corresponding duration, then move to the next.
  30 ## code::Pseg(levels, durs, curves, repeats):: || Similar to Pstep, but interpolates to the next value instead of stepping abruptly at the end of the duration. Interpolation is linear by default, but any envelope segment curve can be used. code::levels::, code::durs:: and code::curves:: should be patterns.
  31
  32 code::
  33 // curve is 5 - here's what the curve looks like, ascending first then descending
  34 Env(#[0, 1, 0], #[1, 1], 5).plot;
  35
  36 (
  37 p = Pbind(
  38                 // using \note b/c Pseg will give fractional note numbers
  39                 // can't use \degree because it handles non-integers differently
  40         \note, Pseg(
  41                 Pwhite(-7, 19, inf),    // chromatic note numbers
  42                         // alternate version for diatonic numbers
  43                         // PdegreeToKey does the same conversion as \degree --> \note
  44 //              PdegreeToKey(Pwhite(-4, 11, inf), Pkey(\scale), 12),
  45                 Pwhite(1, 4, inf) * 0.5,
  46                 5, inf),
  47         \dur, 0.125
  48 ).play;
  49 )
  50
  51 p.stop;
  52 ::
  53 ::
  54
  55 subsection::Using envelopes as patterns
  56
  57 link::Classes/Env:: supports the stream protocol: code::asStream:: turns an Env into a stream, and timed values can be obtained from it using code::next::. The envelope stream returns the value the envelope would have at the elapsed time, in the same way code::.at(time):: returns the envelope value at the specified time.
  58
  59 code::
  60 e = Env.linen(1, 1, 1);
  61 e.at(2);        // == 1
  62 e.at(2.5);      // == 0.5
  63
  64 // print envelope values
  65 r = fork {
  66         var stream = e.asStream;
  67         12.do({
  68                 stream.next.postln;
  69                 0.25.wait;
  70         });
  71 };
  72
  73 // Use an envelope to pan notes from left to right and back
  74 p = Pbind(
  75         \degree, Pwhite(-4, 11, 32),
  76         \pan, Env(#[-1, 1, -1], #[2, 2], \sin),
  77         \dur, 0.125
  78 ).play;
  79
  80 p.stop;
  81 ::
  82
  83 The code::releaseNode:: and code::loopNode:: envelope parameters do not take effect, because they are meaningful only when used in a Synth with a gated EnvGen.
  84
  85 When the envelope ends, the stream will hold the final level indefinitely. The code::Pif(Ptime(inf) < totalTime, Env(...))\x03\x03:: trick can make it stop instead.
  86
  87 code::
  88 // Use an envelope to pan notes from left to right and back
  89 // Plays one cycle
  90 (
  91 p = Pbind(
  92                 // change to inf: we don't need to know exactly how many events are needed
  93         \degree, Pwhite(-4, 11, inf),
  94         \pan, Pif(Ptime(inf) <= 4.0, Env(#[-1, 1, -1], #[2, 2], \sin)),
  95         \dur, 0.125
  96 ).play;
  97 )
  98
  99 p.stop;
 100
 101 // To keep looping the envelope, wrap Pif inside Pn
 102 (
 103 p = Pbind(
 104         \degree, Pwhite(-4, 11, inf),
 105         \pan, Pn(Pif(Ptime(inf) <= 4.0, Env(#[-1, 1, -1], #[2, 2], \sin)), inf),
 106         \dur, 0.125
 107 ).play;
 108 )
 109
 110 p.stop;
 111 ::
 112
 113 Previous:       link::Tutorials/A-Practical-Guide/PG_06a_Repetition_Contraint_Patterns::
 114
 115 Next:           link::Tutorials/A-Practical-Guide/PG_06c_Composition_of_Patterns::