HelpSource/Classes/Pbrown.schelp

   1 class:: Pbrown
   2 summary:: brownian motion pattern
   3 related:: Classes/BrownNoise, Classes/Pgbrown
   4 categories:: Streams-Patterns-Events>Patterns>Random
   5
   6 description::
   7
   8 Returns a stream that behaves like a brownian motion.
   9
  10 ClassMethods::
  11
  12 method::new
  13
  14 argument::lo
  15 lower boundary of values.
  16
  17 argument::hi
  18 upper boundary of values.
  19
  20 argument::step
  21 maximum change per step - the distribution is xrand2.
  22
  23 argument::length
  24 number of values produced.
  25
  26 Examples::
  27
  28 code::
  29 (
  30 var a;
  31 a = Pbrown(0.0, 1.0, 0.1, inf);
  32 c = a.asStream.nextN(500);
  33 w = Window.new("Pbrown", Rect(10, 10, 540, 800));
  34 // plot the values
  35 c.plot(bounds: Rect(10, 10, 520, 380), discrete: true, parent: w);
  36 // a histogram of the values
  37 c.histo(500).plot(bounds: Rect(10, 410, 520, 380), parent: w);
  38 )
  39
  40 (
  41 var a;
  42 a = Pbrown(0.0, 1.0, 0.2, inf);
  43 a.asStream.nextN(1000).plot2;
  44 )
  45 ::
  46
  47 code::
  48 // sound example
  49 (
  50 SynthDef(\help_sinegrain,
  51         { arg out=0, freq=440, sustain=0.05;
  52                 var env;
  53                 env = EnvGen.kr(Env.perc(0.01, sustain, 0.2), doneAction:2);
  54                 Out.ar(out, SinOsc.ar(freq, 0, env))
  55         }).add;
  56 )
  57
  58
  59 (
  60 var a;
  61 a = Pbrown(0.0, 1.0, 0.1, inf).asStream;
  62 {
  63         loop {
  64                 Synth(\help_sinegrain, [\freq, a.next * 600 + 300]);
  65                 0.02.wait;
  66         }
  67 }.fork;
  68 )
  69
  70
  71
  72 // parallel browninan motions
  73 (
  74 var a, x, f;
  75 a = Pbrown(0.0, 1.0, 0.1, inf);
  76
  77 f = { |pattern, dt=0.02, min=300, max=900|
  78         {
  79                 var x = pattern.asStream;
  80                 loop {
  81                         Synth.grain(\help_sinegrain, [\freq, x.next.linexp(0, 1, min, max), \sustain, dt]);
  82                         dt.wait;
  83                 }
  84         }.fork;
  85 }.flop;
  86
  87 // 3 parallel motions
  88 f.(a, [0.02, 0.08, 0.16]);
  89 )
  90 ::