HelpSource/Classes/LinLin.schelp

   1 class:: LinLin
   2 summary:: Map a linear range to another linear range
   3 related:: Classes/LinExp
   4 categories::  UGens>Maths
   5
   6
   7 Description::
   8
   9 Maps a linear range of values to another linear range of values.
  10
  11
  12 classmethods::
  13
  14 method::ar, kr
  15
  16 argument::in
  17
  18 The input signal to convert.
  19
  20
  21 argument::srclo
  22
  23 Lower limit of input range.
  24
  25
  26 argument::srchi
  27
  28 Upper limit of input range.
  29
  30
  31 argument::dstlo
  32
  33 Lower limit of output range.
  34
  35
  36 argument::dsthi
  37
  38 Upper limit of output range.
  39
  40
  41 Examples::
  42
  43 code::
  44 // examples:
  45
  46 (
  47 {
  48         var mod = SinOsc.kr(Line.kr(1, 10, 10));
  49         SinOsc.ar(LinLin.kr(mod, -1,1, 100, 900)) * 0.1
  50 }.play;
  51 )
  52
  53 // modulating destination values.
  54 (
  55 {
  56         var mod = LFNoise2.ar(80);
  57         SinOsc.ar(LinLin.ar(mod, -1,1, MouseX.kr(200, 8000, 1), MouseY.kr(200, 8000, 1))) * 0.1
  58 }.play;
  59 )
  60
  61 // modulating source and destination values.
  62 (
  63 {
  64         var mod = LFNoise2.ar(80);
  65         SinOsc.ar(
  66                 LinLin.ar(mod,
  67                         SinOsc.kr(0.2), SinOsc.kr(0.2543),
  68                         MouseX.kr(200, 8000, 1), MouseY.kr(200, 8000, 1)
  69                 )
  70         ) * 0.1
  71 }.play;
  72 )
  73 ::
  74
  75 linlin and range can be used to create a LinLin implicitly from a ugen, mapping its output values from linear range to an exponential one. The rate is derived from the ugen.
  76
  77 code::
  78 // linlin
  79 (
  80 {
  81         var mod = LFNoise2.ar(80);
  82         SinOsc.ar(mod.linlin(-1,1, MouseX.kr(200, 8000, 1), MouseY.kr(200, 8000, 1))) * 0.1
  83 }.play;
  84 )
  85
  86 // range
  87 (
  88 {
  89         var mod = LFNoise2.ar(80).range(MouseX.kr(200, 8000, 1), MouseY.kr(200, 8000, 1));
  90         SinOsc.ar(mod) * 0.1
  91 }.play;
  92 )
  93 ::
  94