vala/valadeletestatement.vala

   1 /* valadeletestatement.vala
   2  *
   3  * Copyright (C) 2008-2011  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 /**
  24  * Represents a delete statement e.g. "delete a".
  25  */
  26 public class Vala.DeleteStatement : CodeNode, Statement {
  27         /**
  28          * Expression representing the instance to be freed.
  29          */
  30         public Expression expression {
  31                 get { return _expression; }
  32                 set {
  33                         _expression = value;
  34                         _expression.parent_node = this;
  35                 }
  36         }
  37
  38         private Expression _expression;
  39
  40         public DeleteStatement (Expression expression, SourceReference? source_reference = null) {
  41                 this.expression = expression;
  42                 this.source_reference = source_reference;
  43         }
  44
  45         public override void accept (CodeVisitor visitor) {
  46                 visitor.visit_delete_statement (this);
  47         }
  48
  49         public override void accept_children (CodeVisitor visitor) {
  50                 expression.accept (visitor);
  51         }
  52
  53         public override bool check (CodeContext context) {
  54                 if (checked) {
  55                         return !error;
  56                 }
  57
  58                 checked = true;
  59
  60                 if (!expression.check (context)) {
  61                         // if there was an error in the inner expression, skip this check
  62                         return false;
  63                 }
  64
  65                 if (!(expression.value_type is PointerType) && !(expression.value_type is ArrayType)) {
  66                         error = true;
  67                         Report.error (source_reference, "delete operator not supported for `%s'".printf (expression.value_type.to_string ()));
  68                 }
  69
  70                 return !error;
  71         }
  72
  73         public override void emit (CodeGenerator codegen) {
  74                 expression.emit (codegen);
  75
  76                 codegen.visit_delete_statement (this);
  77         }
  78 }