HelpSource/Classes/Formlet.schelp

   1 class:: Formlet
   2 summary:: FOF-like filter.
   3 related:: Classes/RHPF, Classes/RLPF, Classes/Resonz, Classes/Ringz
   4 categories::  UGens>Filters>Linear
   5
   6
   7 Description::
   8
   9 This is a resonant filter whose impulse response is like that of a sine
  10 wave with a  link::Classes/Decay2::  envelope over it. It is possible to
  11 control the attacktime and decaytime.
  12
  13 Formlet is equivalent to:
  14 code::
  15 Ringz(in, freq, decaytime) - Ringz(in, freq, attacktime)
  16 ::
  17
  18 The great advantage to this filter over FOF is that there is no limit to
  19 the number of overlapping grains since the grain is just the impulse
  20 response of the filter.
  21
  22
  23 classmethods::
  24
  25 method::ar, kr
  26
  27 argument::in
  28 The input signal.
  29
  30 argument::freq
  31 Resonant frequency in Hertz.
  32
  33 argument::attacktime
  34 60 dB attack time in seconds.
  35
  36 argument::decaytime
  37 60 dB decay time in seconds.
  38
  39 argument::mul
  40
  41 argument::add
  42
  43 discussion::
  44 Note that if attacktime == decaytime then the signal cancels out and if
  45 attacktime > decaytime then the impulse response is inverted.
  46
  47
  48 Examples::
  49
  50 code::
  51 { Formlet.ar(Impulse.ar(20, 0.5), 1000, 0.01, 0.1) }.play;
  52
  53 { Formlet.ar(Blip.ar(XLine.kr(10,400,8), 1000, 0.1), 1000, 0.01, 0.1) }.play;
  54
  55 (
  56 // modulating formant frequency
  57 {
  58         var in;
  59         in = Blip.ar(SinOsc.kr(5,0,20,300), 1000, 0.1);
  60         Formlet.ar(in, XLine.kr(1500,700,8), 0.005, 0.04);
  61 }.play;
  62 )
  63
  64 (
  65 // mouse control of frequency and decay time.
  66 {
  67         var in;
  68         in = Blip.ar(SinOsc.kr(5,0,20,300), 1000, 0.1);
  69         Formlet.ar(in,
  70                 MouseY.kr(700,2000,1),
  71                 0.005, MouseX.kr(0.01,0.2,1));
  72 }.play;
  73 )
  74
  75 (
  76 // mouse control of frequency and decay time.
  77 {
  78         var freq;
  79         freq = Formlet.kr(
  80                 Dust.kr(10 ! 2),
  81                 MouseY.kr(7,200,1),
  82                 0.005, MouseX.kr(0.1,2,1)
  83         );
  84         SinOsc.ar(freq * 200 + [500, 600] - 100) * 0.2
  85 }.play;
  86 )
  87 ::
  88