usr/src/lib/libc/amd64/gen/setjmp.s

   1 /*
   2  * CDDL HEADER START
   3  *
   4  * The contents of this file are subject to the terms of the
   5  * Common Development and Distribution License (the "License").
   6  * You may not use this file except in compliance with the License.
   7  *
   8  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
   9  * or http://www.opensolaris.org/os/licensing.
  10  * See the License for the specific language governing permissions
  11  * and limitations under the License.
  12  *
  13  * When distributing Covered Code, include this CDDL HEADER in each
  14  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
  15  * If applicable, add the following below this CDDL HEADER, with the
  16  * fields enclosed by brackets "[]" replaced with your own identifying
  17  * information: Portions Copyright [yyyy] [name of copyright owner]
  18  *
  19  * CDDL HEADER END
  20  */
  21
  22 /*
  23  * Copyright 2010 Sun Microsystems, Inc.  All rights reserved.
  24  * Use is subject to license terms.
  25  */
  26
  27         .file   "setjmp.s"
  28
  29 /*
  30  *      longjmp(env, val)
  31  * will generate a "return(val)" from
  32  * the last call to
  33  *      setjmp(env)
  34  * by restoring registers rip rsp rbp rbx r12 r13 r14 r15 from 'env'
  35  * and doing a return.
  36  */
  37
  38 /*
  39  * entry    reg   offset
  40  * env[0] = %rbx  0     register variables
  41  * env[1] = %r12  8
  42  * env[2] = %r13  16
  43  * env[3] = %r14  24
  44  * env[4] = %r15  32
  45  * env[5] = %rbp  40    stack frame
  46  * env[6] = %rsp  48
  47  * env[7] = %rip  56
  48  */
  49
  50 #include <sys/asm_linkage.h>
  51 #include <../assym.h>
  52
  53         ANSI_PRAGMA_WEAK(setjmp,function)
  54         ANSI_PRAGMA_WEAK(longjmp,function)
  55
  56         ENTRY(setjmp)
  57         movq    %rbx, 0(%rdi)
  58         movq    %r12, 8(%rdi)
  59         movq    %r13, 16(%rdi)
  60         movq    %r14, 24(%rdi)
  61         movq    %r15, 32(%rdi)
  62         movq    %rbp, 40(%rdi)
  63         popq    %rdx            /* return address */
  64         movq    %rsp, 48(%rdi)
  65         movq    %rdx, 56(%rdi)
  66
  67         movq    %fs:UL_SIGLINK, %rax
  68         xorq    %rcx, %rcx
  69         testq   %rax, %rax      /* are we in a signal handler? */
  70         jnz     1f
  71         incq    %rcx            /* no, tell longjmp to clear ul_siglink */
  72 1:      orq     %rcx, 48(%rdi)  /* low-order 1-bit flag in the saved %rsp */
  73
  74         xorl    %eax, %eax      /* return 0 */
  75         jmp     *%rdx
  76         SET_SIZE(setjmp)
  77
  78         ENTRY(longjmp)
  79         movq    0(%rdi), %rbx
  80         movq    8(%rdi), %r12
  81         movq    16(%rdi), %r13
  82         movq    24(%rdi), %r14
  83         movq    32(%rdi), %r15
  84         movq    40(%rdi), %rbp
  85
  86         movq    48(%rdi), %rax  /* test low-order bit in the saved %rsp */
  87         testq   $1, %rax
  88         jz      1f
  89         xorq    %rcx, %rcx      /* if set, clear ul_siglink */
  90         movq    %rcx, %fs:UL_SIGLINK
  91         subq    $1, %rax        /* clear the flag bit */
  92 1:      movq    %rax, %rsp
  93
  94         movl    %esi, %eax
  95         test    %eax, %eax      /* if val != 0          */
  96         jnz     1f              /*      return val      */
  97         incl    %eax            /* else return 1        */
  98 1:
  99         movq    56(%rdi), %rdx  /* return to caller of setjmp */
 100         jmp     *%rdx
 101         SET_SIZE(longjmp)