tools/custView.pl

   1 # ======================================================================
   2 #
   3 # custView.pl
   4 # Copyright 2003 Sony Online Entertainment, Inc.
   5 # All Rights Reserved.
   6 #
   7 # ======================================================================
   8
   9 # Used to output customization data assignments for objects in a
  10 # SWG database.  Can view customization values for a list of object
  11 # ids or for all object ids in the database.
  12
  13 # Perl modules DBI and DBD::Oracle must be installed to run this tool.  See www.perl.com for info on getting these modules.
  14 # You must have PERL5LIB (or PERLLIB) set to your mapping for //depot/swg/current/tools/perllib.
  15
  16 use strict;
  17
  18 use Customization;
  19 use DBI;
  20
  21 # ======================================================================
  22 # Globals
  23 # ======================================================================
  24
  25 my $modeIsView       = 0;
  26 my $modeIsChange     = 0;
  27
  28 my $userName         = "";
  29 my $password         = "changeme";
  30 my $databaseName     = "swodb";
  31
  32 my $debug                    = 0;
  33
  34 my $showAll                      = 0;
  35 my $useOldFormat         = 0;
  36 my $useFormatVersion = 1;
  37
  38 my $defaultFilename  = '../dsrc/sku.0/sys.shared/compiled/game/customization/customization_id_manager.mif';
  39 my $customizationIdManagerFilename = $defaultFilename;
  40
  41 my $dbHandle;
  42
  43 my $dumpFileName;
  44 my $dumpFileEntryNumber = 1;
  45
  46 # ======================================================================
  47
  48 sub printHelp
  49 {
  50         print "Calling syntax:\n";
  51         print "\n";
  52         print "show help:\n";
  53         print "\t$0 -h\n";
  54         print "\n";
  55         print "view human-readable customization from database:\n";
  56         print "\t$0 -V -u <database username> [-p <database password>] [-D <database>] [-d]\n";
  57         print "\t   [-m <pathToCustomizationIdManagerMifFile>] [-f format]\n";
  58         print "\t   [-a | [objectId [objectId...]]]\n";
  59         print "\n";
  60         print "change customization data in the database:\n";
  61         print "\t$0 -C -u <database username> [-p <database password>] [-D <database>] [-d]\n";
  62         print "\t   -1 <path to 1-line format dump file> [-e <entry number within dump file>] objectId\n";
  63         print "\n";
  64         print "Option description:\n";
  65         print "\t-V: major operating mode: view database info.\n";
  66         print "\t-C: major operating mode: change database entry.\n";
  67         print "\t-u: specifies the name of the user for the Oracle database.\n";
  68         print "\t-p: [optional] specifies the password for the user of the Oracle database.      Default: changeme.\n";
  69         print "\t-D: [optional] specifies the database to attach to.  Default: swodb.\n";
  70         print "\t-d: [optional] turn on extensive debug-level output.\n";
  71         print "\t-m: [optional] specify path to CustomizationIdManager's mif version of initialization file.\n";
  72         print "\t    Default: $defaultFilename\n";
  73         print "\t-a: [optional] list customization variables for all objects in the database that have any customization info.\n";
  74         print "\t-f: [optional] customization string format: format = 1 (for new packed format version 1), old2 (for old unpacked format version 2).\n";
  75         print "\t    Default: 1.\n";
  76         print "\t-h: [optional] print this help info.\n";
  77         print "\t-1: filename containing 1-line dump format (one entry per line) of Oracle select dump(appearance_data) data.\n";
  78         print "\t-e: [optional] specifies the 1-based entry count to use if the dump file has multiple lines. Default: 1.\n";
  79 }
  80
  81 # ======================================================================
  82
  83 sub collectOptions
  84 {
  85         my $showHelp = 0;
  86         my $exitCode = 0;
  87
  88         while (defined($ARGV[0]) && ($ARGV[0] =~ m/^-(.*)$/))
  89         {
  90                 if ($1 eq 'u')
  91                 {
  92                         # Grab username.
  93                         if (@ARGV < 2)
  94                         {
  95                                 print "-u option missing <database username> specification.\n";
  96                                 $exitCode = 1;
  97                                 last;
  98                         }
  99
 100                         $userName = $ARGV[1];
 101                         print "<username: $userName>\n" if $debug;
 102
 103                         # Skip past arg.
 104                         shift @ARGV;
 105                 }
 106                 elsif ($1 eq 'p')
 107                 {
 108                         # Grab password.
 109                         if (@ARGV < 2)
 110                         {
 111                                 print "-p option missing <password> specification.\n";
 112                                 $exitCode = 1;
 113                                 next;
 114                         }
 115
 116                         $password = $ARGV[1];
 117                         print "<password: $password>\n" if $debug;
 118
 119                         # Skip past arg.
 120                         shift @ARGV;
 121                 }
 122                 elsif ($1 eq 'D')
 123                 {
 124                         # Grab database name.
 125                         if (@ARGV < 2)
 126                         {
 127                                 print "-D option missing <database> specification.\n";
 128                                 $exitCode = 1;
 129                                 next;
 130                         }
 131
 132                         $databaseName = $ARGV[1];
 133                         print "<database: $databaseName>\n" if $debug;
 134
 135                         # Skip past arg.
 136                         shift @ARGV;
 137                 }
 138                 elsif ($1 eq 'C')
 139                 {
 140                         $modeIsChange = 1;
 141                         print "major mode is change\n" if $debug;
 142                 }
 143                 elsif ($1 eq 'd')
 144                 {
 145                         $debug = 1;
 146                         $Customization::Debug = 1;
 147                 }
 148                 elsif ($1 eq 'a')
 149                 {
 150                         $showAll = 1;
 151                 }
 152                 elsif ($1 eq 'h')
 153                 {
 154                         $showHelp = 1;
 155                 }
 156                 elsif ($1 eq 'm')
 157                 {
 158                         # Grab commit count.
 159                         if (@ARGV < 2)
 160                         {
 161                                 print "-m option missing <CustomizationIdManager MIF file> specification.\n";
 162                                 $exitCode = 1;
 163                                 next;
 164                         }
 165
 166                         $customizationIdManagerFilename = $ARGV[1];
 167                         print "<customizationIdManagerFilename: $customizationIdManagerFilename\n" if $debug;
 168
 169                         # Skip past arg.
 170                         shift @ARGV;
 171                 }
 172                 elsif ($1 eq 'f')
 173                 {
 174                         # Grab commit count.
 175                         if (@ARGV < 2)
 176                         {
 177                                 print "-f option missing <format> specification.\n";
 178                                 $exitCode = 1;
 179                                 next;
 180                         }
 181
 182                         if ($ARGV[1] =~ s/^old//i)
 183                         {
 184                                 $useOldFormat = 1;
 185                         }
 186                         print "<useOldFormat: $useOldFormat>\n" if $debug;
 187
 188                         $useFormatVersion = $ARGV[1];
 189                         print "<useFormatVersion: $useFormatVersion>\n" if $debug;
 190
 191                         # Skip past arg.
 192                         shift @ARGV;
 193                 }
 194                 elsif ($1 eq 'V')
 195                 {
 196                         $modeIsView = 1;
 197                         print "major mode is viewing\n" if $debug;
 198                 }
 199                 elsif ($1 eq '1')
 200                 {
 201                         $dumpFileName = $ARGV[1];
 202                         shift @ARGV;
 203
 204                         print "dumpFileName=[$dumpFileName]\n" if $debug;
 205                 }
 206                 elsif ($1 eq 'e')
 207                 {
 208                         $dumpFileEntryNumber = $ARGV[1];
 209                         shift @ARGV;
 210                         print "dumpFileEntryNumber=$dumpFileEntryNumber\n" if $debug;
 211                 }
 212                 else
 213                 {
 214                         warn "unknown option [$1].";
 215                         $exitCode = 1;
 216                 }
 217
 218                 # Process next argument.
 219                 shift @ARGV;
 220         }
 221
 222         # Check for missing options.
 223         if (!$showHelp && (length $userName < 1))
 224         {
 225                 print "missing -u username option.\n";
 226                 $exitCode = 1;
 227         }
 228
 229         # Make sure show all or command line args exist.
 230         if (!$showHelp && (!$showAll && (@ARGV < 1)))
 231         {
 232                 print "must specify one or more object IDs or -a option for all objects.\n";
 233                 $exitCode = 1;
 234         }
 235
 236         # Show help as needed.
 237         if ($showHelp || ($exitCode != 0))
 238         {
 239                 printHelp();
 240                 exit($exitCode);
 241         }
 242 }
 243
 244 sub getVariableInfo(\%$)
 245 {
 246         my $variableInfoRef             = shift;
 247         my $customizationString = shift;
 248
 249         if ($useOldFormat)
 250         {
 251                 if ($useFormatVersion == 2)
 252                 {
 253                         getVariableInfoFromOldString(%$variableInfoRef, $customizationString);
 254                 }
 255                 else
 256                 {
 257                         die "The only old version format supported is version 2, user specified [$useFormatVersion].";
 258                 }
 259         }
 260         else
 261         {
 262                 if ($useFormatVersion == 1)
 263                 {
 264                         getVariableInfoFromNewString(%$variableInfoRef, $customizationString);
 265                 }
 266                 else
 267                 {
 268                         die "New version format [$useFormatVersion] unsupported.";
 269                 }
 270         }
 271 }
 272
 273 # ======================================================================
 274
 275 sub printView($\%)
 276 {
 277         my $objectId            = shift;
 278         my $variableInfoRef = shift;
 279
 280         print "object id: $objectId\n";
 281         dumpVariableInfo(%$variableInfoRef);
 282
 283         print "\n";
 284 }
 285
 286 # ======================================================================
 287
 288 sub handleRow(\@)
 289 {
 290         my $rowRef = shift;
 291
 292         # Validate row entry count.
 293         die "Returned row has " . @$rowRef . "entries, expecting 2." if (@$rowRef != 2);
 294
 295         # Retrieve object id and old customization data.
 296         my $objectId                    = $$rowRef[0];
 297         my $customizationString = $$rowRef[1];
 298         print "<row: id=[$objectId]: string length [" . (length $customizationString) . "]>\n" if $debug;
 299
 300         my %variableInfo = ();
 301
 302         my $success = getVariableInfo(%variableInfo, $customizationString);
 303         die "getVariableInfo() failed for object id [$objectId]." if !$success;
 304
 305         printView($objectId, %variableInfo);
 306 }
 307
 308 # ======================================================================
 309
 310 sub doView
 311 {
 312         if ($showAll)
 313         {
 314                 print "<viewing: all>\n" if $debug;
 315
 316                 # Prepare the SELECT statement: grab all non-empty appearance_data and associated object ids.
 317                 my $statementHandle = $dbHandle->prepare("SELECT object_id, appearance_data FROM tangible_objects WHERE LENGTH(appearance_data) > 0") or die $dbHandle->errstr;
 318                 $statementHandle->execute() or die $statementHandle->errstr;
 319
 320                 while (my @row = $statementHandle->fetchrow_array)
 321                 {
 322                         handleRow(@row);
 323                 }
 324         }
 325         else
 326         {
 327                 print "<viewing: [@ARGV]>\n" if $debug;
 328
 329                 # Prepare the SELECT statement: grab all non-empty appearance_data and associated object ids.
 330                 my $statementHandle = $dbHandle->prepare("SELECT object_id, appearance_data FROM tangible_objects WHERE (LENGTH(appearance_data) > 0) AND object_id = ?") or die $dbHandle->errstr;
 331
 332                 for (; defined($ARGV[0]); shift @ARGV)
 333                 {
 334                         $statementHandle->execute($ARGV[0]) or die $statementHandle->errstr;
 335                         my @row = $statementHandle->fetchrow_array;
 336
 337                         if (!@row)
 338                         {
 339                                 print "object id [$ARGV[0]] has no customization data.\n";
 340                                 next;
 341                         }
 342
 343                         handleRow(@row);
 344                 }
 345         }
 346 }
 347
 348 # ----------------------------------------------------------------------
 349
 350 sub convertOracleDumpToString
 351 {
 352         my $oracleDumpString = shift;
 353         my $newString = "";
 354
 355         # remove header info.
 356         $oracleDumpString =~ s/^\s*(\d+)?.*:\s*//;
 357         my $objectId = $1;
 358
 359         while (length($oracleDumpString) > 0)
 360         {
 361                 if ($oracleDumpString =~ s/^(\d+)(\s*,\s*)?//)
 362                 {
 363                         $newString .= chr($1);
 364                 }
 365                 else
 366                 {
 367                         print STDERR "convertOracleDumpToString: ", length($oracleDumpString), " characters remain: [val=", ord(substr($oracleDumpString,0,1)), "].\n";
 368                         return $newString;
 369                 }
 370         }
 371
 372         return $newString;
 373 }
 374
 375 # ----------------------------------------------------------------------
 376
 377 sub extractAppearanceDataFromFile
 378 {
 379         my $dumpFile;
 380         open($dumpFile, '< ' . $dumpFileName) or die "failed to open dump file [$dumpFileName]: $!";
 381
 382         my $entry = 1;
 383         while (<$dumpFile>)
 384         {
 385                 # Check if we're dealing with the proper entry.
 386                 if ($entry == $dumpFileEntryNumber)
 387                 {
 388                         chomp;
 389                         my $appearanceData = convertOracleDumpToString($_);
 390
 391                         close($dumpFile) or die "Failed to close dump file: $!";
 392                         return $appearanceData;
 393                 }
 394
 395                 # Increment loop.
 396                 ++$entry;
 397         }
 398
 399         close($dumpFile) or die "Failed to close dump file: $!";
 400         die "Entry [$dumpFileEntryNumber] does not exist in file [$dumpFileName] with [$entry] entries.";
 401 }
 402
 403 # ----------------------------------------------------------------------
 404
 405 sub updateAppearanceData
 406 {
 407         # Retrieve args.
 408         my $objectId       = shift;
 409         my $appearanceData = shift;
 410
 411         # Execute query.
 412         my $rowCount = $dbHandle->do("UPDATE tangible_objects SET appearance_data=? WHERE object_id=$objectId", undef, $appearanceData) or die $dbHandle->errstr;
 413         $dbHandle->commit() or die $dbHandle->errstr;
 414         print "[$rowCount] rows updated.\n";
 415 }
 416
 417 # ----------------------------------------------------------------------
 418
 419 sub doChange
 420 {
 421         # Get the line.
 422         my $appearanceData = extractAppearanceDataFromFile();
 423         die "Could not extract appearance data from 1-line dump file.\n" if !defined($appearanceData);
 424
 425         # Update the database.
 426         die "Expecting objectId at end of line.\n" if (@ARGV != 1);
 427
 428         my $objectId = $ARGV[0];
 429         updateAppearanceData($objectId, $appearanceData);
 430 }
 431
 432 # ----------------------------------------------------------------------
 433
 434 sub connectDatabase
 435 {
 436         # Open the database connection.
 437         $dbHandle = DBI->connect("dbi:Oracle:$databaseName", $userName, $password, { RaiseError => 1, AutoCommit => 0 });
 438         error("failed to open database: [$DBI::errstr]") if !defined($dbHandle);
 439         print "<connection: opened connection to database [$databaseName] as user [$userName] successfully.>\n" if $debug;
 440 }
 441
 442 # ----------------------------------------------------------------------
 443
 444 sub disconnectDatabase
 445 {
 446         # Close the database connection.
 447         my $returnCode = $dbHandle->disconnect or warn $dbHandle->errstr;
 448         print "<disconnect: return code $returnCode>\n" if $debug;
 449 }
 450
 451 # ======================================================================
 452 # Program Starts Here
 453 # ======================================================================
 454 {
 455         collectOptions();
 456
 457         connectDatabase();
 458
 459         if ($modeIsView)
 460         {
 461                 Customization::initializeCustomization($customizationIdManagerFilename);
 462                 doView();
 463         }
 464         elsif ($modeIsChange)
 465         {
 466                 doChange();
 467         }
 468         else
 469         {
 470                 die "Major mode is neither viewing or changing.\n";
 471         }
 472
 473         disconnectDatabase();
 474 }
 475
 476 # ======================================================================