HelpSource/Classes/PopUpMenu.schelp

   1 CLASS:: PopUpMenu
   2 redirect:: implClass
   3 summary:: A view displaying a text item selectable from a drop-down menu.
   4 categories:: GUI>Views
   5
   6 DESCRIPTION::
   7
   8 When clicked, this view opens a menu containing several text items, then closes the menu and displays one of the items after it is selected.
   9
  10 CLASSMETHODS::
  11
  12 PRIVATE:: key
  13
  14
  15
  16
  17 INSTANCEMETHODS::
  18
  19
  20
  21 SUBSECTION:: Data
  22
  23 METHOD:: items
  24         The list of items displayed in a menu when the view is clicked.
  25
  26         argument::
  27                 An Array of Strings or Symbols.
  28
  29 METHOD:: item
  30         The currently selected item.
  31
  32         returns::
  33                 A String.
  34
  35 METHOD:: value
  36         The index of the currently selected item.
  37
  38         argument::
  39                 An integer, or nil meaning no selected item.
  40
  41 METHOD:: valueAction
  42         Sets link::#-value:: and triggeres link::#-action::.
  43
  44         argument::
  45                 An integer, or nil meaning no selected item.
  46
  47
  48
  49 SUBSECTION:: Appearance
  50
  51 METHOD:: stringColor
  52         The color used to display text.
  53
  54         argument::
  55                 A Color.
  56
  57 METHOD:: background
  58         Setting this variable colors the area of the view under the text with the given color.
  59
  60         argument::
  61                 A Color.
  62
  63
  64
  65 SUBSECTION:: Interaction
  66
  67 METHOD:: allowsReselection
  68         Determines whether the action is triggered when selecting already selected item. Defaults to false.
  69
  70         argument::
  71                 A Boolean.
  72
  73
  74
  75 SUBSECTION:: Actions
  76
  77 METHOD:: action
  78         The action object evaluated whenever the user changes the selected item from the menu. See link::#-allowsReselection:: for customization.
  79
  80
  81
  82 SUBSECTION:: Drag and drop
  83
  84 METHOD:: defaultGetDrag
  85         returns::
  86                 The link::#-value::.
  87
  88 METHOD:: defaultCanReceiveDrag
  89         returns::
  90                 True if the current drag data is a number.
  91
  92 METHOD:: defaultReceiveDrag
  93         Sets link::#-valueAction:: to the current drag data.
  94
  95
  96
  97 EXAMPLES::
  98
  99 subsection:: Basic Example
 100
 101 code::
 102 (
 103 w = Window.new("The Eightfold Path").front;
 104 m = PopUpMenu(w,Rect(10,10,180,20));
 105
 106 m.items = [
 107     "right view","right thinking","right mindfulness","right speech",
 108     "right action","right diligence","right concentration","right livelihood"
 109 ];
 110
 111 m.background_(Color.green(0.7));        // only changes the look of displayed item
 112 m.stringColor_(Color.white);            // only changes the look of displayed item
 113 m.font_(Font("Courier", 13));           // only changes the look of displayed item
 114 m.action = { arg menu;
 115     [menu.value, menu.item].postln;
 116 };
 117 )
 118
 119 m.value;            // returns the index of the current item;
 120 m.item;             // returns the String or Symbol of the current item
 121
 122 m.value_(2);        // changes the displayed item, but does not evaluate the action
 123 m.valueAction_(3);  // evaluates the action.
 124 ::
 125
 126 subsection:: Sound Example
 127
 128 Play different functions:
 129
 130 code::
 131 (
 132 s.waitForBoot({
 133
 134     var w,menu,snd,funcs,b;
 135
 136     w=Window.new.front;
 137
 138     menu=PopUpMenu(w,Rect(10,10,90,20))
 139         .items_(["Sine" , "Saw" , "Noise" , "Pulse"]);
 140
 141     funcs=[
 142         {SinOsc.ar(440,0,0.3)},
 143         {Saw.ar(440,0.3)},
 144         {WhiteNoise.ar(0.3)},
 145         {Pulse.ar(440,0.2,0.3)}
 146     ];
 147
 148     b=Button(w,Rect(110,10,180,20))
 149         .states_([["play",Color.black,Color.green]])
 150         .mouseDownAction_({
 151                 snd = funcs.at(menu.value).play;
 152             })
 153         .action_({ arg butt, mod;
 154                 snd.free;
 155             });
 156
 157     w.front;
 158
 159     p=CmdPeriod.add({b.value_(0)}); // set button to 0 on hitting Cmd-period
 160     w.onClose_{ snd.free; CmdPeriod.removeAll }; // clean up when window is closed
 161
 162 })
 163 )
 164 ::