HelpSource/Classes/String.schelp

   1 CLASS::String
   2 summary::array of characters
   3 categories:: Collections>Ordered
   4
   5 DESCRIPTION::
   6 String represents an array of characters.
   7
   8 Strings can be written literally using double quotes:
   9 code::
  10 "my string".class.postln;
  11 ::
  12
  13 CLASSMETHODS::
  14
  15 private::initClass
  16
  17 method::readNew
  18 Read the entire contents of a link::Classes/File:: and return them as a new String.
  19
  20 INSTANCEMETHODS::
  21
  22 private::prUnixCmd, prFormat, prCat
  23
  24 method::at
  25 Strings respond to .at in a manner similar to other indexed collections. Each element is a link::Classes/Char::.
  26 code::
  27 "ABCDEFG".at(2).postln;
  28 ::
  29
  30 method::compare
  31 Returns a -1, 0, or 1 depending on whether the receiver should be sorted before the argument, is equal to the argument or should be sorted after the argument. This is a case sensitive compare.
  32
  33 method::<
  34 Returns a link::Classes/Boolean:: whether the receiver should be sorted before the argument.
  35
  36 method::==
  37 Returns a link::Classes/Boolean:: whether the two Strings are equal.
  38
  39 method::post
  40 Prints the string to the current post window.
  41
  42 method::postln
  43 Prints the string and a carriage return to the current post window.
  44
  45 method::postc, postcln
  46 As link::#-post:: and link::#-postln::, but formatted as a comment.
  47 code::
  48 "This is a comment.".postcln;
  49 ::
  50
  51 method::postf
  52 Prints a formatted string with arguments to the current post window. The % character in the format string is replaced by a string representation of an argument. To print a % character use \\% .
  53 code::
  54 postf("this % a %. pi = %, list = %\n", "is", "test", pi.round(1e-4), (1..4))
  55
  56 this is a test. pi = 3.1416, list = [ 1, 2, 3, 4 ]
  57 ::
  58
  59 method::format
  60 Returns a formatted string with arguments. The % character in the format string is replaced by a string representation of an argument. To print a % character use \\% .
  61 code::
  62 format("this % a %. pi = %, list = %\n", "is", "test", pi.round(1e-4), (1..4))
  63
  64 this is a test. pi = 3.1416, list = [ 1, 2, 3, 4 ]
  65 ::
  66
  67 method::matchRegexp
  68 POSIX regular expression matching. Returns true if the receiver (a regular expression pattern) matches the string passed to it. The strong::start:: is an offset where to start searching in the string (default: 0), strong::end:: where to stop.
  69 code::
  70 "c".matchRegexp("abcdefg", 2, 5); // true
  71 "c".matchRegexp("abcdefg", 4, 5); // false
  72
  73 "behaviou?r".matchRegexp("behavior"); // true
  74 "behaviou?r".matchRegexp("behaviour"); // true
  75 "behaviou?r".matchRegexp("behavir"); // false
  76 "b.h.v.r".matchRegexp("behavor"); // true
  77 "b.h.vi*r".matchRegexp("behaviiiiir"); // true
  78 "(a|u)nd".matchRegexp("und"); // true
  79 "(a|u)nd".matchRegexp("and"); // true
  80 "[a-c]nd".matchRegexp("ind"); // false
  81 "[a-c]nd".matchRegexp("bnd"); // true
  82 ::
  83
  84 method::findRegexp
  85 POSIX regular expression search.
  86 code::
  87 "foobar".findRegexp("o*bar");
  88 "32424 334 /**aaaaaa*/".findRegexp("/\\*\\*a*\\*/");
  89 "foobar".findRegexp("(o*)(bar)");
  90 "aaaabaaa".findAllRegexp("a+");
  91 ::
  92
  93 method::error
  94 Prepends an error banner and posts the string.
  95 ::
  96
  97 method::warn
  98 Prepends a warning banner and posts the string.
  99
 100 method::inform
 101 Posts the string.
 102
 103 method::++
 104 Return a concatenation of the two strings.
 105 ::
 106
 107 method::+
 108 Return a concatenation of the two strings with a space between them.
 109
 110 method::compile
 111 Compiles a String containing legal SuperCollider code and returns a Function.
 112 code::
 113 (
 114 var f;
 115 f = "2 + 1".compile.postln;
 116 f.value.postln;
 117 )
 118 ::
 119
 120 method::asCompileString
 121 Returns a String formatted for compiling.
 122 code::
 123 (
 124 var f;
 125 f = "myString";
 126 f.postln;
 127 f.asCompileString.postln;
 128 )
 129 ::
 130
 131 method::postcs
 132 As link::#-postln::, but posts the compileString of the reciever.
 133 code::
 134 List[1, 2, ["comment", [3, 2]], { 1.0.rand }].postcs;
 135 ::
 136
 137 method::interpret
 138 Compile and execute a String containing legal SuperCollider code, returning the result.
 139 code::
 140 "2 + 1".interpret.postln;
 141 ::
 142
 143 method::interpretPrint
 144 Compile, execute and print the result of a String containing legal SuperCollider code.
 145 code::
 146 "2 + 1".interpretPrint;
 147 ::
 148
 149 method::asSymbol
 150 Return a link::Classes/Symbol:: derived from the String.
 151 code::
 152 (
 153 var z;
 154 z = "myString".asSymbol.postln;
 155 z.class.postln;
 156 )
 157 ::
 158
 159 method::asInteger
 160 Return an link::Classes/Integer:: derived from the String. Strings beginning with non-numeric characters return 0.
 161 code::
 162 "4".asInteger.postln;
 163 ::
 164
 165 method::asFloat
 166 Return a link::Classes/Float:: derived from the String. Strings beginning with non-numeric characters return 0.
 167 code::
 168 "4.3".asFloat.postln;
 169 ::
 170
 171 method::asSecs
 172 Return a link::Classes/Float:: based on converting a time string in format (dd):hh:mm:ss.s. This is the inverse method to link::Classes/SimpleNumber#-asTimeString::.
 173 code::
 174 (45296.asTimeString).asSecs;
 175 "32.1".asSecs;
 176 "62.1".asSecs;          // warns
 177 "0:0:59.9".asSecs;
 178 "1:1:1.1".asSecs;
 179 "-1".asSecs;            // neg sign supported
 180 "-12:34:56".asSecs;
 181 "12:-34:56".asSecs;     // warns
 182 "-23:12.3456".asSecs;   //
 183 "-1:00:00:00".asSecs;   // days too.
 184 ::
 185
 186 method::catArgs
 187 Concatenate this string with the following args.
 188 code::
 189 "These are some args: ".catArgs(\fish, SinOsc.ar, {4 + 3}).postln;
 190 ::
 191
 192 method::scatArgs
 193 Same as link::#-catArgs::, but with spaces in between.
 194 code::
 195 "These are some args: ".scatArgs(\fish, SinOsc.ar, {4 + 3}).postln;
 196 ::
 197
 198 method::ccatArgs
 199 Same as link::#-catArgs::, but with commas in between.
 200 code::
 201 "a String".ccatArgs(\fish, SinOsc.ar, {4 + 3}).postln;
 202 ::
 203
 204 method::catList, scatList, ccatList
 205 As link::#-catArgs::, link::#-scatArgs:: and link::#-ccatArgs:: above, but takes a Collection (usually a link::Classes/List:: or an link::Classes/Array::) as an argument.
 206 code::
 207 "a String".ccatList([\fish, SinOsc.ar, {4 + 3}]).postln;
 208 ::
 209
 210 method::split
 211 Returns an Array of Strings split at the separator. The separator is a link::Classes/Char::, and is not included in the output array. The default separator is $/, handy for Unix paths.
 212 code::
 213 "This/could/be/a/Unix/path".split.postln;
 214 "These are several words".split($ ).postln;
 215 ::
 216
 217 method::ascii
 218 Returns an Array of asci numbers of the Strings's characters.
 219 code::
 220 "wertvoll".ascii;
 221 ::
 222
 223 method::find
 224 Returns the index of the string in the receiver, or nil if not found. If strong::ignoreCase:: is true, find makes no difference between uppercase and lowercase letters. The strong::offset:: is the point in the string where the search begins.
 225 code::
 226 "These are several words".find("are").postln;
 227 "These are several words".find("fish").postln;
 228 ::
 229
 230 method::findBackwards
 231 Same like link::#-find::, but starts at the end of the string.
 232 code::
 233 // compare:
 234 "These words are several words".find("words"); // 6
 235 "These words are several words".findBackwards("words"); // 24
 236 ::
 237
 238 method::findAll
 239 Returns the indices of the string in the receiver, or nil if not found.
 240 code::
 241 "These are several words which are fish".findAll("are").postln;
 242 "These are several words which are fish".findAll("fish").postln;
 243 ::
 244
 245 method::contains
 246 Returns a link::Classes/Boolean:: indicating if the String contains string.
 247 code::
 248 "These are several words".contains("are").postln;
 249 "These are several words".contains("fish").postln;
 250 ::
 251
 252 method::containsi
 253 Same as link::#-contains::, but case insensitive.
 254 code::
 255 "These are several words".containsi("ArE").postln;
 256 ::
 257
 258 method::containsStringAt
 259 Returns a link::Classes/Boolean:: indicating if the String contains string beginning at the specified index.
 260 code::
 261 "These are several words".containsStringAt(6, "are").postln;
 262 ::
 263
 264 method::icontainsStringAt
 265 Same as link::#-containsStringAt::, but case insensitive.
 266
 267 method::escapeChar
 268 Add the escape character (\) at the location of your choice.
 269 code::
 270 "This will become a Unix friendly string".escapeChar($ ).postln;
 271 ::
 272
 273 method::tr
 274 Transliteration. Replace all instances of strong::from:: with strong::to::.
 275 code::
 276 ":-(:-(:-(".tr($(, $)); //turn the frowns upside down
 277 ::
 278
 279 method::replace
 280 Like link::#-tr::, but with strings as arguments.
 281 code::
 282 "Here are several words which are fish".replace("are", "were");
 283 ::
 284
 285 method::printOn
 286 Print the String on stream.
 287 code::
 288 "Print this on Post".printOn(Post);
 289
 290 // equivalent to:
 291 Post << "Print this on Post";
 292 ::
 293
 294 method::storeOn
 295 Same as link::#-printOn::, but formatted link::#-asCompileString::.
 296 code::
 297 "Store this on Post".storeOn(Post);
 298
 299 // equivalent to:
 300 Post <<< "Store this on Post";
 301 ::
 302
 303 method::inspectorClass
 304 Returns class link::Classes/StringInspector::.
 305
 306 method::stripRTF
 307 Returns a new String with all RTF formatting removed.
 308 code::
 309 (
 310 // same as File-readAllStringRTF
 311 g = File("/code/SuperCollider3/build/Help/UGens/Chaos/HenonC.help.rtf","r");
 312 g.readAllString.stripRTF.postln;
 313 g.close;
 314 )
 315 ::
 316
 317 subsection::Unix Support
 318
 319 Where relevant, the current working directory is the same as the location of the SuperCollider app and the shell is the Bourne shell (sh). Note that the cwd, and indeed the shell itself, does not persist:
 320 code::
 321 "echo $0".unixCmd; // print the shell (sh)
 322 "pwd".unixCmd;
 323 "cd Help/".unixCmd;
 324 "pwd".unixCmd;
 325
 326 "export FISH=mackerel".unixCmd;
 327 "echo $FISH".unixCmd;
 328 ::
 329 It is however possible to execute complex commands:
 330 code::
 331 "pwd; cd Help/; pwd".unixCmd;
 332 "export FISH=mackerel; echo $FISH".unixCmd;
 333 ::
 334 Also on os x applescript can be called via osascript:
 335 code::
 336 "osascript -e 'tell application \"Safari\" to activate'".unixCmd;
 337 ::
 338 Should you need an environment variable to persist you can use link::#-setenv::.
 339
 340 note::
 341 Despite the fact that the method is called 'unixCmd', strong::it does work in Windows::. The string must be a DOS command, however: "dir" rather than "ls" for instance.
 342 ::
 343
 344 method::unixCmd
 345 Execute the String on the command line using the Bourne shell (sh). Returns the pid of the newly created process (use Integer.pidRunning to test if a pid is alive). action is a Function that is called when the process has exited. It is passed two arguments: the exit code and pid of the exited process. postOutput is a Boolean that controls whether or not the output of the process is displayed in the post window.
 346 code::
 347 "ls Help".unixCmd;
 348 "echo one; sleep 1; echo two; sleep 1".unixCmd { |res, pid| [\done, res, pid].postln };
 349 ::
 350
 351 method::unixCmdGetStdOut
 352 Similar to link::#-unixCmd:: except that the stdout of the process is returned (synchronously) rather than sent to the post window.
 353 code::
 354 ~listing = "ls Help".unixCmdGetStdOut; // Grab
 355 ~listing.reverse.as(Array).stutter.join.postln; // Mangle
 356 ::
 357
 358 method::systemCmd
 359 Executes a unix command synchronously.
 360
 361 returns:: Error code of the unix command
 362
 363 method::runInTerminal
 364 Execute the String in a new terminal window. (The string is incorporated into a temporary script file and executed using a shell. "/usr/bash" is the default shell used but you can optionally specify which shell to use as an argument.)
 365 code::
 366 "echo ---------Hello delightful SuperCollider user----------".runInTerminal;
 367 ::
 368
 369 method::setenv
 370 Set the environment variable indicated in the string to equal the String strong::value::. This value will persist until it is changed or SC is quit. Note that if strong::value:: is a path you may need to call link::#-standardizePath:: on it.
 371 code::
 372 // all defs in this directory will be loaded when a local server boots
 373 "SC_SYNTHDEF_PATH".setenv("~/scwork/".standardizePath);
 374 "echo $SC_SYNTHDEF_PATH".unixCmd;
 375 ::
 376
 377 method::getenv
 378 Returns the value contained in the environment variable indicated by the String.
 379 code::
 380 "USER".getenv;
 381 ::
 382
 383 method::pathMatch
 384 Returns an link::Classes/Array:: containing all paths matching this String. Wildcards apply, non-recursive.
 385 code::
 386 Post << "Help/*".pathMatch;
 387 ::
 388
 389 method::loadPaths
 390 Perform link::#-pathMatch:: on this String, then load and execute all paths in the resultant link::Classes/Array::.
 391 code::
 392 //first prepare a file with some code...
 393 (
 394 var f = File("/tmp/loadPaths_example.scd", "w");
 395 if(f.isOpen, {
 396         f.putString("\"This text is the result of a postln command which was loaded and executed by loadPaths\".postln");
 397 }, {
 398         "test file could not be created - please edit the file's path above".warn;
 399 });
 400 f.close;
 401 )
 402
 403 //then load the file...
 404 "/tmp/loadPaths_example.scd".loadPaths; //This file posts some text
 405 ::
 406
 407 method::load
 408 Load and execute the file at the path represented by the receiver.
 409 ::
 410
 411 method::loadRelative
 412 Load and execute the file at the path represented by the receiver, interpreting the path as relative to the current document or text file. Requires that the file has been saved.
 413
 414 method::resolveRelative
 415 Convert the receiver from a relative path to an absolute path, relative to the current document or text file. Requires that the current text file has been saved. Absolute paths are left untransformed.
 416
 417 method::standardizePath
 418 Expand ~ to your home directory, and resolve aliases on OSX. See link::Classes/PathName:: for more complex needs.
 419 code::
 420 "~/".standardizePath; //This will print your home directory
 421 ::
 422
 423 method::realPath
 424 Follow symbolic links (and aliases on OSX) and any parent directory references (like "..") and return the true absolute path.
 425 returns:: An absolute path or code::nil:: if path did not exist.
 426
 427 method::basename
 428 Return the filename from a Unix path.
 429 code::
 430 "Imaginary/Directory/fish.rtf".basename;
 431 ::
 432
 433 method::dirname
 434 Return the directory name from a Unix path.
 435 code::
 436 "Imaginary/Directory/fish.rtf".dirname;
 437 ::
 438
 439 method::splitext
 440 Split off the extension from a filename or path and return both in an link::Classes/Array:: as [path or filename, extension].
 441 code::
 442 "fish.rtf".splitext;
 443 "Imaginary/Directory/fish.rtf".splitext;
 444 ::
 445
 446 method::openOS
 447 Open file, directory or URL via the operating system. On OSX this is implemented via teletype::open::, on Linux via
 448 teletype::xdg-open:: and on Windows via teletype::start::.
 449 code::
 450 Platform.userConfigDir.openOS;
 451 "http://supercollider.sf.net".openOS;
 452 ::
 453
 454 subsection::Document Support
 455
 456 method::newTextWindow
 457 Create a new link::Classes/Document:: with this.
 458 code::
 459 "Here is a new Document".newTextWindow;
 460 ::
 461
 462 method::openDocument
 463 Create a new link::Classes/Document:: from the path corresponding to this. Returns the Document.
 464 code::
 465 (
 466 d = "Help/Help.html".openDocument;
 467 d.class;
 468 )
 469 ::
 470
 471 method::openTextFile
 472 Create a new link::Classes/Document:: from the path corresponding to this. The selection arguments will preselect the indicated range in the new window. Returns this.
 473 code::
 474 (
 475 d = "Help/Help.html".openTextFile(20, 210);
 476 d.class;
 477 )
 478 ::
 479
 480 method::findHelpFile
 481 Returns the path for the helpfile named this, if it exists, else returns nil.
 482 code::
 483 "Document".findHelpFile;
 484 "foobar".findHelpFile;
 485 ::
 486
 487 method::openHelpFile
 488 Performs link::#-findHelpFile:: on this, and opens the file it if it exists, otherwise opens the main helpfile.
 489 code::
 490 "Document".openHelpFile;
 491 "foobar".openHelpFile;
 492 ::
 493
 494 method::speak
 495 Sends string to the speech synthesisier of the OS. (OS X only.) see: link::Classes/Speech::
 496 code::
 497 "hi i'm talking with the default voice now, i guess".speak;
 498 ::
 499
 500 subsection::Drawing Support
 501
 502 The following methods must be called within an Window-drawHook or a SCUserView-drawFunc function, and will only be visible once the window or the view is refreshed. Each call to Window-refresh SCUserView-refresh will 'overwrite' all previous drawing by executing the currently defined function.
 503
 504 See also: link::Classes/Window::, link::Classes/UserView::, link::Classes/Color::, and link::Classes/Pen::.
 505
 506 note::
 507 for cross-platform GUIs, use code::Pen.stringAtPoint, Pen.stringInRect, Pen.stringCenteredIn, Pen.stringLeftJustIn, Pen.stringRightJustIn:: instead.
 508 ::
 509
 510 method::draw
 511 Draws the String at the current 0@0 link::Classes/Point::. If not transformations of the graphics state have taken place this will be the upper left corner of the window. See also link::Classes/Pen::.
 512 code::
 513 (
 514 w = Window.new.front;
 515 w.view.background_(Color.white);
 516 w.drawHook = {
 517         "abababababa\n\n\n".scramble.draw
 518 };
 519 w.refresh
 520 )
 521 ::
 522
 523 method::drawAtPoint
 524 Draws the String at the given link::Classes/Point:: using the link::Classes/Font:: and link::Classes/Color:: specified.
 525 code::
 526 (
 527 w = Window.new.front;
 528 w.view.background_(Color.white);
 529 w.drawHook = {
 530         "abababababa\n\n\n".scramble.drawAtPoint(
 531                 100@100,
 532                 Font("Courier", 30),
 533                 Color.blue(0.3, 0.5))
 534 };
 535 w.refresh;
 536 )
 537 ::
 538
 539 method::drawInRect
 540 Draws the String into the given link::Classes/Rect:: using the link::Classes/Font:: and link::Classes/Color:: specified.
 541 code::
 542 (
 543 w = Window.new.front;
 544 r = Rect(100, 100, 100, 100);
 545 w.view.background_(Color.white);
 546 w.drawHook = {
 547         "abababababa\n\n\n".scramble.drawInRect(r, Font("Courier", 12), Color.blue(0.3, 0.5));
 548         Pen.strokeRect(r);
 549 };
 550 w.refresh;
 551 )
 552 ::
 553
 554 method::drawCenteredIn
 555 Draws the String into the given Rect using the Font and Color specified.
 556 code::
 557 (
 558 w = Window.new.front;
 559 w.view.background_(Color.white);
 560 r = Rect(100, 100, 100, 100);
 561 w.drawHook = {
 562         "abababababa\n\n\n".scramble.drawCenteredIn(
 563                 r,
 564                 Font("Courier", 12),
 565                 Color.blue(0.3, 0.5)
 566         );
 567         Pen.strokeRect(r);
 568 };
 569 w.refresh;
 570 )
 571 ::
 572
 573 method::drawLeftJustIn
 574 Draws the String into the given Rect using the Font and Color specified.
 575 code::
 576 (
 577 w = Window.new.front;
 578 w.view.background_(Color.white);
 579 r = Rect(100, 100, 100, 100);
 580 w.drawHook = {
 581         "abababababa\n\n\n".scramble.drawLeftJustIn(
 582                 r,
 583                 Font("Courier", 12),
 584                 Color.blue(0.3, 0.5)
 585         );
 586         Pen.strokeRect(r);
 587 };
 588 w.refresh;
 589 )
 590 ::
 591
 592 method::drawRightJustIn
 593 Draws the String into the given link::Classes/Rect:: using the link::Classes/Font:: and link::Classes/Color:: specified.
 594 code::
 595 (
 596 w = Window.new.front;
 597 w.view.background_(Color.white);
 598 r = Rect(100, 100, 100, 100);
 599 w.drawHook = {
 600         "abababababa\n\n\n".scramble.drawRightJustIn(
 601                 r,
 602                 Font("Courier", 12),
 603                 Color.blue(0.3, 0.5)
 604         );
 605         Pen.strokeRect(r);
 606 };
 607 w.refresh;
 608 )
 609 ::