HelpSource/Classes/HLayoutView.schelp

   1 class:: HLayoutView
   2 redirect:: implClass
   3 summary:: A container view that arranges its children horizontally
   4 categories:: GUI>Views
   5 related:: Classes/VLayoutView, Classes/CompositeView
   6
   7 DESCRIPTION::
   8
   9 note::
  10 In Qt GUI, this class has been rendered strong::obsolete:: by a special set of layout classes; they are easier to use and more flexible. See link::Classes/HLayout:: for an equivalent to this class, and link::Guides/GUI-Layout-Management:: for a general description of the Qt layout system.
  11 ::
  12
  13 HLayoutView can be a parent to other views, and it automatically arranges its child views in horizontal order, expanding their height to its own bounds. Only the width of the children is relevant.
  14
  15 When arranging its children, HLayoutView takes the values of their 'minWidth' and 'maxWidth' properties into account. This is useful when a child's link::Classes/View#-resize#resize:: mode is set to 2, 5, or 8. See link::#examples:: below.
  16
  17 HLayoutView inherits some useful formatting methods from its superclasses.
  18
  19 note::
  20 HLayoutView is designed mainly for grouping and placing widgets. While you can set it to accept key presses, it does not accept mouse clicks or drags.
  21 ::
  22
  23 CLASSMETHODS::
  24 PRIVATE:: key
  25
  26 EXAMPLES::
  27
  28 Child view height fills the HLayoutView automatically:
  29
  30 code::
  31 (
  32 q = 10;
  33 w = Window.new;
  34
  35 h = HLayoutView(w,Rect(0,0,300,300));
  36
  37 Array.fill(q,{ arg i;
  38     Slider(h,Rect(0,0,20,75)).value_(i / q)
  39 });
  40 h.background_(Color.rand);
  41
  42 w.front
  43 )
  44 ::
  45
  46 Stretching the layout view; Slider height fills the View automatically:
  47
  48 code::
  49 (
  50 q = 8;
  51 w = Window.new;
  52
  53 h = HLayoutView(w,Rect(0,0,300,300));
  54 h.background = Color.rand;
  55 h.resize = 5; // elastic
  56
  57 Array.fill(q,{ arg i;
  58     var s;
  59     s = Slider(h,Rect(0,0,20,75)).background_(Color.grey.alpha_(0.4));
  60     s.value = i / q;
  61     s
  62 });
  63 StaticText(h, Rect(0,0,105,20)).background_(Color.rand).string_(" Some Example\n Text");
  64 w.front
  65 )
  66 ::
  67
  68 Stretching the layout view and the contents; if all the contents are elastic, the widths of the contents are perfectly divided up. In this example, the StaticText is not elastic in order to preserve its width:
  69
  70 code::
  71 (
  72 q = 10;
  73 w = Window.new;
  74
  75 h = HLayoutView(w,Rect(0,0,300,300));
  76 h.resize = 5; // elastic
  77 h.background = Color.rand;
  78
  79 Array.fill(q,{ arg i;
  80     var s;
  81     s = Slider(h,Rect(0,0,20,75));
  82     s.resize = 5; // elastic
  83     s.value = i / q;
  84     s
  85 });
  86 StaticText(h, Rect(0,0,105,20)).background_(Color.rand).string_(" Some Example\n Text");
  87
  88 w.front
  89 )
  90 ::
  91
  92 Setting minWidth on contents; beware that if the layout view width is smaller than the combined width of all the contents, things might disappear when you try to handle them with the mouse:
  93
  94 code::
  95 (
  96 q = 5;
  97 w = Window.new;
  98
  99 h = HLayoutView(w,Rect(0,0,300,300));
 100 h.background = Color.rand;
 101 h.resize = 5; // elastic
 102
 103 Array.fill(q,{ arg i;
 104     var s;
 105     s = Slider(h,Rect(0,0,20,75));
 106     s.value = i / 5;
 107     if(i < 2,{
 108         s.resize = 5; // some elastic
 109         s.setProperty(\minWidth,20);
 110     },{
 111         s.resize = 1; // some not elastic
 112     });
 113     s
 114 });
 115 StaticText(h, Rect(0,0,105,20)).background_(Color.rand).string_(" Some Example\n Text");
 116
 117 w.front
 118 )
 119 ::
 120
 121 code::
 122 (
 123 q = 5;
 124 w = Window.new;
 125
 126 h = HLayoutView(w,Rect(0,0,300,300));
 127 h.resize = 5; // elastic
 128 h.background = Color.rand;
 129 Array.fill(q,{ arg i;
 130     var s;
 131     s = Slider(h,Rect(0,0,20,75));
 132     s.value = i / 5;
 133     s.resize = 5;
 134     s.setProperty(\minWidth,20);
 135     s.setProperty(\maxWidth,40);
 136     s
 137 });
 138
 139 w.front
 140 )
 141 ::
 142
 143 Text flows:
 144
 145 code::
 146 (
 147 q = 5;
 148 w = Window.new;
 149
 150 h = HLayoutView(w,Rect(0,0,300,300));
 151 h.resize = 5; // elastic
 152
 153 Array.fill(q,{ arg i;
 154     var s;
 155     s =     StaticText(h,120@20).string_("Some short text which wraps around");
 156
 157     s.resize = 5;
 158     s.setProperty(\minWidth,10);
 159     s.setProperty(\maxWidth,120);
 160
 161     // not working
 162     s.setProperty(\maxHeight,10);
 163     s.setProperty(\minHeight,10);
 164
 165     s.background = Color.white;
 166     s
 167 });
 168
 169 w.front
 170 )
 171 ::
 172
 173 Spacing:
 174
 175 code::
 176 (
 177 q = 10;
 178 w = Window.new;
 179
 180 h = HLayoutView(w,Rect(0,0,300,300));
 181 h.setProperty(\spacing,0);
 182
 183 Array.fill(q,{
 184     Slider(h,Rect(0,0,20,75))
 185 });
 186
 187 w.front
 188 )
 189 ::