m4/gtk-doc.m4

   1 dnl -*- mode: autoconf -*-
   2
   3 # serial 1
   4
   5 dnl Usage:
   6 dnl   GTK_DOC_CHECK([minimum-gtk-doc-version])
   7 AC_DEFUN([GTK_DOC_CHECK],
   8 [
   9   AC_BEFORE([AC_PROG_LIBTOOL],[$0])dnl setup libtool first
  10   AC_BEFORE([AM_PROG_LIBTOOL],[$0])dnl setup libtool first
  11   dnl for overriding the documentation installation directory
  12   AC_ARG_WITH([html-dir],
  13     AS_HELP_STRING([--with-html-dir=PATH], [path to installed docs]),,
  14     [with_html_dir='${datadir}/gtk-doc/html'])
  15   HTML_DIR="$with_html_dir"
  16   AC_SUBST([HTML_DIR])
  17
  18   dnl enable/disable documentation building
  19   AC_ARG_ENABLE([gtk-doc],
  20     AS_HELP_STRING([--enable-gtk-doc],
  21                    [use gtk-doc to build documentation [[default=no]]]),,
  22     [enable_gtk_doc=no])
  23
  24   if test x$enable_gtk_doc = xyes; then
  25     ifelse([$1],[],
  26       [PKG_CHECK_EXISTS([gtk-doc],,
  27                         AC_MSG_ERROR([gtk-doc not installed and --enable-gtk-doc requested]))],
  28       [PKG_CHECK_EXISTS([gtk-doc >= $1],,
  29                         AC_MSG_ERROR([You need to have gtk-doc >= $1 installed to build gtk-doc]))])
  30   fi
  31
  32   AC_MSG_CHECKING([whether to build gtk-doc documentation])
  33   AC_MSG_RESULT($enable_gtk_doc)
  34
  35   AC_PATH_PROGS(GTKDOC_CHECK,gtkdoc-check,)
  36
  37   AM_CONDITIONAL([ENABLE_GTK_DOC], [test x$enable_gtk_doc = xyes])
  38   AM_CONDITIONAL([GTK_DOC_USE_LIBTOOL], [test -n "$LIBTOOL"])
  39 ])