com32/lib/sys/entry.S

   1 /* -----------------------------------------------------------------------
   2  *
   3  *   Copyright 2003-2008 H. Peter Anvin - All Rights Reserved
   4  *
   5  *   Permission is hereby granted, free of charge, to any person
   6  *   obtaining a copy of this software and associated documentation
   7  *   files (the "Software"), to deal in the Software without
   8  *   restriction, including without limitation the rights to use,
   9  *   copy, modify, merge, publish, distribute, sublicense, and/or
  10  *   sell copies of the Software, and to permit persons to whom
  11  *   the Software is furnished to do so, subject to the following
  12  *   conditions:
  13  *
  14  *   The above copyright notice and this permission notice shall
  15  *   be included in all copies or substantial portions of the Software.
  16  *
  17  *   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  18  *   EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  19  *   OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  20  *   NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  21  *   HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  22  *   WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  23  *   FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  24  *   OTHER DEALINGS IN THE SOFTWARE.
  25  *
  26  * ----------------------------------------------------------------------- */
  27
  28 /*
  29  * COM32 start up code - must be linked first in the binary
  30  */
  31
  32 /* Number of arguments in our version of the entry structure */
  33 #define COM32_ARGS 8
  34
  35                 .section ".init","ax"
  36                 .globl _start
  37                 .type _start, @function
  38 _start:
  39                 /* This first instruction acts as COM32 magic number */
  40                 movl $0x21cd4cff,%eax
  41
  42                 /* Upwards string operations */
  43                 cld
  44
  45                 /* Zero the .bss segment */
  46                 xorl %eax,%eax
  47                 movl $__bss_start,%edi          # Symbol provided by linker
  48                 movl $_end+3,%ecx               # Symbol provided by linker
  49                 subl %edi,%ecx
  50                 shrl $2,%ecx
  51                 rep ; stosl
  52
  53                 /* Copy COM32 invocation parameters */
  54                 leal 4(%esp),%esi               # Argument list
  55                 movl $__com32,%edi
  56                 movl $(COM32_ARGS),%ecx
  57                 movl %esp,-4(%edi)              # Save the initial stack ptr
  58                 cmpl (%esi),%ecx
  59                 jbe 1f
  60                 movl (%esi),%ecx
  61 1:              inc %ecx                        # Copy the argument count, too
  62                 rep ; movsl
  63
  64                 /* Parse the command line (assumes REGPARM) */
  65                 movl __com32+4,%edx             # Command line
  66                 pushl %edx                      # Make space for argv
  67                 movl %esp,%eax
  68                 call __parse_argv
  69                 pushl %eax                      # Save argc
  70
  71                 /* Look for library initialization functions */
  72                 movl $__ctors_start, %esi
  73 2:
  74                 cmpl $__ctors_end, %esi
  75                 jae 3f
  76                 call *(%esi)
  77                 addl $4,%esi
  78                 jmp 2b
  79 /*
  80  * Actually run main.  This assumes REGPARM is used!!!!
  81  */
  82 3:
  83                 popl %eax                       # argc
  84                 popl %edx                       # argv
  85                 call main
  86                 call *(__exit_handler)
  87                 hlt
  88                 .size _start, .-_start
  89
  90                 .bss
  91                 .globl __entry_esp
  92 __entry_esp:    .space 4
  93                 .globl __com32
  94 __com32:        .space 4*(COM32_ARGS+1)