src/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(tar.h)
   3 PROGS="tar"
   4 AC_SUBST(PROGS)dnl
   5 AC_PROG_CC
   6 AC_PROG_CPP
   7 AC_GCC_TRADITIONAL
   8 AC_PROG_INSTALL
   9 AC_PROG_YACC
  10 AC_AIX
  11 AC_MINIX
  12 AC_ISC_POSIX
  13 AC_CONST
  14 AC_RETSIGTYPE
  15 AC_SIZE_T
  16 AC_MAJOR_HEADER
  17 AC_DIR_HEADER
  18 # The 3-argument open happens to go along with the O_* defines,
  19 # which are easier to check for.
  20 AC_HEADER_CHECK(fcntl.h, open_header=fcntl.h, open_header=sys/file.h)
  21 AC_COMPILE_CHECK(3-argument open,
  22 [#include <$open_header>], [int x = O_RDONLY;], , AC_DEFINE(EMUL_OPEN3))
  23 AC_REMOTE_TAPE
  24 AC_RSH
  25 AC_STDC_HEADERS
  26 AC_UNISTD_H
  27 echo checking for getgrgid declaration
  28 AC_HEADER_EGREP(getgrgid, grp.h, AC_DEFINE(HAVE_GETGRGID))
  29 echo checking for getpwuid declaration
  30 AC_HEADER_EGREP(getpwuid, pwd.h, AC_DEFINE(HAVE_GETPWUID))
  31 AC_HAVE_HEADERS(string.h limits.h)
  32 echo checking default archive
  33 # This might guess wrong, but it's not very important.
  34 for dev in rmt8 rmt0 rmt0h rct0 rst0 tape rct/c7d0s2
  35 do
  36   if test -n "`ls /dev/$dev 2>/dev/null`"; then
  37     DEF_AR_FILE=/dev/$dev
  38     break
  39   fi
  40 done
  41 if test -z "$DEF_AR_FILE"; then
  42   DEF_AR_FILE=-
  43 fi
  44
  45 AC_SUBST(DEF_AR_FILE)dnl
  46 AC_HAVE_FUNCS(strstr valloc mkdir mknod rename ftruncate ftime getcwd)
  47 AC_VPRINTF
  48 AC_ALLOCA
  49 echo checking for BSD
  50 ( test -f /vmunix || test -f /sdmach || test -f /../../mach ) && AC_DEFINE(BSD42)
  51 echo checking for HP-UX
  52 test "`(uname -s) 2> /dev/null`" = 'HP-UX' && MALLOC=malloc.o
  53 AC_SUBST(MALLOC)
  54 AC_XENIX_DIR
  55 AC_HAVE_LIBRARY(socket, [LIBS="$LIBS -lsocket"])
  56 AC_HAVE_LIBRARY(nsl, [LIBS="$LIBS -lnsl"])
  57 AC_OUTPUT(Makefile)