HelpSource/Classes/Gendy1.schelp

   1 class:: Gendy1
   2 summary:: Dynamic stochastic synthesis generator.
   3 related:: Classes/Gendy2, Classes/Gendy3
   4 categories::  UGens>Generators>Stochastic
   5
   6
   7 Description::
   8
   9 An implementation of the dynamic stochastic synthesis generator conceived
  10 by Iannis Xenakis and described in  emphasis::Formalized Music (1992, Stuyvesant, NY: Pendragon Press) chapter 9 (pp 246-254) and chapters 13 and 14 (pp 289-322)::.
  11
  12 The BASIC program in the book was written by Marie-Helene Serra so I
  13 think it helpful to credit her too.
  14
  15 The program code has been adapted to avoid infinities in the probability
  16 distribution functions.
  17
  18 The distributions are hard-coded in C but there is an option to have new
  19 amplitude or time breakpoints sampled from a continuous controller input.
  20
  21 subsection:: Technical notes
  22 X's plan as described in chapter 13 allows the 12 segments in the period to be successively modified with each new period.
  23 Yet the period is allowed to vary as the sum of the segment durations, as figure 1 demonstrates.
  24 We can setup some memory of n (conventionally 12) points, or even simply vary successively a single point's ordinate and
  25 duration. There are thus various schemes available to us. In one, fix period T and only move the (ti, Ei) within the period. In another, have a memory of 12 segments but allow continuous modification of the inter point intervals and the amplitudes.
  26 In yet another, just have one point and random walk its amplitude and duration based on the probability distribution.
  27 In this implementation I allow the user to initialise a certain number of memory points which is up to them.
  28 To restrict the period to be unchanging, you must set rate variation to zero (dscale=0).
  29
  30 SuperCollider implementation by Nick Collins.
  31
  32
  33 classmethods::
  34
  35 method::ar, kr
  36
  37 argument::ampdist
  38
  39 Choice of probability distribution for the next perturbation of
  40 the amplitude of a control point.
  41
  42 The distributions are (adapted from the GENDYN program in Formalized Music):
  43
  44 table::
  45 ## 0: || LINEAR.
  46 ## 1: || CAUCHY.
  47 ## 2: || LOGIST.
  48 ## 3: || HYPERBCOS.
  49 ## 4: || ARCSINE.
  50 ## 5: || EXPON.
  51 ## 6: || SINUS.
  52 ::
  53
  54 Where the sinus (Xenakis' name) is in this implementation taken
  55 as sampling from a third party oscillator. See example below.
  56
  57
  58 argument::durdist
  59
  60 Choice of distribution for the perturbation of the current inter
  61 control point duration.
  62
  63
  64 argument::adparam
  65
  66 A parameter for the shape of the amplitude probability
  67 distribution, requires values in the range 0.0001 to 1 (there are
  68 safety checks in the code so don't worry too much if you want to
  69 modulate!).
  70
  71
  72 argument::ddparam
  73
  74 A parameter for the shape of the duration probability
  75 distribution, requires values in the range 0.0001 to 1.
  76
  77
  78 argument::minfreq
  79
  80 Minimum allowed frequency of oscillation for the Gendy1
  81 oscillator, so gives the largest period the duration is allowed
  82 to take on.
  83
  84
  85 argument::maxfreq
  86
  87 Maximum allowed frequency of oscillation for the Gendy1
  88 oscillator, so gives the smallest period the duration is allowed
  89 to take on.
  90
  91
  92 argument::ampscale
  93
  94 Normally 0.0 to 1.0, multiplier for the distribution's delta
  95 value for amplitude. An ampscale of 1.0 allows the full range
  96 of  -1 to 1 for a change of amplitude.
  97
  98
  99 argument::durscale
 100
 101 Normally 0.0 to 1.0, multiplier for the distribution's delta
 102 value for duration. An ampscale of 1.0 allows the full range of
 103 -1 to 1 for a change of duration.
 104
 105
 106 argument::initCPs
 107
 108 Initialise the number of control points in the memory.
 109 Xenakis specifies 12. There would be this number of control
 110 points per cycle of the oscillator, though the oscillator's
 111 period will constantly change due to the duration distribution.
 112
 113
 114 argument::knum
 115
 116 Current number of utilised control points, allows modulation.
 117
 118 argument::mul
 119
 120 argument::add
 121
 122 discussion::
 123 All parameters can be modulated at control rate except for code::initCPs:: which is used only at initialisation.
 124
 125 Examples::
 126
 127 warning::
 128 if you have lots of CPs and you have fast frequencies, the CPU cost goes up a lot because a new CP move happens every sample!
 129 ::
 130
 131 code::
 132 //defaults
 133 {Pan2.ar(Gendy1.ar)}.play
 134
 135 //wandering bass/ powerline
 136 {Pan2.ar(Gendy1.ar(1,1,1.0,1.0,30,100,0.3,0.05,5))}.play
 137
 138 //play me
 139 {Pan2.ar(RLPF.ar(Gendy1.ar(2,3,minfreq:20,maxfreq:MouseX.kr(100,1000),durscale:0.0,initCPs:40),500,0.3,0.2),0.0)}.play
 140
 141 //scream! - careful with your ears for this one!
 142 (
 143 {
 144     var mx, my;
 145
 146     mx= MouseX.kr(220,440);
 147     my= MouseY.kr(0.0,1.0);
 148
 149     Pan2.ar(Gendy1.ar(2,3,1,1,minfreq:mx, maxfreq:8*mx, ampscale:my, durscale:my, initCPs:7, mul:0.3), 0.0)
 150 }.play
 151 )
 152
 153
 154 //1 CP = random noise effect
 155 {Pan2.ar(Gendy1.ar(initCPs:1))}.play
 156
 157 //2 CPs = suudenly an oscillator (though a fast modulating one here)
 158 {Pan2.ar(Gendy1.ar(initCPs:2))}.play
 159
 160
 161 //used as an LFO
 162 (
 163 {
 164     Pan2.ar(
 165         SinOsc.ar(
 166             Gendy1.kr(2, 4,
 167                 SinOsc.kr(0.1,0,0.49,0.51),
 168                 SinOsc.kr(0.13,0,0.49,0.51),
 169                 3.4, 3.5,
 170                 SinOsc.kr(0.17,0,0.49,0.51),
 171                 SinOsc.kr(0.19,0,0.49,0.51),
 172                 10,10,50, 350),
 173         0, 0.3),
 174     0.0)
 175 }.play
 176 )
 177
 178 //wasp
 179 {Pan2.ar(Gendy1.ar(0, 0, SinOsc.kr(0.1, 0, 0.1, 0.9),1.0, 50,1000, 1,0.005, 12, 12, 0.2), 0.0)}.play
 180
 181
 182 //modulate distributions
 183 //change of pitch as distributions change the duration structure and spectrum
 184 {Pan2.ar(Gendy1.ar(MouseX.kr(0,7),MouseY.kr(0,7),mul:0.2), 0.0)}.play
 185
 186
 187 //modulate num of CPs
 188 {Pan2.ar(Gendy1.ar(knum:MouseX.kr(1,13),mul:0.2), 0.0)}.play
 189
 190
 191 (//Gendy into Gendy...with cartoon side effects
 192 {Pan2.ar(Gendy1.ar(
 193     maxfreq:Gendy1.kr(5,4,0.3, 0.7, 0.1, MouseY.kr(0.1,10), 1.0, 1.0, 5,5, 500, 600),
 194     knum:MouseX.kr(1,13),mul:0.2), 0.0)
 195 }.play
 196 )
 197
 198 //use SINUS to track any oscillator and take CP positions from it, use adparam and ddparam as the inputs to sample
 199 {Pan2.ar(Gendy1.ar(6,6,LFPulse.kr(100, 0, 0.4, 1.0), SinOsc.kr(30, 0, 0.5),mul:0.2), 0.0)}.play
 200
 201
 202 //try out near the corners especially
 203 (
 204 {Pan2.ar(Gendy1.ar(6,6,LFPulse.kr(MouseX.kr(0,200), 0, 0.4, 1.0),
 205     SinOsc.kr(MouseY.kr(0,200), 0, 0.5),mul:0.2), 0.0)}.play
 206 )
 207
 208 //texture
 209 (
 210 {
 211 Mix.fill(10,{
 212 var freq;
 213
 214 freq= rrand(130,160.3);
 215 Pan2.ar(SinOsc.ar(Gendy1.ar(6.rand,6.rand,SinOsc.kr(0.1,0,0.49,0.51),
 216     SinOsc.kr(0.13,0,0.49,0.51),freq ,freq, SinOsc.kr(0.17,0,0.49,0.51),
 217     SinOsc.kr(0.19,0,0.49,0.51), 12, 12, 200, 400), 0, 0.1), 1.0.rand2)
 218 });
 219 }.play
 220 )
 221
 222 //wahhhhhhhh- try durscale 10.0 and 0.0 too
 223 (
 224 {Pan2.ar(
 225 CombN.ar(
 226 Resonz.ar(
 227 Gendy1.ar(2,3,minfreq:1, maxfreq:MouseX.kr(10,700), durscale:0.1, initCPs:10),
 228 MouseY.kr(50,1000), 0.1)
 229 ,0.1,0.1,5, 0.6
 230 )
 231 , 0.0)}.play
 232 )
 233
 234 //overkill
 235 (
 236 {
 237 var n;
 238 n=10;
 239
 240 Mix.fill(n,{
 241 var freq, numcps;
 242
 243 freq= rrand(130,160.3);
 244 numcps= rrand(2,20);
 245 Pan2.ar(Gendy1.ar(6.rand,6.rand,1.0.rand,1.0.rand,freq ,freq, 1.0.rand, 1.0.rand, numcps,
 246     SinOsc.kr(exprand(0.02,0.2), 0, numcps/2, numcps/2), 0.5/(n.sqrt)), 1.0.rand2)
 247 });
 248 }.play
 249 )
 250
 251 //another traffic moment
 252 (
 253 {
 254     var n;
 255     n=10;
 256
 257     Resonz.ar(
 258     Mix.fill(n,{
 259     var freq, numcps;
 260
 261     freq= rrand(50,560.3);
 262     numcps= rrand(2,20);
 263     Pan2.ar(Gendy1.ar(6.rand,6.rand,1.0.rand,1.0.rand,freq ,freq, 1.0.rand, 1.0.rand, numcps,
 264         SinOsc.kr(exprand(0.02,0.2), 0, numcps/2, numcps/2), 0.5/(n.sqrt)), 1.0.rand2)
 265     })
 266     ,MouseX.kr(100,2000), MouseY.kr(0.01,1.0))
 267     ;
 268 }.play
 269 )
 270
 271 (
 272 {
 273 var n;
 274 n=15;
 275
 276 Out.ar(0,
 277 Resonz.ar(
 278 Mix.fill(n,{
 279 var freq, numcps;
 280
 281 freq= rrand(330,460.3);
 282 numcps= rrand(2,20);
 283 Pan2.ar(Gendy1.ar(6.rand,6.rand,1.0.rand,1.0.rand,freq,MouseX.kr(freq,2*freq), 1.0.rand, 1.0.rand, numcps,
 284     SinOsc.kr(exprand(0.02,0.2), 0, numcps/2, numcps/2), 0.5/(n.sqrt)), 1.0.rand2)
 285 })
 286 ,MouseX.kr(100,2000), MouseY.kr(0.01,1.0))
 287 )
 288
 289 }.play;
 290 )
 291 ::
 292