vala/valacatchclause.vala

   1 /* valacatchvala
   2  *
   3  * Copyright (C) 2007-2008  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using Gee;
  24
  25 /**
  26  * Represents a catch clause in a try statement in the source code.
  27  */
  28 public class Vala.CatchClause : CodeNode {
  29         /**
  30          * Specifies the error type.
  31          */
  32         public DataType? error_type {
  33                 get { return _data_type; }
  34                 set {
  35                         _data_type = value;
  36                         if (_data_type != null) {
  37                                 _data_type.parent_node = this;
  38                         }
  39                 }
  40         }
  41
  42         /**
  43          * Specifies the error variable name.
  44          */
  45         public string? variable_name { get; set; }
  46
  47         /**
  48          * Specifies the error handler body.
  49          */
  50         public Block body { get; set; }
  51
  52         /**
  53          * Specifies the declarator for the generated error variable.
  54          */
  55         public LocalVariable error_variable { get; set; }
  56
  57         /**
  58          * Specifies the label used for this catch clause in the C code.
  59          */
  60         public string? clabel_name { get; set; }
  61
  62         private DataType _data_type;
  63
  64         /**
  65          * Creates a new catch
  66          *
  67          * @param type_reference   error type
  68          * @param variable_name    error variable name
  69          * @param body             error handler body
  70          * @param source_reference reference to source code
  71          * @return                 newly created catch clause
  72          */
  73         public CatchClause (DataType? error_type, string? variable_name, Block body, SourceReference? source_reference = null) {
  74                 this.error_type = error_type;
  75                 this.variable_name = variable_name;
  76                 this.body = body;
  77                 this.source_reference = source_reference;
  78         }
  79
  80         public override void accept (CodeVisitor visitor) {
  81                 visitor.visit_catch_clause (this);
  82         }
  83
  84         public override void accept_children (CodeVisitor visitor) {
  85                 if (error_type != null) {
  86                         error_type.accept (visitor);
  87                 }
  88
  89                 body.accept (visitor);
  90         }
  91
  92         public override void replace_type (DataType old_type, DataType new_type) {
  93                 if (error_type == old_type) {
  94                         error_type = new_type;
  95                 }
  96         }
  97
  98         public override bool check (SemanticAnalyzer analyzer) {
  99                 if (checked) {
 100                         return !error;
 101                 }
 102
 103                 checked = true;
 104
 105                 if (error_type != null) {
 106                         error_variable = new LocalVariable (error_type.copy (), variable_name);
 107
 108                         body.scope.add (variable_name, error_variable);
 109                         body.add_local_variable (error_variable);
 110
 111                         error_variable.checked = true;
 112                 } else {
 113                         error_type = new ErrorType (null, null, source_reference);
 114                 }
 115
 116                 error_type.check (analyzer);
 117
 118                 analyzer.current_source_file.add_type_dependency (error_type, SourceFileDependencyType.SOURCE);
 119
 120                 body.check (analyzer);
 121
 122                 return !error;
 123         }
 124
 125         public override void get_defined_variables (Collection<LocalVariable> collection) {
 126                 if (error_variable != null) {
 127                         collection.add (error_variable);
 128                 }
 129         }
 130 }