HelpSource/Classes/Osc.schelp

   1 class:: Osc
   2 summary:: Interpolating wavetable oscillator.
   3 related:: Classes/COsc, Classes/OscN, Classes/VOsc, Classes/VOsc3, Classes/Wavetable
   4 categories::  UGens>Generators>Deterministic
   5
   6
   7 Description::
   8
   9 Linear interpolating wavetable lookup oscillator with frequency and
  10 phase modulation inputs.
  11
  12
  13 This oscillator requires a buffer to be filled with a wavetable format
  14 signal. This preprocesses the Signal into a form which can be used
  15 efficiently by the Oscillator. The buffer size must be a power of 2.
  16
  17
  18 This can be acheived by creating a Buffer object and sending it one of
  19 the "b_gen" messages ( link::Classes/Buffer#-sine1::, link::Classes/Buffer#-sine2::, link::Classes/Buffer#-sine3:: ) with the wavetable flag set
  20 to true.
  21
  22
  23 This can also be achieved by creating a link::Classes/Signal:: object and sending it
  24 the 'asWavetable' message, thereby creating a Wavetable object in the required format. Then, the wavetable data may be transmitted to the server using the link::Classes/Buffer#*sendCollection:: or link::Classes/Buffer#*loadCollection:: methods.
  25
  26
  27 classmethods::
  28
  29 method::ar, kr
  30
  31 argument::bufnum
  32 Buffer index.
  33
  34 argument::freq
  35 Frequency in Hertz.
  36
  37 argument::phase
  38 Phase offset or modulator in radians.
  39
  40 argument::mul
  41 Output will be multiplied by this value.
  42
  43 argument::add
  44 This value will be added to the output.
  45
  46 Examples::
  47
  48 code::
  49
  50 (
  51 s = Server.local;
  52 b = Buffer.alloc(s, 512, 1);
  53 b.sine1(1.0/[1,2,3,4,5,6], true, true, true);
  54
  55 SynthDef("help-Osc",{ arg out=0,bufnum=0;
  56         Out.ar(out,
  57                 Osc.ar(bufnum, 200, 0, 0.5)
  58         )
  59 }).play(s,[\out, 0, \bufnum, b.bufnum]);
  60 )
  61
  62 (
  63 s = Server.local;
  64 b = Buffer.alloc(s, 512, 1);
  65 b.sine1(1.0/[1,2,3,4,5,6], true, true, true);
  66
  67 SynthDef("help-Osc",{ arg out=0,bufnum=0;
  68         Out.ar(out,
  69                 Osc.ar(bufnum, XLine.kr(2000,200), 0, 0.5)// modulate freq
  70         )
  71 }).play(s,[\out, 0, \bufnum, b.bufnum]);
  72 )
  73
  74
  75 (
  76 s = Server.local;
  77 b = Buffer.alloc(s, 512, 1);
  78 b.sine1([1.0], true, true, true);
  79
  80 SynthDef("help-Osc",{ arg out=0,bufnum=0;
  81         Out.ar(out,
  82                 Osc.ar(bufnum,
  83                         Osc.ar(bufnum,
  84                                 XLine.kr(1,1000,9),
  85                                 0,
  86                                 200,
  87                                 800),
  88                         0,
  89                         0.25)
  90         )
  91 }).play(s,[\out, 0, \bufnum, b.bufnum]);
  92 )
  93
  94
  95 (
  96 // modulate phase
  97 s = Server.local;
  98 b = Buffer.alloc(s, 512, 1);
  99 b.sine1([1.0], true, true, true);
 100
 101 SynthDef("help-Osc",{ arg out=0,bufnum=0;
 102         Out.ar(out,
 103                 Osc.ar(bufnum,
 104                                 800,
 105                                 Osc.ar(bufnum,
 106                                                 XLine.kr(20,8000,10),
 107                                                 0,
 108                                                 2pi),
 109                                 0.25)
 110         )
 111 }).play(s,[\out, 0, \bufnum, b.bufnum]);
 112 )
 113
 114
 115
 116 (
 117 // change the buffer while its playing
 118 s = Server.local;
 119 b = Buffer.alloc(s, 4096, 1);
 120 b.sine1(1.0/[1,2,3,4,5,6], true, true, true);
 121
 122 SynthDef("help-Osc",{ arg out=0,bufnum=0;
 123         Out.ar(out,
 124                 Osc.ar(bufnum, [80,80.2], 0, 0.2)
 125         )
 126 }).play(s,[\out, 0, \bufnum, b.bufnum]);
 127 )
 128
 129 (
 130 fork {
 131         var n = 32;
 132         50.do {
 133                 b.sine1(Array.rand(n,0,1).cubed, true, true, true);
 134                 0.25.wait;
 135         };
 136 };
 137 )
 138
 139 ::
 140