com32/lib/sys/entry.S

   1 # -----------------------------------------------------------------------
   2 #
   3 #   Copyright 2003-2008 H. Peter Anvin - All Rights Reserved
   4 #
   5 #   Permission is hereby granted, free of charge, to any person
   6 #   obtaining a copy of this software and associated documentation
   7 #   files (the "Software"), to deal in the Software without
   8 #   restriction, including without limitation the rights to use,
   9 #   copy, modify, merge, publish, distribute, sublicense, and/or
  10 #   sell copies of the Software, and to permit persons to whom
  11 #   the Software is furnished to do so, subject to the following
  12 #   conditions:
  13 #
  14 #   The above copyright notice and this permission notice shall
  15 #   be included in all copies or substantial portions of the Software.
  16 #
  17 #   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  18 #   EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  19 #   OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  20 #   NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  21 #   HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  22 #   WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  23 #   FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  24 #   OTHER DEALINGS IN THE SOFTWARE.
  25 #
  26 # -----------------------------------------------------------------------
  27
  28 # COM32 start up code - must be linked first in the binary
  29
  30 /* Number of arguments in our version of the entry structure */
  31 #define COM32_ARGS 6
  32
  33                 .section ".init","ax"
  34                 .globl _start
  35                 .type _start, @function
  36 _start:
  37                 # This first instruction acts as COM32 magic number
  38                 movl $0x21cd4cff,%eax
  39
  40                 # Upwards string operations
  41                 cld
  42
  43                 # Zero the .bss segment
  44                 xorl %eax,%eax
  45                 movl $__bss_start,%edi          # Symbol provided by linker
  46                 movl $_end+3,%ecx               # Symbol provided by linker
  47                 subl %edi,%ecx
  48                 shrl $2,%ecx
  49                 rep ; stosl
  50
  51                 # Copy COM32 invocation parameters
  52                 leal 4(%esp),%esi               # Argument list
  53                 movl $__com32,%edi
  54                 movl $COM32_ARGS,%ecx
  55                 movl %esp,-4(%edi)              # Save the initial stack ptr
  56                 cmpl (%esi),%ecx
  57                 jbe 1f
  58                 movl (%esi),%ecx
  59 1:              inc %ecx                        # Copy the argument count, too
  60                 rep ; movsl
  61
  62                 # Parse the command line (assumes REGPARM)
  63                 movl __com32+4,%edx             # Command line
  64                 pushl %edx                      # Make space for argv
  65                 movl %esp,%eax
  66                 call __parse_argv
  67                 pushl %eax                      # Save argc
  68
  69                 # Look for library initialization functions
  70                 movl $__ctors_start, %esi
  71 2:
  72                 cmpl $__ctors_end, %esi
  73                 jae 3f
  74                 call *(%esi)
  75                 addl $4,%esi
  76                 jmp 2b
  77 #
  78 # Actually run main.  This assumes REGPARM is used!!!!
  79 #
  80 3:
  81                 popl %eax                       # argc
  82                 popl %edx                       # argv
  83                 call main
  84                 call *(__exit_handler)
  85                 hlt
  86                 .size _start, .-_start
  87
  88                 .bss
  89                 .globl __entry_esp
  90 __entry_esp:    .space 4
  91                 .globl __com32
  92 __com32:        .space 4*(COM32_ARGS+1)