HelpSource/Classes/TaskProxy.schelp

   1 class:: TaskProxy
   2 summary:: event stream reference
   3 categories:: Libraries>JITLib>Patterns
   4 related:: Classes/Tdef
   5
   6 description::
   7 Keeps a reference to a task (time pattern) that can be replaced while playing. It plays on when the old stream ended and a new stream is set and schedules the changes to the beat.
   8
   9 ClassMethods::
  10
  11 method::new
  12 create a new instance with a function (the source). the source should be a strong::routine function:: (see link::Classes/Tdef::) or a strong::pattern:: of time values.
  13
  14 method::default
  15 a default source, if none is given. the default is a loop that does nothing with a 1.0 beat wait time.
  16
  17 method::defaultQuant
  18 set the default quantization value for the class. (default: 1.0). can be a pair [quant, offset]
  19
  20 InstanceMethods::
  21
  22 method::source
  23 set the source. If a quantization is given, schedule this change to the next beat the object is a strong::routine function::, which is evaluated in a protected way, so that failure will notify the proxy that it has stopped. The object can also be a strong::pattern:: of time values.
  24
  25 method::clear
  26 set the source to nil
  27
  28 method::quant
  29 get or set the quantization value. can be a pair [quant, offset]
  30
  31 method::condition
  32 provide a condition under which the pattern is switched when a new one is inserted. the stream value and a count is passed into the function. the methods strong::count_(n):: simply counts up to n and switches the pattern then
  33
  34 method::reset
  35 switch the pattern immediately. (stuck conditions can be subverted by this)
  36
  37 method::envir
  38 provide a default environment for the proxy. If given, it is used as an environment for the routine function. When set for the first time, the routine pattern is rebuilt.
  39
  40 method::set
  41 set arguments in the environment. If there is none, it is created and the routine pattern is rebuilt.
  42
  43 method::endless
  44 returns a link::Classes/Proutine:: that plays the proxy endlessly, replacing strong::nil:: with a strong::default:: value (1 s. wait time). This allows to create streams that idle on until a new pattern is inserted.
  45
  46 subsection::a) using it as stream reference
  47
  48 method::source
  49 set the routine function / pattern (internally done by *new(key, obj)
  50
  51 method::embedInStream
  52 just like any stream, embeds itself in stream
  53
  54 subsection::b) using it as EventStreamPlayer
  55
  56 method::play
  57 starts the TaskProxy and creates a player. if you want to play multiple instances, use strong::.playOnce(clock, protoEvent, quant)::
  58
  59 argument::quant
  60 can be an array of [quant, phase]
  61
  62 method::stop
  63 stops the player
  64
  65 method::player
  66 the current player (if the TaskProxy is simply used in other streams this is nil)
  67
  68 method::pause, resume, reset
  69 perform player method
  70
  71 method::isPlaying
  72 returns true if TaskProxy is running. if a TaskProxy is playing and its stream ends, it will schedule a stream for playing as soon as a new one is assigned to it.
  73
  74 Examples::
  75
  76 subsection::a) using TaskProxy as a player
  77
  78 code::
  79 // create an empty Tdef and play it.
  80 x = TaskProxy.new;
  81 x.play;
  82
  83
  84 x.source = { loop { "ggggggggggggggggg9999ggg999ggg999gg".scramble.postln; 0.5.wait; } };
  85
  86
  87 x.source = { loop { "---------////----------------------".scramble.postln; 0.25.wait; } };
  88 x.source = { loop { thisThread.seconds.postln; 1.wait; } };
  89 x.source = { loop { thisThread.seconds.postln; 1.01.wait; } };
  90
  91 TempoClock.default.tempo = 2;
  92
  93 x.source = { "the end".postln };
  94 x.source = { "one more".postln };
  95 x.source = { 10.do { "ten more".scramble.postln; 0.25.wait; } };
  96 x.source = { loop { "many more".scramble.postln; 0.25.wait; } };
  97
  98 TempoClock.default.tempo = 1;
  99
 100 x.stop;
 101 x.play;
 102 x.stop;
 103 ::
 104
 105
 106 code::
 107 // sound example
 108
 109 (
 110 // load a synthdef
 111 s.boot;
 112 SynthDef("pdef_grainlet",
 113         { arg out=0, freq=440, sustain=0.05;
 114                 var env;
 115                 env = EnvGen.kr(Env.perc(0.01, sustain, 0.3), doneAction:2);
 116                 Out.ar(out, SinOsc.ar(freq, 0, env))
 117         }).add;
 118 )
 119 x.play;
 120
 121 (
 122 x.source = {
 123         loop {
 124                 s.sendMsg("/s_new", "pdef_grainlet", -1,0,0, \freq, rrand(600, 640));
 125                 0.1.wait;
 126         }
 127 }
 128 )
 129
 130 (
 131 x.source = {
 132         var x;
 133         x = Pseries(300, 20, 100).loop.asStream;
 134         loop {
 135                 s.sendMsg("/s_new", "pdef_grainlet", -1,0,0, \freq, x.next);
 136                 0.05.wait;
 137         }
 138 }
 139 )
 140
 141 (
 142 x.source = {
 143         var x;
 144         x = Plazy { Pseries(300 + 300.rand, 10 + 30.rand, 10 + 30.rand) }.loop.asStream;
 145         loop {
 146                 s.sendMsg("/s_new", "pdef_grainlet", -1,0,0, \freq, x.next);
 147                 0.05.wait;
 148         }
 149 }
 150 )
 151
 152 // metronome
 153 (
 154 y = TaskProxy {
 155         loop { s.sendMsg("/s_new", "pdef_grainlet", -1,0,0, \freq, 1500); 1.wait; }
 156 };
 157 y.play;
 158 )
 159
 160 // play ending stream once
 161 (
 162 x.source = {
 163         var x, dt;
 164         dt = [0.1, 0.125, 0.05].choose;
 165         x = Plazy { Pseries(1300 + 300.rand, 110 + 130.rand, 16) }.asStream;
 166         x.do { arg item;
 167                 s.sendMsg("/s_new", "pdef_grainlet", -1,0,0, \freq, item);
 168                 dt.wait;
 169         }
 170 }
 171 )
 172
 173 ... and so on ...
 174
 175 x.stop;
 176 y.stop;
 177 ::
 178
 179 subsection::b) embedding TaskProxy into other Tasks / Routines
 180
 181 code::
 182 (
 183 #a, c = { TaskProxy.new } ! 2;
 184 a.source = { "one".postln; 1.wait; "two".postln };
 185 c.source = { var z; z = Synth(\default); 0.5.wait; z.release };
 186 r = Task {
 187         "counting...".postln;
 188         2.wait;
 189         a.embedInStream;
 190         1.wait;
 191         c.embedInStream;
 192         "done.".postln;
 193 };
 194 )
 195
 196 r.play; // play a stream
 197
 198 c.source = { var z; z = Synth(\default, [\freq, 300]); 1.5.wait; z.release }; // change the def
 199
 200 r.reset;
 201 r.play;
 202
 203 // of course TaskProxies can be used in other Tdefs:
 204 (
 205 b = TaskProxy.new;
 206 b.source = {
 207         "counting...".postln;
 208         2.wait;
 209         a.embedInStream;
 210         1.wait;
 211         c.embedInStream;
 212         "done.".postln;
 213 };
 214 )
 215 b.playOnce;
 216
 217 // if one wants to branch off a stream in a separate thread, asStream is used.
 218 (
 219 Routine {
 220         c.asStream.play;
 221         0.1.wait;
 222         c.asStream.play;
 223         0.1.wait;
 224         a.asStream.play;
 225
 226 }.play;
 227 )
 228 ::