HelpSource/Classes/Gendy2.schelp

   1 class:: Gendy2
   2 summary:: Dynamic stochastic synthesis generator.
   3 related:: Classes/Gendy1, Classes/Gendy3
   4 categories::  UGens>Generators>Stochastic
   5
   6
   7 Description::
   8
   9 See  link::Classes/Gendy1::  help file for background. This variant of
  10 GENDYN is closer to that presented in emphasis::Hoffmann, Peter. (2000) The New GENDYN Program. Computer Music Journal 24:2, pp 31-38::.
  11
  12 note::
  13 Random walk is of the amplitude and time delta, not the amp and time
  14 directly. The amplitude step random walk uses a lehmer style number
  15 generator whose parameters are accessible.
  16 ::
  17
  18 SuperCollider implementation by Nick Collins
  19
  20 classmethods::
  21
  22 method::ar, kr
  23
  24
  25 argument::ampdist
  26
  27 Choice of probability distribution for the next perturbation of
  28 the amplitude of a control point.
  29
  30 The distributions are (adapted from the GENDYN program in Formalized Music):
  31 table::
  32 ## 0: || LINEAR.
  33 ## 1: || CAUCHY.
  34 ## 2: || LOGIST.
  35 ## 3: || HYPERBCOS.
  36 ## 4: || ARCSINE.
  37 ## 5: || EXPON.
  38 ## 6: || SINUS.
  39 ::
  40
  41 Where the sinus (Xenakis' name) is in this implementation taken
  42 as sampling from a third party oscillator. See example below.
  43
  44 argument::durdist
  45
  46 Choice of distribution for the perturbation of the current inter
  47 control point duration.
  48
  49 argument::adparam
  50
  51 A parameter for the shape of the amplitude probability
  52 distribution, requires values in the range 0.0001 to 1 (there are
  53 safety checks in the code so don't worry too much if you want to
  54 modulate!).
  55
  56 argument::ddparam
  57
  58 A parameter for the shape of the duration probability
  59 distribution, requires values in the range 0.0001 to 1.
  60
  61
  62 argument::minfreq
  63
  64 Minimum allowed frequency of oscillation for the Gendy1
  65 oscillator, so gives the largest period the duration is allowed
  66 to take on.
  67
  68
  69 argument::maxfreq
  70
  71 Maximum allowed frequency of oscillation for the Gendy1
  72 oscillator, so gives the smallest period the duration is allowed
  73 to take on.
  74
  75
  76 argument::ampscale
  77
  78 Normally 0.0 to 1.0, multiplier for the distribution's delta
  79 value for amplitude. An ampscale of 1.0 allows the full range
  80 of  -1 to 1 for a change of amplitude.
  81
  82
  83 argument::durscale
  84
  85 Normally 0.0 to 1.0, multiplier for the distribution's delta
  86 value for duration. An ampscale of 1.0 allows the full range of
  87 -1 to 1 for a change of duration.
  88
  89
  90 argument::initCPs
  91
  92 Initialise the number of control points in the memory.
  93 Xenakis specifies 12. There would be this number of control
  94 points per cycle of the oscillator, though the oscillator's
  95 period will constantly change due to the duration distribution.
  96
  97
  98 argument::knum
  99
 100 Current number of utilised control points, allows modulation.
 101
 102
 103 argument::a
 104
 105 Parameter for Lehmer random number generator perturbed by
 106 Xenakis as in
 107
 108 code::
 109 ((old*a)+c)%1.0
 110 ::
 111
 112 argument::c
 113
 114 Parameter for Lehmer random number generator perturbed by
 115 Xenakis.
 116
 117
 118 argument::mul
 119 Output will be multiplied by this value.
 120
 121 argument::add
 122 This value will be added to the output.
 123
 124 discussion::
 125 All parameters can be modulated at control rate except for code::initCPs:: which is used only at initialisation.
 126
 127
 128 Examples::
 129 warning::
 130 if you have lots of CPs and you have fast frequencies, the CPU cost goes up a lot because a new CP move happens every sample!
 131 ::
 132
 133 code::
 134 //LOUD! defaults like a rougher Gendy1
 135 {Pan2.ar(Gendy2.ar)}.play
 136
 137 //advantages of messing with the random number generation- causes periodicities
 138 {Pan2.ar(Gendy2.ar(a:MouseX.kr(0.0,1.0),c:MouseY.kr(0.0,1.0)))}.play
 139
 140 (
 141 {Pan2.ar(
 142 Normalizer.ar(
 143 RLPF.ar(
 144 RLPF.ar(Gendy2.ar(a:SinOsc.kr(0.4,0,0.05,0.05),c:SinOsc.kr(0.3,0,0.1,0.5)),
 145 MouseX.kr(10,10000,'exponential'),0.05),
 146 MouseY.kr(10,10000,'exponential'),0.05)
 147 ,0.9)
 148 ,Lag.kr(LFNoise0.kr(1),0.5))}.play
 149 )
 150
 151
 152
 153 {Pan2.ar(Gendy2.ar(3,5,1.0,1.0,50,1000,MouseX.kr(0.05,1),MouseY.kr(0.05,1),15, 0.05,0.51,mul:0.5))}.play
 154
 155
 156 //play me
 157 {Pan2.ar(RLPF.ar(Gendy2.ar(1,3,minfreq:20,maxfreq:MouseX.kr(100,1000),durscale:0.0,initCPs:4),500,0.3, 0.2),0.0)}.play
 158
 159
 160 //1 CP = random noise effect
 161 {Pan2.ar(Gendy2.ar(initCPs:1))}.play
 162
 163 //2 CPs = suudenly an oscillator (though a fast modulating one here)
 164 {Pan2.ar(Gendy2.ar(initCPs:2))}.play
 165
 166
 167 //used as an LFO
 168 (
 169 {Pan2.ar(SinOsc.ar(Gendy2.kr(2,1,SinOsc.kr(0.1,0,0.49,0.51),SinOsc.kr(0.13,0,0.49,0.51),
 170 3.4,3.5, SinOsc.kr(0.17,0,0.49,0.51), SinOsc.kr(0.19,0,0.49,0.51),10,10,mul:50, add:350), 0, 0.3), 0.0)}.play
 171 )
 172
 173 //very angry wasp
 174 {Pan2.ar(Gendy2.ar(0, 0, SinOsc.kr(0.1, 0, 0.1, 0.9),1.0, 50,1000, 1,0.005, 12, 12, 0.2,0.2,0.2), 0.0)}.play
 175
 176
 177 //modulate distributions
 178 //change of pitch as distributions change the duration structure and spectrum
 179 {Pan2.ar(Gendy2.ar(MouseX.kr(0,7),MouseY.kr(0,7),mul:0.2), 0.0)}.play
 180
 181
 182 //modulate num of CPs
 183 {Pan2.ar(Gendy2.ar(knum:MouseX.kr(1,13),mul:0.2), 0.0)}.play
 184
 185
 186 (//Gendy1 into Gendy2...with cartoon side effects
 187 {Pan2.ar(Gendy2.ar(maxfreq:Gendy1.kr(5,4,0.3, 0.7, 0.1, MouseY.kr(0.1,10),
 188     1.0, 1.0, 5,5, 500, 600), knum:MouseX.kr(1,13),mul:0.2), 0.0)}.play
 189 )
 190
 191 //use SINUS to track any oscillator and take CP positions from it, use adparam and ddparam as the inputs to sample
 192 {Pan2.ar(Gendy2.ar(6,6,LFPulse.kr(100, 0, 0.4, 1.0), SinOsc.kr(30, 0, 0.5),mul:0.2), 0.0)}.play
 193
 194
 195 (//try out near the corners especially
 196 {Pan2.ar(Gendy2.ar(6,6,LFPulse.kr(MouseX.kr(0,200), 0, 0.4, 1.0),
 197     SinOsc.kr(MouseY.kr(0,200), 0, 0.5),mul:0.2), 0.0)}.play
 198 )
 199
 200 //texture- the howling wind?
 201 (
 202 {
 203     Mix.fill(10,{
 204     var freq;
 205
 206     freq= rrand(130,160.3);
 207     Pan2.ar(SinOsc.ar(Gendy2.ar(6.rand,6.rand,SinOsc.kr(0.1,0,0.49,0.51),SinOsc.kr(0.13,0,0.49,0.51),
 208         freq ,freq, SinOsc.kr(0.17,0,0.49,0.51), SinOsc.kr(0.19,0,0.49,0.51),
 209         12, 12, 0.4.rand, 0.4.rand, 200, 400), 0, 0.1), 1.0.rand2)
 210     });
 211 }.play
 212 )
 213
 214 //CAREFUL! mouse to far right causes explosion of sound
 215 (
 216 {Pan2.ar(
 217 CombN.ar(
 218 Resonz.ar(
 219 Gendy2.ar(2,3,minfreq:1, maxfreq:MouseX.kr(10,700), initCPs:100),
 220 MouseY.kr(50,1000), 0.1)
 221 ,0.1,0.1,5, 0.16
 222 )
 223 , 0.0)}.play
 224 )
 225
 226 //storm
 227 (
 228 {
 229     var n;
 230     n=15;
 231
 232     0.5*Mix.fill(n,{
 233     var freq, numcps;
 234
 235     freq= rrand(130,160.3);
 236     numcps= rrand(2,20);
 237     Pan2.ar(Gendy2.ar(6.rand,6.rand,10.0.rand,10.0.rand,freq,freq*exprand(1.0,2.0),
 238         10.0.rand, 10.0.rand, numcps, SinOsc.kr(exprand(0.02,0.2), 0, numcps/2, numcps/2),
 239         10.0.rand, 10.0.rand, 0.5/(n.sqrt)), 1.0.rand2)
 240     });
 241 }.play
 242 )
 243
 244 //another traffic moment
 245 (
 246 {
 247     var n;
 248     n=10;
 249
 250     Resonz.ar(
 251     Mix.fill(n,{
 252     var freq, numcps;
 253
 254     freq= rrand(50,560.3);
 255     numcps= rrand(2,20);
 256     Pan2.ar(Gendy2.ar(6.rand,6.rand,1.0.rand,1.0.rand,freq ,freq,
 257         1.0.rand, 1.0.rand, numcps, SinOsc.kr(exprand(0.02,0.2), 0,
 258         numcps/2, numcps/2), 0.5/(n.sqrt)), 1.0.rand2)
 259     })
 260     ,MouseX.kr(100,2000), MouseY.kr(0.01,1.0), 0.3)
 261     ;
 262     }.play
 263 )
 264 ::
 265