usr/src/cmd/sgs/rtld/i386/boot.s

   1 /*
   2  * CDDL HEADER START
   3  *
   4  * The contents of this file are subject to the terms of the
   5  * Common Development and Distribution License, Version 1.0 only
   6  * (the "License").  You may not use this file except in compliance
   7  * with the License.
   8  *
   9  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
  10  * or http://www.opensolaris.org/os/licensing.
  11  * See the License for the specific language governing permissions
  12  * and limitations under the License.
  13  *
  14  * When distributing Covered Code, include this CDDL HEADER in each
  15  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
  16  * If applicable, add the following below this CDDL HEADER, with the
  17  * fields enclosed by brackets "[]" replaced with your own identifying
  18  * information: Portions Copyright [yyyy] [name of copyright owner]
  19  *
  20  * CDDL HEADER END
  21  */
  22 /*
  23  *      Copyright (c) 1988 AT&T
  24  *        All Rights Reserved
  25  *
  26  *
  27  * Copyright 2004 Sun Microsystems, Inc.  All rights reserved.
  28  * Use is subject to license terms.
  29  */
  30
  31 /*
  32  * Bootstrap routine for run-time linker.
  33  * We get control from exec which has loaded our text and
  34  * data into the process' address space and created the process
  35  * stack.
  36  *
  37  * On entry, the process stack looks like this:
  38  *
  39  *      #                       # <- %esp
  40  *      #_______________________#  high addresses
  41  *      #       strings         #
  42  *      #_______________________#
  43  *      #       0 word          #
  44  *      #_______________________#
  45  *      #       Auxiliary       #
  46  *      #       entries         #
  47  *      #       ...             #
  48  *      #       (size varies)   #
  49  *      #_______________________#
  50  *      #       0 word          #
  51  *      #_______________________#
  52  *      #       Environment     #
  53  *      #       pointers        #
  54  *      #       ...             #
  55  *      #       (one word each) #
  56  *      #_______________________#
  57  *      #       0 word          #
  58  *      #_______________________#
  59  *      #       Argument        # low addresses
  60  *      #       pointers        #
  61  *      #       Argc words      #
  62  *      #_______________________#
  63  *      #       argc            #
  64  *      #_______________________# <- %ebp
  65  *
  66  *
  67  * We must calculate the address at which ld.so was loaded,
  68  * find the addr of the dynamic section of ld.so, of argv[0], and  of
  69  * the process' environment pointers - and pass the thing to _setup
  70  * to handle.  We then call _rtld - on return we jump to the entry
  71  * point for the a.out.
  72  */
  73
  74
  75 #include        <link.h>
  76
  77         .file   "boot.s"
  78         .text
  79         .globl  _rt_boot
  80         .globl  _setup
  81         .globl  _GLOBAL_OFFSET_TABLE_
  82         .type   _rt_boot,@function
  83         .align  4
  84
  85         / init is called from the _init symbol in the CRT, however .init_array
  86         / are called "naturally" from call_init.  Because of that, we need the
  87         / stack aligned here so that initializers called via _array sections may
  88         / safely use SIMD instructions.
  89 _rt_alias:
  90         jmp     .get_ip                 / in case we were invoked from libc.so
  91 _rt_boot:
  92         movl    %esp,%ebp               / save for referencing args
  93         subl    $EB_MAX_SIZE32,%esp     / make room for a max sized boot vector
  94         andl    $-16,%esp
  95         subl    $8,%esp
  96         movl    %esp,%esi               / use esi as a pointer to &eb[0]
  97         movl    $EB_ARGV,0(%esi)        / set up tag for argv
  98         leal    4(%ebp),%eax            / get address of argv
  99         movl    %eax,4(%esi)            / put after tag
 100         movl    $EB_ENVP,8(%esi)        / set up tag for envp
 101         movl    (%ebp),%eax             / get # of args
 102         addl    $2,%eax                 / one for the zero & one for argc
 103         leal    (%ebp,%eax,4),%edi      / now points past args & @ envp
 104         movl    %edi,12(%esi)           / set envp
 105 .L0:    addl    $4,%edi                 / next
 106         cmpl    $0,-4(%edi)             / search for 0 at end of env
 107         jne     .L0
 108         movl    $EB_AUXV,16(%esi)       / set up tag for auxv
 109         movl    %edi,20(%esi)           / point to auxv
 110         movl    $EB_NULL,24(%esi)       / set up NULL tag
 111 .get_ip:
 112         call    .L1                     / only way to get IP into a register
 113 .L1:
 114         popl    %ebx                    / pop the IP we just "pushed"
 115         addl    $_GLOBAL_OFFSET_TABLE_+[.-.L1],%ebx
 116         pushl   (%ebx)                  / address of dynamic structure
 117         pushl   %esi                    / push &eb[0]
 118
 119         call    _setup@PLT              / _setup(&eb[0], _DYNAMIC)
 120         movl    %ebp,%esp               / release stack frame
 121
 122         movl    atexit_fini@GOT(%ebx), %edx
 123         jmp     *%eax                   / transfer control to a.out
 124         .size   _rt_boot,.-_rt_boot
 125