perl/lib/Net/REPL/Client.pm

   1 package Net::REPL::Client;
   2 use strict;
   3 use warnings;
   4
   5 =pod
   6
   7 =head1 NAME
   8
   9 Net::REPL::Client - ReadLine + Socket to Eval Server = interactive development
  10
  11 =head1 DESCRIPTION
  12
  13 The client object connects L<Term::ReadLine> to a socket that speaks
  14 the L<Net::REPL::Server> protocol. Perl code is sent over the socket
  15 to be eval'd in the server process, which sends back a result for the
  16 client to print.
  17
  18 Like the Server, this class can be used as-is or superclassed to
  19 provide additional capabilities.
  20
  21 =head2 Methods
  22
  23 =cut
  24
  25 use base qw(Net::REPL::Base);
  26
  27 use IO::Socket::INET;
  28 use Term::ReadLine;
  29
  30 =head3 new(argument => value...)
  31
  32 Arguments:
  33
  34 =over
  35
  36 =item C<socket_args>
  37
  38 Hashref of arguments for L<IO::Socket::INET>.
  39
  40 =item C<debug>
  41
  42 Debug level (refer to L<Net::REPL::Base>).
  43
  44 =back
  45
  46 =cut
  47
  48 sub new {
  49     my $proto = shift;
  50     my $class = ref($proto) || $proto;
  51     my $self = {
  52         'socket_args' => {},
  53         'prompt' => '',
  54         @_,
  55     };
  56     bless($self, $class);
  57
  58     my $client = IO::Socket::INET->new(
  59         'Proto' => 'tcp',
  60         %{$self->{'socket_args'}},
  61     );
  62     if (not $client) {
  63         die("Can't connect client: $!\n");
  64     }
  65     $self->debug("Client PID $$ connected");
  66
  67     $self->{'fh'} = $client;
  68
  69     $self->setup_io();
  70
  71     return $self;
  72 }
  73
  74 sub DESTROY {
  75     my ($self) = @_;
  76
  77     if ($self->{'fh'}) {
  78         $self->{'fh'}->close();
  79     }
  80 }
  81
  82 =head3 interact()
  83
  84 Run one iteration of the REPL. Returns true if the socket remains open
  85 for further iterations.
  86
  87 Blocks until a line of input can be read from the terminal, sent to
  88 the server, and the result received and printed.
  89
  90 =cut
  91
  92 sub interact {
  93     my ($self) = @_;
  94
  95     my $input = $self->read();
  96     if (not defined($input)) {
  97         return 0;
  98     }
  99     elsif ($input eq '') {
 100         return 1;
 101     }
 102
 103     my $output;
 104     if ($input =~ m{^/(.*)$}) {
 105         # $input is a local command
 106         my ($cmd, $input) = split(/\s+/, $1);
 107         if ($cmd eq 'local_eval') {
 108             my @output = $self->formatted_eval($input);
 109             $output = "@output";
 110         }
 111         elsif ($cmd eq 'exit') {
 112             return 0;
 113         }
 114     }
 115     else {
 116         # $input is for remote eval
 117         $self->lv_send($input);
 118         $output = $self->lv_receive();
 119         if (not defined($output)) {
 120             # Server has gone away?
 121             return 0;
 122         }
 123     }
 124
 125     $self->print($output, "\n");
 126     return 1;
 127 }
 128
 129 =head3 setup_io()
 130
 131 Create the input source for L<read>() and output for L<print>().
 132
 133 =cut
 134
 135 sub setup_io {
 136     my ($self) = @_;
 137
 138     $self->{'term'} ||= Term::ReadLine->new($self->{'prompt'});
 139     $self->{'out_fh'} = $self->{'term'}->OUT();
 140 }
 141
 142 =head3 read()
 143
 144 Read and return one line of user input.
 145
 146 =cut
 147
 148 sub read {
 149     my ($self) = @_;
 150
 151     my $prompt = $self->{'prompt'} . '> ';
 152     return $self->{'term'}->readline($prompt);
 153 }
 154
 155 =head3 print()
 156
 157 Output the result string(s) from one L<interact>() iteration.
 158
 159 =cut
 160
 161 sub print {
 162     my ($self, @output) = @_;
 163
 164     for my $s (@output) {
 165         print { $self->{'out_fh'} } $s;
 166     }
 167 }
 168
 169
 170
 171 1;