conio.inc

   1 ;; -----------------------------------------------------------------------
   2 ;;
   3 ;;   Copyright 1994-2005 H. Peter Anvin - All Rights Reserved
   4 ;;
   5 ;;   This program is free software; you can redistribute it and/or modify
   6 ;;   it under the terms of the GNU General Public License as published by
   7 ;;   the Free Software Foundation, Inc., 53 Temple Place Ste 330,
   8 ;;   Boston MA 02111-1307, USA; either version 2 of the License, or
   9 ;;   (at your option) any later version; incorporated herein by reference.
  10 ;;
  11 ;; -----------------------------------------------------------------------
  12
  13 ;;
  14 ;; conio.inc
  15 ;;
  16 ;; Console I/O code, except:
  17 ;;   writechr, writestr         - module-dependent
  18 ;;   cwritestr, crlf            - writestr.inc
  19 ;;   writehex*                  - writehex.inc
  20 ;;
  21
  22 ;
  23 ; loadkeys:     Load a LILO-style keymap; SI and DX:AX set by searchdir
  24 ;
  25                 section .text
  26
  27 loadkeys:
  28                 and dx,dx                       ; Should be 256 bytes exactly
  29                 jne loadkeys_ret
  30                 cmp ax,256
  31                 jne loadkeys_ret
  32
  33                 mov bx,trackbuf
  34                 mov cx,1                        ; 1 cluster should be >= 256 bytes
  35                 call getfssec
  36
  37                 mov si,trackbuf
  38                 mov di,KbdMap
  39                 mov cx,256 >> 2
  40                 rep movsd
  41
  42 loadkeys_ret:   ret
  43
  44 ;
  45 ; get_msg_file: Load a text file and write its contents to the screen,
  46 ;               interpreting color codes.  Is called with SI and DX:AX
  47 ;               set by routine searchdir
  48 ;
  49 get_msg_file:
  50                 push es
  51                 shl edx,16                      ; EDX <- DX:AX (length of file)
  52                 mov dx,ax
  53                 mov ax,xfer_buf_seg             ; Use for temporary storage
  54                 mov es,ax
  55
  56                 mov byte [TextAttribute],07h    ; Default grey on white
  57                 mov byte [DisplayMask],07h      ; Display text in all modes
  58                 call msg_initvars
  59
  60 get_msg_chunk:  push edx                        ; EDX = length of file
  61                 xor bx,bx                       ; == xbs_textbuf
  62                 mov cx,[BufSafe]
  63                 call getfssec
  64                 pop edx
  65                 push si                         ; Save current cluster
  66                 xor si,si                       ; == xbs_textbuf
  67                 mov cx,[BufSafeBytes]           ; Number of bytes left in chunk
  68 print_msg_file:
  69                 push cx
  70                 push edx
  71                 es lodsb
  72                 cmp al,1Ah                      ; DOS EOF?
  73                 je msg_done_pop
  74                 push si
  75                 mov cl,[UsingVGA]
  76                 and cl,01h
  77                 inc cx                          ; CL <- 01h = text mode,
  78                                                 ;       02h = graphics mode
  79                 call [NextCharJump]             ; Do what shall be done
  80                 pop si
  81                 pop edx
  82                 pop cx
  83                 dec edx
  84                 jz msg_done
  85                 loop print_msg_file
  86                 pop si
  87                 jmp short get_msg_chunk
  88 msg_done_pop:
  89                 add sp,byte 6                   ; Drop pushed EDX, CX
  90 msg_done:
  91                 pop si
  92                 pop es
  93                 ret
  94 msg_putchar:                                    ; Normal character
  95                 cmp al,0Fh                      ; ^O = color code follows
  96                 je msg_ctrl_o
  97                 cmp al,0Dh                      ; Ignore <CR>
  98                 je msg_ignore
  99                 cmp al,0Ah                      ; <LF> = newline
 100                 je msg_newline
 101                 cmp al,0Ch                      ; <FF> = clear screen
 102                 je msg_formfeed
 103                 cmp al,07h                      ; <BEL> = beep
 104                 je msg_beep
 105                 cmp al,19h                      ; <EM> = return to text mode
 106                 je msg_novga
 107                 cmp al,18h                      ; <CAN> = VGA filename follows
 108                 je msg_vga
 109                 jnb .not_modectl
 110                 cmp al,10h                      ; 10h to 17h are mode controls
 111                 jae msg_modectl
 112 .not_modectl:
 113
 114 msg_normal:     call write_serial_displaymask   ; Write to serial port
 115                 test [DisplayMask],cl
 116                 jz msg_ignore                   ; Not screen
 117                 test byte [DisplayCon],01h
 118                 jz msg_ignore
 119                 mov bl,[TextAttribute]
 120                 mov bh,[BIOS_page]
 121                 mov ah,09h                      ; Write character/attribute
 122                 mov cx,1                        ; One character only
 123                 int 10h                         ; Write to screen
 124                 mov al,[CursorCol]
 125                 inc ax
 126                 cmp al,[VidCols]
 127                 ja msg_line_wrap                ; Screen wraparound
 128                 mov [CursorCol],al
 129
 130 msg_gotoxy:     mov bh,[BIOS_page]
 131                 mov dx,[CursorDX]
 132                 mov ah,02h                      ; Set cursor position
 133                 int 10h
 134 msg_ignore:     ret
 135
 136 msg_beep:       mov ax,0E07h                    ; Beep
 137                 xor bx,bx
 138                 int 10h
 139                 ret
 140
 141 msg_ctrl_o:                                     ; ^O = color code follows
 142                 mov word [NextCharJump],msg_setbg
 143                 ret
 144 msg_newline:                                    ; Newline char or end of line
 145                 mov si,crlf_msg
 146                 call write_serial_str_displaymask
 147 msg_line_wrap:                                  ; Screen wraparound
 148                 test [DisplayMask],cl
 149                 jz msg_ignore
 150                 mov byte [CursorCol],0
 151                 mov al,[CursorRow]
 152                 inc ax
 153                 cmp al,[VidRows]
 154                 ja msg_scroll
 155                 mov [CursorRow],al
 156                 jmp short msg_gotoxy
 157 msg_scroll:     xor cx,cx                       ; Upper left hand corner
 158                 mov dx,[ScreenSize]
 159                 mov [CursorRow],dh              ; New cursor at the bottom
 160                 mov bh,[ScrollAttribute]
 161                 mov ax,0601h                    ; Scroll up one line
 162                 int 10h
 163                 jmp short msg_gotoxy
 164 msg_formfeed:                                   ; Form feed character
 165                 mov si,crff_msg
 166                 call write_serial_str_displaymask
 167                 test [DisplayMask],cl
 168                 jz msg_ignore
 169                 xor cx,cx
 170                 mov [CursorDX],cx               ; Upper lefthand corner
 171                 mov dx,[ScreenSize]
 172                 mov bh,[TextAttribute]
 173                 mov ax,0600h                    ; Clear screen region
 174                 int 10h
 175                 jmp msg_gotoxy
 176 msg_setbg:                                      ; Color background character
 177                 call unhexchar
 178                 jc msg_color_bad
 179                 shl al,4
 180                 test [DisplayMask],cl
 181                 jz .dontset
 182                 mov [TextAttribute],al
 183 .dontset:
 184                 mov word [NextCharJump],msg_setfg
 185                 ret
 186 msg_setfg:                                      ; Color foreground character
 187                 call unhexchar
 188                 jc msg_color_bad
 189                 test [DisplayMask],cl
 190                 jz .dontset
 191                 or [TextAttribute],al           ; setbg set foreground to 0
 192 .dontset:
 193                 jmp short msg_putcharnext
 194 msg_vga:
 195                 mov word [NextCharJump],msg_filename
 196                 mov di, VGAFileBuf
 197                 jmp short msg_setvgafileptr
 198
 199 msg_color_bad:
 200                 mov byte [TextAttribute],07h    ; Default attribute
 201 msg_putcharnext:
 202                 mov word [NextCharJump],msg_putchar
 203                 ret
 204
 205 msg_filename:                                   ; Getting VGA filename
 206                 cmp al,0Ah                      ; <LF> = end of filename
 207                 je msg_viewimage
 208                 cmp al,' '
 209                 jbe msg_ret                     ; Ignore space/control char
 210                 mov di,[VGAFilePtr]
 211                 cmp di,VGAFileBufEnd
 212                 jnb msg_ret
 213                 mov [di],al                     ; Can't use stosb (DS:)
 214                 inc di
 215 msg_setvgafileptr:
 216                 mov [VGAFilePtr],di
 217 msg_ret:        ret
 218
 219 msg_novga:
 220                 call vgaclearmode
 221                 jmp short msg_initvars
 222
 223 msg_viewimage:
 224                 push es
 225                 push ds
 226                 pop es                          ; ES <- DS
 227                 mov si,[VGAFilePtr]
 228                 mov byte [si],0                 ; Zero-terminate filename
 229                 mov si,VGAFileBuf
 230                 mov di,VGAFileMBuf
 231                 push di
 232                 call mangle_name
 233                 pop di
 234                 call searchdir
 235                 pop es
 236                 jz msg_putcharnext              ; Not there
 237                 call vgadisplayfile
 238                 ; Fall through
 239
 240                 ; Subroutine to initialize variables, also needed
 241                 ; after loading a graphics file
 242 msg_initvars:
 243                 pusha
 244                 mov bh,[BIOS_page]
 245                 mov ah,03h                      ; Read cursor position
 246                 int 10h
 247                 mov [CursorDX],dx
 248                 popa
 249                 jmp short msg_putcharnext       ; Initialize state machine
 250
 251 msg_modectl:
 252                 and al,07h
 253                 mov [DisplayMask],al
 254                 jmp short msg_putcharnext
 255
 256 ;
 257 ; write_serial: If serial output is enabled, write character on serial port
 258 ; write_serial_displaymask: d:o, but ignore if DisplayMask & 04h == 0
 259 ;
 260 write_serial_displaymask:
 261                 test byte [DisplayMask], 04h
 262                 jz write_serial.end
 263 write_serial:
 264                 pushfd
 265                 pushad
 266                 mov bx,[SerialPort]
 267                 and bx,bx
 268                 je .noserial
 269                 push ax
 270                 mov ah,[FlowInput]
 271 .waitspace:
 272                 ; Wait for space in transmit register
 273                 lea dx,[bx+5]                   ; DX -> LSR
 274                 in al,dx
 275                 test al,20h
 276                 jz .waitspace
 277
 278                 ; Wait for input flow control
 279                 inc dx                          ; DX -> MSR
 280                 in al,dx
 281                 and al,ah
 282                 cmp al,ah
 283                 jne .waitspace
 284 .no_flow:
 285
 286                 xchg dx,bx                      ; DX -> THR
 287                 pop ax
 288                 call slow_out                   ; Send data
 289 .noserial:      popad
 290                 popfd
 291 .end:           ret
 292
 293 ;
 294 ; write_serial_str: write_serial for strings
 295 ; write_serial_str_displaymask: d:o, but ignore if DisplayMask & 04h == 0
 296 ;
 297 write_serial_str_displaymask:
 298                 test byte [DisplayMask], 04h
 299                 jz write_serial_str.end
 300
 301 write_serial_str:
 302 .loop           lodsb
 303                 and al,al
 304                 jz .end
 305                 call write_serial
 306                 jmp short .loop
 307 .end:           ret
 308
 309 ;
 310 ; pollchar: check if we have an input character pending (ZF = 0)
 311 ;
 312 pollchar:
 313                 pushad
 314                 mov ah,11h              ; Poll keyboard
 315                 int 16h
 316                 jnz .done               ; Keyboard response
 317                 mov dx,[SerialPort]
 318                 and dx,dx
 319                 jz .done                ; No serial port -> no input
 320                 add dx,byte 5           ; DX -> LSR
 321                 in al,dx
 322                 test al,1               ; ZF = 0 if data pending
 323                 jz .done
 324                 inc dx                  ; DX -> MSR
 325                 mov ah,[FlowIgnore]     ; Required status bits
 326                 in al,dx
 327                 and al,ah
 328                 cmp al,ah
 329                 setne al
 330                 dec al                  ; Set ZF = 0 if equal
 331 .done:          popad
 332                 ret
 333
 334 ;
 335 ; getchar: Read a character from keyboard or serial port
 336 ;
 337 getchar:
 338                 RESET_IDLE
 339 .again:
 340                 DO_IDLE
 341                 mov ah,11h              ; Poll keyboard
 342                 int 16h
 343                 jnz .kbd                ; Keyboard input?
 344                 mov bx,[SerialPort]
 345                 and bx,bx
 346                 jz .again
 347                 lea dx,[bx+5]           ; DX -> LSR
 348                 in al,dx
 349                 test al,1
 350                 jz .again
 351                 inc dx                  ; DX -> MSR
 352                 mov ah,[FlowIgnore]
 353                 in al,dx
 354                 and al,ah
 355                 cmp al,ah
 356                 jne .again
 357 .serial:        xor ah,ah               ; Avoid confusion
 358                 xchg dx,bx              ; Data port
 359                 in al,dx
 360                 ret
 361 .kbd:           mov ah,10h              ; Get keyboard input
 362                 int 16h
 363                 cmp al,0E0h
 364                 jnz .not_ext
 365                 xor al,al
 366 .not_ext:
 367                 and al,al
 368                 jz .func_key
 369                 mov bx,KbdMap           ; Convert character sets
 370                 xlatb
 371 .func_key:      ret
 372
 373 %ifdef DEBUG_TRACERS
 374 ;
 375 ; debug hack to print a character with minimal code impact
 376 ;
 377 debug_tracer:   pushad
 378                 pushfd
 379                 mov bp,sp
 380                 mov bx,[bp+9*4]         ; Get return address
 381                 mov al,[cs:bx]          ; Get data byte
 382                 inc word [bp+9*4]       ; Return to after data byte
 383                 call writechr
 384                 popfd
 385                 popad
 386                 ret
 387 %endif  ; DEBUG_TRACERS
 388
 389                 section .data
 390                 ; This is a word to pc_setint16 can set it
 391 DisplayCon      dw 01h                  ; Console display enabled
 392
 393 ScrollAttribute db 07h                  ; Grey on white (normal text color)
 394
 395                 section .bss
 396                 alignb 2
 397 NextCharJump    resw 1                  ; Routine to interpret next print char
 398 CursorDX        equ $
 399 CursorCol       resb 1                  ; Cursor column for message file
 400 CursorRow       resb 1                  ; Cursor row for message file
 401 ScreenSize      equ $
 402 VidCols         resb 1                  ; Columns on screen-1
 403 VidRows         resb 1                  ; Rows on screen-1
 404
 405 ; Serial console stuff...
 406 BaudDivisor     resw 1                  ; Baud rate divisor
 407 FlowControl     equ $
 408 FlowOutput      resb 1                  ; Outputs to assert for serial flow
 409 FlowInput       resb 1                  ; Input bits for serial flow
 410 FlowIgnore      resb 1                  ; Ignore input unless these bits set
 411
 412 TextAttribute   resb 1                  ; Text attribute for message file
 413 DisplayMask     resb 1                  ; Display modes mask