HelpSource/Classes/PackFFT.schelp

   1 class:: PackFFT
   2 summary:: Pack separate demand-rate FFT bin streams into an FFT chain buffer
   3 categories:: UGens>FFT
   4 related:: Classes/UnpackFFT
   5
   6 description::
   7 Takes an array of magnitudes and phases, and packs them into an FFT buffer ready for transforming back into time-domain audio using IFFT.
   8
   9 Most people won't need to use this directly - instead, use pvcollect, pvcalc, or pvcalc2 methods from the link::Classes/PV_ChainUGen:: base class.
  10
  11 classmethods::
  12 private:: categories
  13
  14 method:: new
  15
  16 argument:: chain
  17 The link::Classes/FFT:: chain
  18
  19 argument:: bufsize
  20 FFT buffer size
  21
  22 argument:: magsphases
  23 The input data should be a flat array containing magnitude and phase of all bins in ascending order.
  24 e.g. code:: [mag0, phase0, mag1, phase1, mag2, phase2, ... magN, phaseN] ::
  25 This input is typically demand-rate.
  26
  27 argument:: frombin
  28 restricts the frequency band
  29
  30 argument:: tobin
  31 restricts the frequency band
  32
  33 argument:: zeroothers
  34 set to 1 to zero all the magnitudes outside the restricted frequency band
  35
  36 discussion::
  37 This is technically similar to Demand or Duty in that it calls demand-rate UGens further up the graph to process the values, eventually calling UnpackFFT. These two ends of the process must in most cases see the same chain...! Otherwise behaviour is undefined and, who knows, possibly unpleasant.
  38
  39 Optional parameters: frombin and tobin allow you to fill the supplied data only into a subset of the FFT bins (i.e. a single delimited frequency band), and if you do this, you can also optionally set zeroothers to 1 to zero all the magnitudes outside this band (otherwise they stay intact).
  40
  41 examples::
  42 Here's an unusual example which uses PackFFT without using UnpackFFT first - essentially creating our FFT data from scratch.
  43 code::
  44 // Reminder: This isn't the intended typical usage! It's OK to do this though.
  45 (
  46 x = {
  47         var mags, phases, chain, sig;
  48         // Create simple undulating magnitudes
  49         mags = {FSinOsc.kr(ExpRand(0.1, 1)).range(0, 1)}.dup(100);
  50         // Then give them a "rolloff" to make the sound less unpleasant
  51         mags = mags  * ((1, 0.99 .. 0.01).squared);
  52         // Let's turn the bins on and off at different rates, I'm *sure* that'll sound interesting
  53         mags = mags * {LFPulse.kr(2 ** IRand(-3, 5)).range(0, 1)}.dup(100);
  54         // Let's ignore phase for now
  55         phases = 0.dup(100);
  56         // We need to create an FFT chain to feed our data in to.
  57         // The easiest way is to do an FFT on some signal which we then ignore!
  58         chain = FFT(LocalBuf(512), FSinOsc.ar);
  59         // Now we can do the packing
  60         chain = PackFFT(chain, 512, [mags, phases].flop.flatten, 0, 99, 1);
  61         sig = IFFT(chain);
  62         Out.ar(0, sig.dup);
  63 }.play(s);
  64 )
  65 x.free;
  66 ::
  67