usr/src/cmd/sendmail/cf/feature/ratecontrol.m4

   1 divert(-1)
   2 #
   3 # Copyright (c) 2003, 2004 Sendmail, Inc. and its suppliers.
   4 #       All rights reserved.
   5 #
   6 # By using this file, you agree to the terms and conditions set
   7 # forth in the LICENSE file which can be found at the top level of
   8 # the sendmail distribution.
   9 #
  10 # ident "%Z%%M% %I%     %E% SMI"
  11 #
  12
  13 divert(0)
  14 VERSIONID(`$Id: ratecontrol.m4,v 1.5 2004/02/19 21:31:47 ca Exp $')
  15
  16 divert(-1)
  17 ifdef(`_ACCESS_TABLE_', `
  18         define(`_RATE_CONTROL_', `1')
  19         ifelse(defn(`_ARG_'), `', `',
  20                 strcasecmp(defn(`_ARG_'), `nodelay'), `1',
  21                 `ifdef(`_DELAY_CHECKS_',
  22                         `
  23                         define(`_RATE_CONTROL_IMMEDIATE_', `1')
  24                         define(`_CONTROL_IMMEDIATE_', `1')
  25                         ',
  26                         `errprint(`*** ERROR: FEATURE(`ratecontrol', `nodelay') requires FEATURE(`delay_checks')')'
  27                 )',
  28                 `errprint(`*** ERROR: unknown parameter '"defn(`_ARG_')"` for FEATURE(`ratecontrol')')')
  29         define(`_FFR_SRCHLIST_A', `1')
  30         ifelse(len(X`'_ARG2_), `1', `',
  31                 _ARG2_, `terminate', `define(`_RATE_CONTROL_REPLY', `421')',
  32                 `errprint(`*** ERROR: FEATURE(`ratecontrol'): unknown argument '"_ARG2_"
  33 )'
  34                 )
  35         ', `errprint(`*** ERROR: FEATURE(`ratecontrol') requires FEATURE(`access_db')
  36 ')')
  37 ifdef(`_RATE_CONTROL_REPLY',,`define(`_RATE_CONTROL_REPLY', `452')')