lib/Tails/Persistence/Configuration.pm

   1 =head1 NAME
   2
   3 Tails::Persistence::Configuration - manage live-persistence.conf and presets
   4
   5 =cut
   6
   7 package Tails::Persistence::Configuration;
   8 use Moo;
   9 use MooX::late;
  10 use MooX::HandlesVia;
  11
  12 use strictures 2;
  13 use autodie qw(:all);
  14 use Carp;
  15
  16 use Tails::Persistence::Configuration::Atom;
  17 use Tails::Persistence::Configuration::ConfigFile;
  18 use Tails::Persistence::Configuration::Presets;
  19 use Types::Path::Tiny qw{AbsPath};
  20
  21 use Locale::gettext;
  22 use POSIX;
  23 setlocale(LC_MESSAGES, "");
  24 textdomain("tails-persistence-setup");
  25
  26 use namespace::clean;
  27
  28
  29 =head1 ATTRIBUTES
  30
  31 =cut
  32
  33 has 'config_file_path' => (
  34     isa      => AbsPath,
  35     is       => 'rw',
  36     coerce   => AbsPath->coercion,
  37 );
  38
  39 has 'file' => (
  40     lazy_build => 1,
  41     is         => 'rw',
  42     isa        => 'Tails::Persistence::Configuration::ConfigFile',
  43 );
  44 has 'presets' => (
  45     lazy_build => 1,
  46     is         => 'rw',
  47     isa        => 'Tails::Persistence::Configuration::Presets',
  48 );
  49 has 'force_enable_presets' => (
  50     is      => 'ro',
  51     isa     => 'ArrayRef[Str]',
  52     default => sub { [] },
  53 );
  54 has 'atoms' => (
  55     lazy_build => 1,
  56     is            => 'rw',
  57     isa           => 'ArrayRef[Tails::Persistence::Configuration::Atom]',
  58     handles_via   => 'Array',
  59     handles       => {
  60         all_atoms => 'elements',
  61         push_atom => 'push',
  62     },
  63 );
  64
  65
  66 =head1 CONSTRUCTORS
  67
  68 =cut
  69
  70 sub _build_file {
  71     my $self = shift;
  72     my $file = Tails::Persistence::Configuration::ConfigFile->new(
  73         config_file_path => $self->config_file_path
  74     );
  75     return $file;
  76 }
  77
  78 sub _build_presets {
  79     my $self = shift;
  80     Tails::Persistence::Configuration::Presets->new();
  81 }
  82
  83 sub _build_atoms {
  84     my $self = shift;
  85     return $self->merge_file_with_presets($self->file, $self->presets);
  86 }
  87
  88 =head1 METHODS
  89
  90 =cut
  91
  92 sub lines_not_in_presets {
  93     my $self = shift;
  94     grep {
  95         my $line = $_;
  96         ! grep { $_->equals_line($line) } $self->presets->all
  97     } $self->file->all_lines;
  98 }
  99
 100 sub merge_file_with_presets {
 101     my $self = shift;
 102     # Modifying and returning clones of the presets atoms would be a bit cleaner.
 103     $self->presets->set_state_from_lines($self->file->all_lines);
 104     $self->presets->set_state_from_overrides($self->force_enable_presets);
 105
 106     [
 107         $self->presets->all,
 108         map {
 109             Tails::Persistence::Configuration::Atom->new_from_line(
 110                 $_,
 111                 enabled => 1
 112             );
 113         } $self->lines_not_in_presets,
 114     ];
 115 }
 116
 117 sub all_enabled_atoms {
 118     my $self = shift;
 119     grep { $_->enabled } $self->all_atoms;
 120 }
 121
 122 sub all_enabled_lines {
 123     my $self = shift;
 124     map {
 125         Tails::Persistence::Configuration::Line->new(
 126             destination => $_->destination,
 127             options     => $_->options,
 128         )
 129     } $self->all_enabled_atoms;
 130 }
 131
 132 sub save {
 133     my $self = shift;
 134     $self->file->lines([ $self->all_enabled_lines ]);
 135     $self->file->save;
 136 }
 137
 138 no Moo;
 139 1;