HelpSource/Classes/Paddpre.schelp

   1 class:: Paddpre
   2 summary:: event pattern that adds to existing value of one key
   3 related:: Classes/Padd, Classes/Paddp
   4 categories:: Streams-Patterns-Events>Patterns>Math
   5
   6 description::
   7
   8 Adds a value in an event, strong::before it is passed up:: the stream. To add to the value after it has been passed to the stream, use link::Classes/Padd::.
   9
  10 code::
  11 (
  12 var a, b;
  13 a = Paddpre(\x, 8, Pbind(\dur, 0.5));
  14 x = a.asStream;
  15 9.do({ x.next((\x:4)).postln; });
  16 )
  17 ::
  18
  19 Paddpre does not override incoming values:
  20 code::
  21 (
  22 var a, b;
  23 a = Paddpre(\freq, 302, Pset(\freq, 500, Pbind(\dur, 0.3)));
  24 x = a.asStream;
  25 9.do({ x.next(Event.default).postln; });
  26 )
  27 ::
  28
  29 ClassMethods::
  30
  31 method::new
  32
  33 argument::value
  34 can be a pattern or a stream. The resulting stream ends when that incoming stream ends.
  35
  36 Examples::
  37
  38 code::
  39 (
  40 var a, b;
  41 a = Paddpre(\legato, Pseq([0.2, 0.4], 2), Pbind(\dur, 0.5));
  42 x = a.asStream;
  43 9.do({ x.next(Event.default).postln; });
  44 )
  45 ::
  46
  47 code::
  48 //sound example
  49 (
  50 SynthDef(\sinegrain,
  51         { arg out=0, freq=440, sustain=0.02;
  52                 var env;
  53                 env = EnvGen.kr(Env.perc(0.001, sustain), 1, doneAction:2);
  54                 Out.ar(out, SinOsc.ar(freq, 0, env * 0.1))
  55         }).add;
  56 )
  57
  58 (
  59 a = Pbind(\dur, 0.5, \instrument, \sinegrain);
  60 b = Paddpre(\freq, Pseq([10, 30, 100], inf), a);
  61 b.play;
  62 )
  63 ::