configure.ac

   1 # Configure template for GNU tar.  -*- autoconf -*-
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free
   5 # Software Foundation, Inc.
   6
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3, or (at your option)
  10 # any later version.
  11
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20 # 02110-1301, USA.
  21
  22 AC_INIT([GNU tar], [1.22.90], [bug-tar@gnu.org])
  23 AC_CONFIG_SRCDIR([src/tar.c])
  24 AC_CONFIG_AUX_DIR([build-aux])
  25 AC_CONFIG_HEADERS([config.h])
  26 AC_PREREQ([2.63])
  27 AM_INIT_AUTOMAKE([1.11 gnits tar-ustar dist-bzip2 dist-shar std-options silent-rules])
  28
  29 # Enable silent rules by default:
  30 AM_SILENT_RULES([yes])
  31
  32 AC_PROG_CC
  33 AC_EXEEXT
  34 AC_PROG_RANLIB
  35 AC_PROG_YACC
  36 gl_EARLY
  37
  38 AC_SYS_LARGEFILE
  39 AC_ISC_POSIX
  40 AC_C_INLINE
  41
  42 AC_CHECK_HEADERS_ONCE(fcntl.h linux/fd.h memory.h net/errno.h \
  43   sgtty.h string.h stropts.h \
  44   sys/param.h sys/device.h sys/filio.h sys/gentape.h \
  45   sys/inet.h sys/io/trioctl.h \
  46   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  47   unistd.h locale.h)
  48
  49 AC_CHECK_HEADERS([sys/buf.h], [], [],
  50 [#if HAVE_SYS_PARAM_H
  51 #include <sys/param.h>
  52 #endif])
  53
  54 AC_HEADER_SYS_WAIT
  55
  56 AC_HEADER_DIRENT
  57 AC_HEADER_MAJOR
  58 AC_HEADER_STAT
  59 AC_HEADER_STDC
  60
  61 AC_MSG_CHECKING([for st_fstype string in struct stat])
  62 AC_CACHE_VAL(diff_cv_st_fstype_string,
  63   [AC_TRY_COMPILE([#include <sys/types.h>
  64 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  65    diff_cv_st_fstype_string=yes,
  66    diff_cv_st_fstype_string=no)])
  67 AC_MSG_RESULT($diff_cv_st_fstype_string)
  68 if test $diff_cv_st_fstype_string = yes; then
  69   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  70     [Define if struct stat has a char st_fstype[] member.])
  71 fi
  72
  73 AC_TYPE_SIGNAL
  74 AC_TYPE_MODE_T
  75 AC_TYPE_PID_T
  76 AC_TYPE_OFF_T
  77 AC_TYPE_SIZE_T
  78 AC_TYPE_UID_T
  79 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  80                                    [Type of major device numbers.]))
  81 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  82                                    [Type of minor device numbers.]))
  83 AC_CHECK_TYPE(dev_t, unsigned)
  84 AC_CHECK_TYPE(ino_t, unsigned)
  85
  86 gt_TYPE_SSIZE_T
  87
  88 # gnulib modules
  89 gl_INIT
  90 # paxutils modules
  91 tar_PAXUTILS
  92
  93 AC_CHECK_FUNCS(fsync getdtablesize lstat mkfifo readlink symlink setlocale utimes)
  94 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
  95 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
  96 AC_CHECK_DECLS([time],,, [#include <time.h>])
  97
  98 AC_REPLACE_FUNCS(waitpid)
  99
 100 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 101   [if test -n "$RSH"; then
 102     tar_cv_path_RSH=$RSH
 103   else
 104     tar_cv_path_RSH=no
 105     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 106         /usr/bin/nsh /usr/bin/rcmd
 107     do
 108       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 109       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 110       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 111       if test -f $ac_file; then
 112         if (test -h $ac_file) 2>/dev/null; then
 113           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 114         else
 115           tar_cv_path_RSH=$ac_file
 116           break
 117         fi
 118       fi
 119     done
 120   fi])
 121 if test $tar_cv_path_RSH = no; then
 122   AC_CHECK_HEADERS(netdb.h)
 123 else
 124   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 125     [Define to the full path of your rsh, if any.])
 126 fi
 127
 128 TAR_COMPR_PROGRAM(compress)
 129 TAR_COMPR_PROGRAM(gzip)
 130 TAR_COMPR_PROGRAM(bzip2)
 131 TAR_COMPR_PROGRAM(lzma)
 132 TAR_COMPR_PROGRAM(lzop)
 133 TAR_COMPR_PROGRAM(xz)
 134
 135 AC_MSG_CHECKING(for default archive format)
 136
 137 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 138            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 139
 140 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 141   DEFAULT_ARCHIVE_FORMAT="GNU"
 142 fi
 143 case $DEFAULT_ARCHIVE_FORMAT in
 144   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 145   *) AC_MSG_ERROR(Invalid format name);;
 146 esac
 147 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 148   [By default produce archives of this format])
 149 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 150
 151 AC_MSG_CHECKING(for default archive)
 152
 153 AC_ARG_VAR([DEFAULT_ARCHIVE],
 154            [Set the name of the default archive (default: -)])
 155 if test -z "$DEFAULT_ARCHIVE"; then
 156   DEFAULT_ARCHIVE=-
 157 else
 158   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 159     AC_MSG_WARN(DEFAULT_ARCHIVE \`$DEFAULT_ARCHIVE' not found on this system)
 160   fi
 161   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 162   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 163   # FIXME: Rearrange, here.
 164   case $DEFAULT_ARCHIVE in
 165     *[[0-7][lmh]])
 166       AC_DEFINE(DENSITY_LETTER, 1,
 167         [Define to 1 if density may be indicated by [lmh] at end of device.])
 168       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 169       ;;
 170     *[[0-7]])
 171       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 172       ;;
 173     *)
 174       device_prefix=
 175       ;;
 176   esac
 177   case "$device_prefix" in
 178     ?*)
 179       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 180         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 181       ;;
 182   esac
 183 fi
 184 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 185   [Define to a string giving the full name of the default archive file.])
 186 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 187
 188 AC_ARG_VAR([DEFAULT_BLOCKING],
 189            [Define default blocking factor (default: 20)])
 190 AC_MSG_CHECKING(for default blocking)
 191 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 192 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 193   [Define to a number giving the default blocking size for archives.])
 194 AC_MSG_RESULT($DEFAULT_BLOCKING)
 195
 196 AC_MSG_CHECKING(for default quoting style)
 197
 198 m4_define([QUOTING_STYLES],dnl
 199           [literal|shell|shell-always|c|escape|locale|clocale])
 200 DEFAULT_QUOTING_STYLE="escape"
 201 AC_ARG_VAR([DEFAULT_QUOTING_STYLE],
 202            [Set the default quoting style. Allowed values are: ] m4_bpatsubst(QUOTING_STYLES,[|], [[, ]]) [. Default is "escape".])
 203
 204 case $DEFAULT_QUOTING_STYLE in
 205 QUOTING_STYLES) ;;
 206 *)  AC_MSG_ERROR(Invalid quoting style);;
 207 esac
 208 AC_MSG_RESULT($DEFAULT_QUOTING_STYLE)
 209 DEFAULT_QUOTING_STYLE=`echo ${DEFAULT_QUOTING_STYLE}|sed 's/-/_/g'`_quoting_style
 210 AC_DEFINE_UNQUOTED(DEFAULT_QUOTING_STYLE, $DEFAULT_QUOTING_STYLE,
 211   [Define to a default quoting style (see lib/quoteargs.c for the list)])
 212
 213 # Iconv
 214 AM_ICONV
 215 AC_CHECK_HEADERS(iconv.h)
 216 AC_CHECK_TYPE(iconv_t,:,
 217               AC_DEFINE(iconv_t, int,
 218                         [Conversion descriptor type]),
 219               [
 220 #ifdef HAVE_ICONV_H
 221 # include <iconv.h>
 222 #endif
 223 ])
 224
 225 # Gettext.
 226 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 227 AM_GNU_GETTEXT_VERSION([0.16])
 228
 229 # Initialize the test suite.
 230 AC_CONFIG_TESTDIR(tests)
 231 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 232 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 233
 234 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 235 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 236 AC_ARG_ENABLE(backup-scripts,
 237               AC_HELP_STRING([--enable-backup-scripts],
 238                              [Create and install backup and restore scripts]),
 239               [case $enableval in
 240                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 241                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 242                     ;;
 243                esac])
 244
 245 AC_SUBST(BACKUP_SED_COND)
 246 if date +%Y-%m-%d 2>/dev/null >&2; then
 247         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 248 else
 249         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 250 fi
 251
 252 AC_OUTPUT([Makefile\
 253            doc/Makefile\
 254            gnu/Makefile\
 255            lib/Makefile\
 256            po/Makefile.in\
 257            scripts/Makefile\
 258            rmt/Makefile\
 259            src/Makefile])