configure.ac

   1 AC_INIT([tig],[0],[jonas.fonseca@gmail.com],[tig])
   2
   3 AC_LANG([C])
   4 AC_CONFIG_HEADER(config.h)
   5 AC_CONFIG_SRCDIR(src)
   6
   7 dnl  Document where we keep our .m4 file.
   8 AC_CONFIG_MACRO_DIR([tools])
   9 dnl  Make sure aclocal actually found it!
  10 m4_pattern_forbid([^AX_])
  11
  12 AC_PROG_CC
  13
  14 AC_CHECK_HEADERS([stdint.h stdlib.h string.h sys/time.h unistd.h])
  15 AC_CHECK_FUNCS([gettimeofday])
  16 AC_CHECK_DECLS([environ])
  17 AC_CHECK_DECLS([errno], [], [], [#include <errno.h>])
  18
  19 dnl Checks for compatibility flags
  20 AC_CHECK_FUNCS([mkstemps], [AC_SUBST([NO_MKSTEMPS], ["#"])])
  21 AC_CHECK_FUNCS([setenv], [AC_SUBST([NO_SETENV], ["#"])])
  22 AC_CHECK_FUNCS([strndup], [AC_SUBST([NO_STRNDUP], ["#"])])
  23
  24 AX_WITH_CURSES
  25 case "$ax_cv_ncurses" in "no")
  26         AC_MSG_ERROR([ncurses not found])
  27 esac
  28 case "$ax_cv_ncursesw" in "no")
  29         AC_MSG_WARN([The found ncurses library does not support wide-char.])
  30         AC_MSG_WARN([This means that tig will not correctly render UTF-8.])
  31 esac
  32 AC_SUBST(CURSES_LIB)
  33
  34 AX_LIB_READLINE(6.2)
  35
  36 AM_ICONV
  37
  38 AC_CHECK_PROGS(SED, [gsed], [sed])
  39 AC_TDD_GCOV
  40 AC_SUBST(COVERAGE_CFLAGS)
  41 AC_SUBST(COVERAGE_LDFLAGS)
  42
  43 AC_CHECK_PROGS(ASCIIDOC, [asciidoc], [false])
  44 AC_CHECK_PROGS(XMLTO, [xmlto], [false])
  45 AC_CHECK_PROGS(DOCBOOK2PDF, [docbook2pdf], [false])
  46
  47 AC_CONFIG_FILES([config.make])
  48 AC_OUTPUT
  49
  50 dnl Local Variables:
  51 dnl eval: (font-lock-add-keywords nil '(("\\_<AX_\\sw+" . font-lock-keyword-face)))
  52 dnl End: