release/src/router/openssl/VMS/install-vms.com

   1 $! install-vms.com -- Installs the files in a given directory tree
   2 $!
   3 $! Author: Richard Levitte <richard@levitte.org>
   4 $! Time of creation: 23-MAY-1998 19:22
   5 $!
   6 $! P1   root of the directory tree
   7 $!
   8 $!
   9 $! Announce/identify.
  10 $!
  11 $ proc = f$environment( "procedure")
  12 $ write sys$output "@@@ "+ -
  13    f$parse( proc, , , "name")+ f$parse( proc, , , "type")
  14 $!
  15 $ on error then goto tidy
  16 $ on control_c then goto tidy
  17 $!
  18 $ if p1 .eqs. ""
  19 $ then
  20 $   write sys$output "First argument missing."
  21 $   write sys$output -
  22      "Should be the directory where you want things installed."
  23 $   exit
  24 $ endif
  25 $
  26 $ if (f$getsyi( "cpu") .lt. 128)
  27 $ then
  28 $   arch = "VAX"
  29 $ else
  30 $   arch = f$edit( f$getsyi( "arch_name"), "upcase")
  31 $   if (arch .eqs. "") then arch = "UNK"
  32 $ endif
  33 $
  34 $ root = f$parse( P1, "[]A.;0", , , "SYNTAX_ONLY, NO_CONCEAL")- "A.;0"
  35 $ root_dev = f$parse( root, , , "device", "syntax_only")
  36 $ root_dir = f$parse( root, , , "directory", "syntax_only") - -
  37    "[000000." - "][" - "[" - "]"
  38 $ root = root_dev + "[" + root_dir
  39 $
  40 $ define /nolog wrk_sslroot 'root'.] /translation_attributes = concealed
  41 $ define /nolog wrk_sslinclude wrk_sslroot:[include]
  42 $
  43 $ if f$parse( "wrk_sslroot:[000000]") .eqs. "" then -
  44    create /directory /log wrk_sslroot:[000000]
  45 $ if f$parse( "wrk_sslinclude:") .eqs. "" then -
  46    create /directory /log wrk_sslinclude:
  47 $ if f$parse( "wrk_sslroot:[vms]") .eqs. "" then -
  48    create /directory /log wrk_sslroot:[vms]
  49 $!
  50 $ copy /log /protection = world:re openssl_startup.com wrk_sslroot:[vms]
  51 $ copy /log /protection = world:re openssl_undo.com wrk_sslroot:[vms]
  52 $ copy /log /protection = world:re openssl_utils.com wrk_sslroot:[vms]
  53 $!
  54 $ tidy:
  55 $!
  56 $ call deass wrk_sslroot
  57 $ call deass wrk_sslinclude
  58 $!
  59 $ exit
  60 $!
  61 $ deass: subroutine
  62 $ if (f$trnlnm( p1, "LNM$PROCESS") .nes. "")
  63 $ then
  64 $   deassign /process 'p1'
  65 $ endif
  66 $ endsubroutine
  67 $!