HelpSource/Classes/AmpComp.schelp

   1 class:: AmpComp
   2 summary:: Basic psychoacoustic amplitude compensation.
   3 related:: Classes/AmpCompA
   4 categories::  UGens>Analysis>Amplitude
   5
   6
   7 Description::
   8
   9 Implements the (optimized) formula:
  10
  11 code::
  12 compensationFactor = (root / freq) ** exp
  13 ::
  14
  15
  16 Higher frequencies are normally perceived as louder, which AmpComp
  17 compensates.
  18
  19
  20 classmethods::
  21
  22 method::ar, kr, ir
  23
  24 argument::freq
  25
  26 Input frequency value. For freq == root, the output is 1.0.
  27
  28
  29 argument::root
  30
  31 Root freq relative to which the curve is calculated
  32 (usually lowest freq).
  33
  34
  35 argument::exp
  36
  37 Exponent: how steep the curve decreases for increasing freq.
  38
  39 discussion::
  40 Note that for frequencies very much smaller than root the amplitudes can become very high.
  41 In this case limit the freq with code::freq.max(minval)::, or use AmpCompA.
  42
  43 Examples::
  44
  45 code::
  46 // compare a sine without compensation
  47
  48 { SinOsc.ar(MouseX.kr(300, 15000, 1)) * 0.1 }.play;
  49
  50 // with one that uses amplitude compensation
  51 (
  52 {
  53         var freq;
  54         freq = MouseX.kr(300, 15000, 1);
  55         SinOsc.ar(freq) * 0.1 * AmpComp.kr(freq, 300)
  56 }.play;
  57 )
  58
  59
  60 // different sounds cause quite different loudness perception,
  61 // and the desired musical behavior can vary, so the exponent can be tuned:
  62 (
  63 {
  64         var freq;
  65         freq = MouseX.kr(300, 15000, 1);
  66         Pulse.ar(freq) * 0.1 * AmpComp.kr(freq, 300, 1.3)
  67 }.play;
  68 )
  69
  70 // the curves:
  71
  72 // exp = 0.3333
  73 (200,210..10000).collect {|freq| (200/freq) ** 0.3333 }.plot;
  74
  75 // nearly linear for semitone steps:
  76
  77 (48..72).midicps.collect {|freq| (48.midicps/freq) ** 0.3333 }.plot;
  78 { AmpComp.ar(Line.ar(48, 72, 1).midicps, 48.midicps) }.plot(1.0);
  79
  80 // exp = 1.2
  81 (200,210..10000).collect {|freq| (200/freq) ** 1.2 }.plot;
  82 (48..72).midicps.collect {|freq| (200/freq) ** 1.2 }.plot;
  83 { AmpComp.ar(Line.ar(48, 72, 1).midicps, 48.midicps, 1.2) }.plot(1.0);
  84
  85
  86 // amplitude compensation in frequency modulation
  87 (
  88 {
  89         var freq;
  90         freq = MouseX.kr(300, 15000, 1);
  91         freq = freq * SinOsc.ar(MouseY.kr(3, 200, 1), 0, 0.5, 1);
  92         SinOsc.ar(freq) * 0.1 * AmpComp.ar(freq, 300)
  93 }.play;
  94 )
  95
  96 // without amplitude compensation
  97 (
  98 {
  99         var freq;
 100         freq = MouseX.kr(300, 15000, 1);
 101         freq = freq * SinOsc.ar(MouseY.kr(3, 200, 1), 0, 0.5, 1);
 102         SinOsc.ar(freq) * 0.1
 103 }.play;
 104 )
 105
 106 // in granular synthesis:
 107 (
 108 SynthDef("pgrain",
 109         { arg out = 0, sustain=0.01, amp=0.5, pan = 0;
 110                 var freq = MouseX.kr(300, 7000, 1);
 111                 var window = Env.sine(sustain, amp * AmpComp.ir(freq));
 112                 Out.ar(out,
 113                         Pan2.ar(
 114                                 SinOsc.ar(freq),
 115                                 pan
 116                         ) * EnvGen.ar(window, doneAction:2)
 117                 )
 118         }
 119 ).send(s);
 120 )
 121
 122 // send grains
 123 (
 124 fork {
 125         loop {
 126                 s.sendBundle(0.1, [\s_new, \pgrain, -1,1,1]);
 127                 0.02.wait;
 128         };
 129 }
 130 )
 131
 132
 133 // try different synth defs:
 134
 135
 136 // without AmpComp:
 137
 138 (
 139 SynthDef("pgrain",
 140         { arg out = 0, sustain=0.01, amp=0.5, pan = 0;
 141                 var freq = MouseX.kr(300, 7000, 1);
 142                 var window = Env.sine(sustain, amp);
 143                 Out.ar(out,
 144                         Pan2.ar(
 145                                 SinOsc.ar(freq),
 146                                 pan
 147                         ) * EnvGen.ar(window, doneAction:2)
 148                 )
 149         }
 150 ).send(s);
 151 )
 152
 153 // with AmpCompA
 154 (
 155 SynthDef("pgrain",
 156         { arg out = 0, sustain=0.01, amp=0.5, pan = 0;
 157                 var freq = MouseX.kr(300, 7000, 1);
 158                 var window = Env.sine(sustain, amp * AmpCompA.ir(freq));
 159                 Out.ar(out,
 160                         Pan2.ar(
 161                                 SinOsc.ar(freq),
 162                                 pan
 163                         ) * EnvGen.ar(window, doneAction:2)
 164                 )
 165         }
 166 ).send(s);
 167 )
 168 ::
 169