vala/valaconstant.vala

   1 /* valaconstant.vala
   2  *
   3  * Copyright (C) 2006-2008  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents a type member with a constant value.
  27  */
  28 public class Vala.Constant : Member, Lockable {
  29         /**
  30          * The data type of this constant.
  31          */
  32         public DataType type_reference {
  33                 get { return _data_type; }
  34                 set {
  35                         _data_type = value;
  36                         _data_type.parent_node = this;
  37                 }
  38         }
  39
  40         /**
  41          * The value of this constant.
  42          */
  43         public Expression? initializer {
  44                 get { return _initializer; }
  45                 set {
  46                         _initializer = value;
  47                         if (_initializer != null) {
  48                                 _initializer.parent_node = this;
  49                         }
  50                 }
  51         }
  52
  53         private string cname;
  54
  55         private bool lock_used = false;
  56
  57         private DataType _data_type;
  58
  59         private Expression _initializer;
  60
  61         /**
  62          * Creates a new constant.
  63          *
  64          * @param name             constant name
  65          * @param type_reference   constant type
  66          * @param initializer      constant value
  67          * @param source_reference reference to source code
  68          * @return                 newly created constant
  69          */
  70         public Constant (string name, DataType type_reference, Expression? initializer, SourceReference? source_reference) {
  71                 base (name, source_reference);
  72                 this.type_reference = type_reference;
  73                 this.initializer = initializer;
  74         }
  75
  76         public override void accept (CodeVisitor visitor) {
  77                 visitor.visit_member (this);
  78
  79                 visitor.visit_constant (this);
  80         }
  81
  82         public override void accept_children (CodeVisitor visitor) {
  83                 type_reference.accept (visitor);
  84
  85                 if (initializer != null) {
  86                         initializer.accept (visitor);
  87                 }
  88         }
  89
  90         /**
  91          * Returns the name of this constant as it is used in C code.
  92          *
  93          * @return the name to be used in C code
  94          */
  95         public string get_cname () {
  96                 if (cname == null) {
  97                         cname = get_default_cname ();
  98                 }
  99                 return cname;
 100         }
 101
 102         /**
 103          * Returns the default name of this constant as it is used in C
 104          * code.
 105          *
 106          * @return the name to be used in C code by default
 107          */
 108         public string get_default_cname () {
 109                 if (parent_symbol == null) {
 110                         // global constant
 111                         return name;
 112                 } else {
 113                         return "%s%s".printf (parent_symbol.get_lower_case_cprefix ().up (), name);
 114                 }
 115         }
 116
 117         public bool get_lock_used () {
 118                 return lock_used;
 119         }
 120
 121         public void set_lock_used (bool used) {
 122                 lock_used = used;
 123         }
 124
 125         public override void replace_type (DataType old_type, DataType new_type) {
 126                 if (type_reference == old_type) {
 127                         type_reference = new_type;
 128                 }
 129         }
 130
 131         private void process_ccode_attribute (Attribute a) {
 132                 if (a.has_argument ("cname")) {
 133                         cname = a.get_string ("cname");
 134                 }
 135                 if (a.has_argument ("cheader_filename")) {
 136                         var val = a.get_string ("cheader_filename");
 137                         foreach (string filename in val.split (",")) {
 138                                 add_cheader_filename (filename);
 139                         }
 140                 }
 141         }
 142
 143         /**
 144          * Process all associated attributes.
 145          */
 146         public void process_attributes () {
 147                 foreach (Attribute a in attributes) {
 148                         if (a.name == "CCode") {
 149                                 process_ccode_attribute (a);
 150                         }
 151                 }
 152         }
 153
 154         public override bool check (SemanticAnalyzer analyzer) {
 155                 if (checked) {
 156                         return !error;
 157                 }
 158
 159                 checked = true;
 160
 161                 process_attributes ();
 162
 163                 type_reference.check (analyzer);
 164
 165                 if (!external_package) {
 166                         if (initializer == null) {
 167                                 error = true;
 168                                 Report.error (source_reference, "A const field requires a initializer to be provided");
 169                         } else {
 170                                 initializer.target_type = type_reference;
 171
 172                                 initializer.check (analyzer);
 173                         }
 174                 }
 175
 176                 return !error;
 177         }
 178 }