HelpSource/Classes/Pgpar.schelp

   1 class:: Pgpar
   2 summary:: embed event streams in parallel and put each in its own group
   3 related:: Classes/Ppar, Classes/Pbus, Classes/Pgroup
   4 categories:: Streams-Patterns-Events>Patterns>Parallel
   5
   6 description::
   7
   8 Embeds several event streams so that they form a single output stream with all their events in temporal order. When one stream ends, the other streams are further embedded until all have ended.
   9
  10 note::
  11 In order to fully separate these layers from other synths, use link::Classes/Pbus::.
  12 ::
  13
  14 See link::Classes/Pgroup:: for a description of the code::\groupReleaseTime:: event key.
  15
  16 ClassMethods::
  17
  18 method::new
  19
  20 argument::list
  21 list of patterns or streams.
  22
  23 argument::repeats
  24 repeat the whole pattern n times.
  25
  26 Examples::
  27
  28 code::
  29 // an example analogous to the one in the Pfx helpfile
  30
  31 (
  32 SynthDef(\echo, { arg out=0, maxdtime=0.2, dtime=0.2, decay=2, gate=1;
  33         var env, in;
  34         env = Linen.kr(gate, 0.05, 1, 0.1, 2);
  35         in = In.ar(out, 2);
  36         XOut.ar(out, env, CombL.ar(in * env, maxdtime, dtime, decay, 1, in));
  37 }, [\ir, \ir, 0.1, 0.1, 0]).add;
  38
  39 SynthDef(\distort, { arg out=0, pregain=40, amp=0.2, gate=1;
  40         var env;
  41         env = Linen.kr(gate, 0.05, 1, 0.1, 2);
  42         XOut.ar(out, env, (In.ar(out, 2) * pregain).distort * amp);
  43 }, [\ir, 0.1, 0.1, 0]).add;
  44
  45 SynthDef(\wah, { arg out=0, gate=1, rate=0.3;
  46         var env, in;
  47         env = Linen.kr(gate, 0.05, 1, 0.4, 2);
  48         in = In.ar(out, 2);
  49         XOut.ar(out, env, RLPF.ar(in, LinExp.kr(LFNoise1.kr(rate), -1, 1, 200, 8000), 0.1).softclip * 0.8);
  50 }, [\ir, 0]).add;
  51 )
  52
  53
  54 (
  55 var p, q, r, o;
  56 Pbus(
  57         Pgpar([
  58                 Pbind(\degree, Prand((0..7), inf), \dur, 0.3, \legato, 0.2),
  59                 Pbind(\instrument, \echo, \dur, 3, \legato, 1.1,
  60                         \dtime, Pwhite(0.01, 0.1, inf), \decay, 3),
  61                 Pbind(\instrument, \distort, \dur, 1.2, \legato, 1.1,
  62                         \pregain, Pwhite(1, 20, inf), \amp, 0.25),
  63                 Pbind(\instrument, \wah, \dur, 4.0, \legato, 1.1,
  64                         \rate, Pwhite(0.1, 3, inf))
  65         ])
  66 ).play
  67 )
  68 ::
  69
  70 code::
  71 // synthdefs
  72 (
  73 SynthDef(\gap, { arg out, sustain=1.0, attack=0.0001, decay=0.01, leak;
  74         var level;
  75         level = EnvGen.ar(Env.linen(attack, sustain, decay, 1-leak), doneAction:2);
  76         XOut.ar(out, level, Silent.ar ! 2)
  77 }).add;
  78
  79 SynthDef(\help_sinegrain,
  80         { arg out=0, freq=440, sustain=0.05;
  81                 var env;
  82                 env = EnvGen.kr(Env.perc(0.01, sustain, 0.2), doneAction:2);
  83                 Out.ar(out, SinOsc.ar(freq, 0, env))
  84 }).add;
  85 )
  86
  87
  88 // play a layered pattern with gaps and overlays
  89 (
  90 x = Pbind(
  91         \instrument, \help_sinegrain,
  92         \degree, Pn(Plazy({ Prand([0, 4, 5], 16) + 5.rand })) + Prand(#[0, [0, 3], [0, 7]], inf),
  93         \dur, Prand([0.25, 0.5, 1.0], inf),
  94         \scale, #[0, 3, 5, 9, 10]
  95 );
  96 y = Pbind(
  97         \instrument, \gap,
  98         \dur, Prand([0.25, 0.5, 1.0], inf) * Pstutter(inf, Prand([0.25, 1, 2],1)),
  99         \legato, Prand([0.25, 0.5, 1.0], inf),
 100         \leak, 0.25
 101 );
 102 a = Pbus(Pgpar([x, y, x, y, x, y]));
 103 a.play;
 104 )
 105 ::