libvaladoc/api/struct.vala

   1 /* struct.vala
   2  *
   3  * Copyright (C) 2011  Florian Brosch
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9  *
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Florian Brosch <flo.brosch@gmail.com>
  21  */
  22
  23
  24 using Valadoc.Content;
  25
  26 /**
  27  * Represents a struct declaration.
  28  */
  29 public class Valadoc.Api.Struct : TypeSymbol {
  30         private string? dup_function_cname;
  31         private string? copy_function_cname;
  32         private string? free_function_cname;
  33         private string? destroy_function_cname;
  34         private string? type_id;
  35         private string? cname;
  36
  37         public Struct (Node parent, SourceFile file, string name, SymbolAccessibility accessibility,
  38                                    SourceComment? comment, string? cname, string? type_macro_name,
  39                                    string? type_function_name, string? type_id, string? dup_function_cname,
  40                                    string? copy_function_cname, string? destroy_function_cname,
  41                                    string? free_function_cname, bool is_basic_type, Vala.Struct data)
  42         {
  43                 base (parent, file, name, accessibility, comment, type_macro_name, null, null,
  44                         type_function_name, is_basic_type, data);
  45
  46                 this.dup_function_cname = dup_function_cname;
  47                 this.copy_function_cname = copy_function_cname;
  48                 this.free_function_cname = free_function_cname;
  49                 this.destroy_function_cname = destroy_function_cname;
  50
  51                 this.cname = cname;
  52         }
  53
  54         /**
  55          * Specifies the base struct.
  56          */
  57         public TypeReference? base_type {
  58                 set;
  59                 get;
  60         }
  61
  62
  63         /**
  64          * Returns the name of this struct as it is used in C.
  65          */
  66         public string? get_cname () {
  67                 return cname;
  68         }
  69
  70         /**
  71          * Returns the C symbol representing the runtime type id for this data type.
  72          */
  73         public string? get_type_id () {
  74                 return type_id;
  75         }
  76
  77         /**
  78          * Returns the C function name that duplicates instances of this data
  79          * type.
  80          */
  81         public string? get_dup_function_cname () {
  82                 return dup_function_cname;
  83         }
  84
  85         /**
  86          * Returns the C function name that copies instances of this data
  87          * type.
  88          */
  89         public string? get_copy_function_cname () {
  90                 return copy_function_cname;
  91         }
  92
  93         /**
  94          * Returns the C function name that frees instances of this data type.
  95          */
  96         public string? get_free_function_cname () {
  97                 return free_function_cname;
  98         }
  99
 100         /**
 101          * Returns the C function name that destroys instances of this data type.
 102          */
 103         public string? get_destroy_function_cname () {
 104                 return destroy_function_cname;
 105         }
 106
 107         /**
 108          * {@inheritDoc}
 109          */
 110         public override NodeType node_type {
 111                 get { return NodeType.STRUCT; }
 112         }
 113
 114         /**
 115          * {@inheritDoc}
 116          */
 117         public override void accept (Visitor visitor) {
 118                 visitor.visit_struct (this);
 119         }
 120
 121
 122         private Vala.Set<Struct> _known_child_structs = new Vala.HashSet<Struct> ();
 123
 124         /**
 125          * Returns a list of all known structs based on this struct
 126          */
 127         public Vala.Collection<Struct> get_known_child_structs () {
 128                 return _known_child_structs;
 129         }
 130
 131         public void register_child_struct (Struct stru) {
 132                 if (this.base_type != null) {
 133                         ((Struct) this.base_type.data_type).register_child_struct (stru);
 134                 }
 135
 136                 _known_child_structs.add (stru);
 137         }
 138
 139
 140         /**
 141          * {@inheritDoc}
 142          */
 143         protected override Inline build_signature () {
 144                 var signature = new SignatureBuilder ();
 145
 146                 signature.append_keyword (accessibility.to_string ());
 147                 signature.append_keyword ("struct");
 148                 signature.append_symbol (this);
 149
 150                 var type_parameters = get_children_by_type (NodeType.TYPE_PARAMETER, false);
 151                 if (type_parameters.size > 0) {
 152                         signature.append ("<", false);
 153                         bool first = true;
 154                         foreach (Item param in type_parameters) {
 155                                 if (!first) {
 156                                         signature.append (",", false);
 157                                 }
 158                                 signature.append_content (param.signature, false);
 159                                 first = false;
 160                         }
 161                         signature.append (">", false);
 162                 }
 163
 164                 if (base_type != null) {
 165                         signature.append (":");
 166
 167                         signature.append_content (base_type.signature);
 168                 }
 169
 170                 return signature.get ();
 171         }
 172 }
 173