HelpSource/Tutorials/Getting-Started/14-Scheduling-Events.schelp

   1 title:: 14. Scheduling Events
   2 summary:: Getting Started With SuperCollider
   3 categories:: Tutorials>Getting-Started
   4 related:: Tutorials/Getting-Started/00-Getting-Started-With-SC
   5
   6 Music happens over time, and to make effective music, it's necessary to control when things happen. In SuperCollider, this is done by scheduling things on clocks.
   7
   8 section::Clocks
   9
  10 A clock in SuperCollider has two major functions. It knows what time it is, and it knows what time things are supposed to happen, so that it can wake them up at just the right time.
  11
  12 Musical sequencing will usually use link::Classes/TempoClock::, because you can change its tempo and it is also aware of meter changes. Two other kinds of clock exist: link::Classes/SystemClock::, which always runs in seconds, and link::Classes/AppClock::, which also runs in seconds but has a lower system priority (so it is better for graphic updates and other activities that are not time critical).
  13
  14 section::Scheduling
  15
  16 Scheduling means to tell the clock to execute something at some time in the future. So, you need to have the thing to schedule, and a number indicating the time.
  17
  18 Let's have SuperCollider say hello, 5 seconds from now.
  19
  20 code::
  21 SystemClock.sched(5, { "hello".postln });
  22 ::
  23
  24 Notice that when you do this, 'SystemClock' prints immediately. Every time you run something in SuperCollider, it has to return a value right away; the method's return value is the clock. Before returning, however, the clock 'remembers' the function, and that you wanted it to run 5 seconds later. And indeed, 'hello' appears in the post window, right on cue. code::{ "hello".postln } :: is an emphasis::asynchronous:: action: it runs emphasis::after:: its code block has already returned.
  25
  26 strong::sched:: does emphasis::relative:: scheduling. The actual time when the function runs is x seconds (or beats, for TempoClock) later than the time the .sched call occurred. It is also possible to schedule for an exact time point, provided you know what time it is on the clock. strong::schedAbs:: handles emphasis::absolute:: scheduling.
  27
  28 code::
  29 (
  30 var timeNow = TempoClock.default.beats;
  31 "Time is now: ".post; timeNow.postln;
  32 "Scheduling for: ".post; (timeNow + 5).postln;
  33 TempoClock.default.schedAbs(timeNow + 5,
  34         { "Time is later: ".post; thisThread.clock.beats.postln; nil });
  35 )
  36 ::
  37
  38 Note that we have moved to TempoClock, since this is the most commonly used. While there is only one SystemClock, there can be many TempoClocks all running at different speeds, if need be. One TempoClock is the default, accessed by code::TempoClock.default:: -- we will use this throughout. (To save typing, you may wish to assign a TempoClock to a variable, for instance, code::t = TempoClock.default ::.)
  39
  40 For fun, change the tempo and run the last example again:
  41
  42 code::
  43 (
  44 var timeNow;
  45 TempoClock.default.tempo = 2;   // 2 beats/sec, or 120 BPM
  46 timeNow = TempoClock.default.beats;
  47 "Time is now: ".post; timeNow.postln;
  48 "Scheduling for: ".post; (timeNow + 5).postln;
  49 TempoClock.default.schedAbs(timeNow + 5,
  50         { "Time is later: ".post; thisThread.clock.beats.postln; nil });
  51 )
  52 ::
  53
  54 Notice that the 'Time is later' message shows up after a shorter delay, but the difference between the two times is still 5.
  55
  56 section::What time is it?
  57
  58 Inside a scheduled function, you might want to know which clock is running the function. code::thisThread.clock:: tells you this -- don't worry for now about how it knows, just know that you can use this to find out.
  59
  60 Once you know the clock, you can find out what time it is using strong::beats:: :
  61
  62 code::
  63 SystemClock.beats;
  64 TempoClock.default.beats;
  65 AppClock.beats;
  66 thisThread.clock.beats;
  67 ::
  68
  69 section::What can you schedule?
  70
  71 Suppose we schedule "hello" by itself.
  72
  73 code::
  74 TempoClock.default.sched(5, "hello");
  75 ::
  76
  77 Nothing happens. That's because "hello" is just a value -- it doesn't do anything. The lesson is that it makes sense to schedule objects that will emphasis::take some action::.
  78
  79 code::
  80 Function
  81 Routine
  82 Task
  83 ::
  84
  85 Routines and Tasks will be covered in the next section, and Functions we have already seen. There are some others, but these are the best starting point.
  86
  87 section::Caution
  88
  89 If you schedule function that returns a number, the clock will treat that number as the amount of time before running the function again.
  90
  91 code::
  92 // fires many times (but looks like it should fire just once)
  93 TempoClock.default.sched(1, { rrand(1, 3).postln; });
  94 ::
  95
  96 This will keep going forever, until you stop it with cmd-.
  97
  98 If you want the function to run only once, make sure to end the function with 'nil':
  99
 100 code::
 101 // fires once
 102 TempoClock.default.sched(1, { rrand(1, 3).postln; nil });
 103 ::
 104
 105 It's easy to return a number by mistake, and get an ongoing activity when you wanted a one-shot action.
 106
 107 If that number happens to be 0, or negative, something worse happens. The function will run again immediately. And, if the number is always 0, it creates an infinite loop that can lock up SuperCollider.
 108
 109 That shouldn't scare you off of scheduling -- this is less likely to happen with Routines and Tasks, which you will use more often. But you should be aware of it.
 110
 111 For more: link::Classes/SystemClock::, link::Classes/TempoClock::, link::Classes/AppClock::, link::Classes/Function::
 112
 113 ____________________
 114
 115 This document is part of the tutorial strong::Getting Started With SuperCollider::.
 116
 117 Click here to go on to the next section: link::Tutorials/Getting-Started/15-Sequencing-with-Routines-and-Tasks::
 118
 119 Click here to return to the table of Contents: link::Tutorials/Getting-Started/00-Getting-Started-With-SC::