board/gen860t/u-boot.lds

   1 /*
   2  * Linker command file for the GEN860T board.
   3  *
   4  * (C) Copyright 2000-2010
   5  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   6  *
   7  * SPDX-License-Identifier:     GPL-2.0+
   8  */
   9
  10 OUTPUT_ARCH(powerpc)
  11 SECTIONS
  12 {
  13   /*
  14    * Read-only sections, merged into text segment:
  15    */
  16   . = + SIZEOF_HEADERS;
  17   .text :
  18   {
  19     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  20     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  21
  22     *(.text*)
  23   }
  24   _etext = .;
  25   PROVIDE (etext = .);
  26   .rodata    :
  27   {
  28     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  29   }
  30
  31   /*
  32    * Read-write section, merged into data segment:
  33    */
  34   . = (. + 0x00FF) & 0xFFFFFF00;
  35   _erotext = .;
  36   PROVIDE (erotext = .);
  37   .reloc   :
  38   {
  39     _GOT2_TABLE_ = .;
  40     KEEP(*(.got2))
  41     KEEP(*(.got))
  42     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  43     _FIXUP_TABLE_ = .;
  44     KEEP(*(.fixup))
  45   }
  46   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  47   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  48
  49   .data    :
  50   {
  51     *(.data*)
  52     *(.sdata*)
  53   }
  54   _edata  =  .;
  55   PROVIDE (edata = .);
  56
  57   . = .;
  58
  59   . = ALIGN(4);
  60   .u_boot_list : {
  61         KEEP(*(SORT(.u_boot_list*)));
  62   }
  63
  64
  65   . = .;
  66   __start___ex_table = .;
  67   __ex_table : { *(__ex_table) }
  68   __stop___ex_table = .;
  69
  70   . = ALIGN(256);
  71   __init_begin = .;
  72   .text.init : { *(.text.init) }
  73   .data.init : { *(.data.init) }
  74   . = ALIGN(256);
  75   __init_end = .;
  76
  77   __bss_start = .;
  78   .bss (NOLOAD)       :
  79   {
  80    *(.bss*)
  81    *(.sbss*)
  82    *(COMMON)
  83    . = ALIGN(4);
  84   }
  85   __bss_end = . ;
  86   PROVIDE (end = .);
  87 }