HelpSource/Classes/Sweep.schelp

   1 class:: Sweep
   2 summary:: Triggered linear ramp
   3 categories::  UGens>Triggers
   4
   5 Description::
   6
   7 Starts a linear raise by rate/sec from zero when trig input crosses from
   8 non-positive to positive.
   9
  10
  11 classmethods::
  12 private:: categories
  13
  14 method::ar, kr
  15
  16 argument::trig
  17
  18 triggers when trig input crosses from non-positive to positive.
  19
  20
  21 argument::rate
  22
  23 rate/sec raise rate
  24
  25
  26 Examples::
  27
  28 code::
  29 // using sweep to modulate sine frequency
  30 (
  31 { var trig;
  32         trig = Impulse.kr(MouseX.kr(0.5, 20, 1));
  33         SinOsc.ar(Sweep.kr(trig, 700) + 500, 0, 0.2)
  34 }.play;
  35 )
  36
  37
  38 // using sweep to index into a buffer
  39 b = Buffer.read(s, Platform.resourceDir +/+ "sounds/a11wlk01.wav");
  40
  41 (
  42 { var trig;
  43         trig = Impulse.kr(MouseX.kr(0.5, 10, 1));
  44         BufRd.ar(1, b, Sweep.ar(trig, BufSampleRate.ir(0)))
  45 }.play;
  46 )
  47
  48 // backwards, variable offset
  49 (
  50 { var trig, pos, rate;
  51         trig = Impulse.kr(MouseX.kr(0.5, 10, 1));
  52         rate = BufSampleRate.ir(0);
  53         pos = Sweep.ar(trig, rate.neg) + (BufFrames.ir(0) * LFNoise0.kr(0.2));
  54         BufRd.ar(1, b, pos)
  55 }.play;
  56 )
  57
  58 // raising rate
  59 (
  60 { var trig, rate;
  61         trig = Impulse.kr(MouseX.kr(0.5, 10, 1));
  62         rate = Sweep.kr(trig, 2) + 0.5;
  63         BufRd.ar(1, b, Sweep.ar(trig, BufSampleRate.ir(0) * rate))
  64 }.play;
  65 )
  66
  67 b.free
  68
  69 ::
  70
  71 Sweep can be used as a resettable link::Classes/Phasor:: or link::Classes/Line:: - one that can start, pause, resume and stop. To get a resettable link::Classes/XLine:: behavior change the code::linlin:: to code::linexp:: in the SynthDef below.
  72 code::
  73 (
  74 SynthDef(\lineReset, {|start= 0, end= 1, dur= 1, t_trig= 1, run= 1|
  75         var phasor= (Sweep.ar(t_trig, 1/dur*run)).linlin(0, 1, start, end, \minmax);
  76         phasor.poll;
  77         Out.ar(0, SinOsc.ar(phasor, 0, 0.2));
  78 }).add;
  79 )
  80 a= Synth(\lineReset, [\start, 400, \end, 800, \dur, 2])
  81 a.set(\t_trig, 1)
  82 a.set(\run, 0)
  83 a.set(\run, 1)
  84 a.set(\t_trig, 1)
  85 a.free
  86
  87 //shorter duration and downwards...
  88 a= Synth(\lineReset, [\start, 1000, \end, 500, \dur, 0.5])
  89 a.set(\t_trig, 1)
  90 a.set(\run, 0)
  91 a.set(\run, 1)
  92 a.set(\t_trig, 1)
  93 a.free
  94 ::