HelpSource/Classes/Pbindef.schelp

   1 class:: Pbindef
   2 summary:: incremental event pattern reference definition
   3 categories:: Libraries>JITLib>Patterns
   4 related:: Classes/Pdef, Classes/Pbind
   5
   6 description::
   7 Pbindef keeps a reference to a Pbind in which single keys can be replaced, combining link::Classes/PbindProxy:: and link::Classes/Pdef::. It plays on when the old stream ended and a new stream is set and schedules the changes to the beat.
   8
   9 the difference to Pdef is that it allows to incrementally change the elementary patterns (patternpairs) of a Pbind - also of an already existing Pbind inside a Pdef.
  10
  11 Pbindef and Pdef use the same global collection, while Pdef and Pdefn use separate ones.
  12
  13 Pbindef inherits most methods from link::Classes/Pdef::. Overview: link::Overviews/JITLib::
  14
  15 ClassMethods::
  16
  17 method::new
  18 store the pattern in the global dictionary of link::Classes/Pdef:: under key. (if there is already a Pdef there, replace its pattern with the new one. If there is already a strong::Pbindef:: there, set the parameters only, or add a new one (the whole pattern is replaced).
  19
  20 Using strong::*new(key):: you can access the pattern at that key (if none is there, a default pattern is created). see link::Classes/Pdef::.
  21
  22 Examples::
  23
  24 code::
  25 (
  26 SynthDef("Pdefhelp", { arg out, freq, sustain=1, amp=1, pan;
  27         var env, u=1;
  28         env = EnvGen.kr(Env.perc(0.01, sustain), 1, doneAction:2);
  29         5.do { var d; d = exprand(0.01, 1); u = SinOsc.ar(d * 300, u, rrand(0.1,1.2) * d, 1) };
  30         Out.ar(out, Pan2.ar(SinOsc.ar(u + 1 * freq, 0, amp * env), pan));
  31 }).add;
  32 )
  33 s.boot;
  34
  35
  36 Pbindef(\a, \instrument, \Pdefhelp).play;
  37 Pbindef(\a, \degree, Pseq([0, 2, 5b, 1b], inf));
  38 Pbindef(\a, \dur, 0.1);
  39 Pbindef(\a, \degree, Pseq([1b, 5, 3, 1b, 6, 2, 5, 0, 3, 0, 2], inf));
  40 Pbindef(\a, \legato, Prand([1.0, 2.4, 0.2], inf), \mtranspose, -3);
  41 Pbindef(\a, \mtranspose, nil); // remove key
  42
  43 Pbindef(\a, \degree, Pseq([1, 2, 3, 4, 5, 6], 1));
  44 Pbindef(\a, \degree, Pseq([1, 2, 3, 4, 5, 6], 3), \dur, 0.02);
  45 Pbindef(\a, \degree, Pseq([1, 2, 3, 4, 5, 6], 3), \dur, 0.1);
  46
  47 // apart from this Pbindef behaves like Pdef:
  48
  49 Pbindef(\a).quant = 0.0;
  50 Pbindef(\a, \degree, Pseq([1, 2, 3, 4, 5, 6], 1));
  51
  52 Pbindef(\a).stop;
  53 Pbindef(\a, \degree, Pseq([1, 2, 3, 4, 5, 6], 1)); // does not resume now
  54
  55 Pbindef(\a).playOnce; // play single instance
  56 Pseq([Pbindef(\a), Pdef(\a)]).play; // same here (Pdef(\a) is the same pattern as Pbindef))
  57
  58 Pbindef(\a) === Pdef(\a) // identical.
  59
  60
  61
  62 // an already existing Pdef can be incrementally changed
  63
  64 Pdef(\x, Pbind(\instrument, \Pdefhelp, \dur, 0.3));
  65 Pdef(\x).play;
  66
  67 Pbindef(\x, \degree, 7.rand);
  68 Pbindef(\x, \degree, Pseq([0, 7, 3, 7, 4], inf), \dur, Pn(Pseries(0.2, -0.02, 10)));
  69 Pbindef(\x, \stretch, 2);
  70 ::