HelpSource/Classes/DiskIn.schelp

   1 class:: DiskIn
   2 summary:: Stream in audio from a file.
   3 related:: Classes/PlayBuf, Classes/DiskOut
   4 categories::  UGens>InOut, UGens>Buffer
   5
   6 Description::
   7
   8 Continously play a longer soundfile from disk. This requires a buffer to
   9 be preloaded with one buffer size of sound.
  10
  11
  12 classmethods::
  13 private:: categories
  14
  15 method::ar
  16
  17 argument::numChannels
  18 Number of channels. This must match the number of channels in the buffer.
  19
  20 argument::bufnum
  21 Buffer number
  22 Note:: The Buffer's numFrames must be a power of two and is recommended to be at least 65536 -- preferably 131072 or 262144. Smaller buffer sizes mean more frequent disk access, which can cause glitches. ::
  23
  24 argument:: loop
  25 If set to 1, the soundfile will loop.
  26
  27 discussion::
  28 This UGen will set the link::Classes/Done##'done' flag:: when finished playing.
  29
  30 instancemethods::
  31 private:: init
  32
  33 Examples::
  34
  35 code::
  36 s.boot; // start the server
  37
  38 (
  39 SynthDef("help-Diskin", { arg bufnum = 0;
  40         Out.ar(0, DiskIn.ar(1, bufnum));
  41 }).send(s)
  42 )
  43 ::
  44
  45 subsection:: OSC Messaging Style
  46 code::
  47 // allocate a disk i/o buffer
  48 s.sendMsg("/b_alloc", 0, 65536, 1);
  49
  50 // open an input file for this buffer, leave it open
  51 s.sendMsg("/b_read", 0, Help.dir +/+ "sounds/a11wlk01-44_1.aiff", 0, 65536, 0, 1);
  52
  53 // create a diskin node
  54 s.sendMsg("/s_new", "help-Diskin", x = s.nextNodeID, 1, 1);
  55
  56 s.sendMsg("/b_close", 0); // close the file (very important!)
  57
  58
  59 // again
  60 // don't need to reallocate and Synth is still reading
  61 s.sendMsg("/b_read", 0, Help.dir +/+ "sounds/a11wlk01-44_1.aiff", 0, 0, 0, 1);
  62
  63 s.sendMsg("/n_free", x); // stop reading
  64
  65 s.sendMsg("/b_close", 0); // close the file.
  66
  67 s.sendMsg("/b_free", 0); // frees the buffer
  68 ::
  69
  70 subsection:: Using Buffer (Object Style)
  71 code::
  72 b = Buffer.cueSoundFile(s, Help.dir +/+ "sounds/a11wlk01-44_1.aiff", 0, 1);
  73
  74 x = { DiskIn.ar(1, b.bufnum) }.play;
  75
  76 b.close;
  77
  78 // again
  79 // note the like named instance method, but different arguments
  80 b.cueSoundFile(Help.dir +/+ "sounds/a11wlk01-44_1.aiff", 0);
  81
  82 x.free; b.close; b.free;
  83
  84
  85
  86 // loop it (for better looping use PlayBuf!)
  87 (
  88 p = Help.dir +/+ "sounds/a11wlk01-44_1.aiff";
  89 a = SoundFile.new;
  90 a.openRead(p);
  91 d = a.numFrames/s.sampleRate; // get the duration
  92 a.close; // don't forget
  93 b = Buffer.cueSoundFile(s, p, 0, 1);
  94 f = { DiskIn.ar(1, b.bufnum) };
  95 x = f.play;
  96 r = Routine({
  97         loop({ d.wait; x.free; x = f.play; b.close( b.cueSoundFileMsg(p, 0)) });
  98 }).play; )
  99 r.stop; x.free; b.close; b.free; // you need to do all these to properly cleanup
 100
 101
 102
 103 // cue and play right away
 104 (
 105 SynthDef("help-Diskin", { arg bufnum = 0;
 106         Out.ar(0, DiskIn.ar(1, bufnum));
 107 }).send(s);
 108 )
 109 (
 110 x = Synth.basicNew("help-Diskin");
 111 m = { arg buf; x.addToHeadMsg(nil, [\bufnum,buf.bufnum])};
 112
 113 b = Buffer.cueSoundFile(s,Help.dir +/+ "sounds/a11wlk01-44_1.aiff",0,1, completionMessage: m);
 114
 115 )
 116
 117 ::
 118