usr/src/cmd/sendmail/cf/feature/greet_pause.m4

   1 divert(-1)
   2 #
   3 # Copyright (c) 2004 Sendmail, Inc. and its suppliers.
   4 #       All rights reserved.
   5 #
   6 # By using this file, you agree to the terms and conditions set
   7 # forth in the LICENSE file which can be found at the top level of
   8 # the sendmail distribution.
   9 #
  10 # ident "%Z%%M% %I%     %E% SMI"
  11 #
  12
  13 divert(0)
  14 VERSIONID(`$Id: greet_pause.m4,v 1.4 2004/07/06 20:49:51 ca Exp $')
  15 divert(-1)
  16
  17 ifelse(len(X`'_ARG_),`1',`ifdef(`_ACCESS_TABLE_', `',
  18         `errprint(`*** ERROR: FEATURE(`greet_pause') requires FEATURE(`access_db')
  19 ')')')
  20
  21 define(`_GREET_PAUSE_', `')
  22
  23 LOCAL_RULESETS
  24 ######################################################################
  25 ###  greet_pause: lookup pause time before 220 greeting
  26 ###
  27 ###     Parameters:
  28 ###             $1: {client_name}
  29 ###             $2: {client_addr}
  30 ######################################################################
  31 SLocal_greet_pause
  32 Sgreet_pause
  33 R$*                     $: <$1><?> $| $>"Local_greet_pause" $1
  34 R<$*><?> $| $#$*        $#$2
  35 R<$*><?> $| $*          $: $1
  36 ifdef(`_ACCESS_TABLE_', `dnl
  37 R$+ $| $+               $: $>D < $1 > <?> <! GreetPause> < $2 >
  38 R   $| $+               $: $>A < $1 > <?> <! GreetPause> <>     empty client_name
  39 R<?> <$+>               $: $>A < $1 > <?> <! GreetPause> <>     no: another lookup
  40 ifelse(len(X`'_ARG_),`1',
  41 `R<?> <$*>              $@',
  42 `R<?> <$*>              $# _ARG_')
  43 R<$* <TMPF>> <$*>       $@
  44 R<$+> <$*>              $# $1',`dnl
  45 R$*                     $# _ARG_')