arch/.unmaintained/m68k-native/exec/coldreboot.s

   1 /*
   2     Copyright © 1995-2001, The AROS Development Team. All rights reserved.
   3     $Id$
   4 */
   5
   6 /*****************************************************************************
   7
   8     NAME
   9
  10         AROS_LH0(void, ColdReboot,
  11
  12     SYNOPSIS
  13
  14     LOCATION
  15         struct ExecBase *, SysBase, 121, Exec)
  16
  17     FUNCTION
  18         Reboots the Amiga.
  19
  20     INPUTS
  21
  22     RESULT
  23
  24     NOTES
  25         This function never returns.
  26
  27     EXAMPLE
  28
  29     BUGS
  30
  31     SEE ALSO
  32
  33     INTERNALS
  34
  35     HISTORY
  36
  37 ******************************************************************************/
  38
  39         #include "machine.i"
  40
  41         .text
  42         .balign 4
  43         .globl  AROS_SLIB_ENTRY(ColdReboot,Exec)
  44         .type   AROS_SLIB_ENTRY(ColdReboot,Exec),@function
  45 AROS_SLIB_ENTRY(ColdReboot,Exec):
  46         move.w  #0x4000,custom+intena   /* disable */
  47         moveq.l #0,d0                   /* cache bits */
  48         moveq.l #-1,d1                  /* cache mask */
  49         jsr     CacheControl(a6)        /* disable all cache modes */
  50
  51         lea.l   resetus(pc),a5          /* actual reset routine */
  52         jsr     Supervisor(a6)          /* supervisor mode, ofcourse */
  53
  54         .balign 4
  55 resetus:
  56         lea.l   0x1000000,a0            /* end of rom */
  57         sub.l   -0x14(a0),a0            /* subtract size of rom */
  58         move.l  4(a0),a0                /* get vector from rom+4 */
  59         subq.w  #2,a0                   /* point to reset instruction */
  60         reset                           /* reset stuff */
  61         jmp     (a0)                    /* this instruction was still in prefetch */
  62
  63         /* never gets here */
  64