vala/valaenumvalue.vala

   1 /* valaenumvalue.vala
   2  *
   3  * Copyright (C) 2006-2008  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents an enum member in the source code.
  27  */
  28 public class Vala.EnumValue : Symbol {
  29         /**
  30          * Specifies the numerical representation of this enum value.
  31          */
  32         public Expression value { get; set; }
  33
  34         private string cname;
  35
  36         /**
  37          * Creates a new enum value.
  38          *
  39          * @param name enum value name
  40          * @return     newly created enum value
  41          */
  42         public EnumValue (string name, SourceReference? source_reference = null) {
  43                 base (name, source_reference);
  44         }
  45
  46         /**
  47          * Creates a new enum value with the specified numerical representation.
  48          *
  49          * @param name  enum value name
  50          * @param value numerical representation
  51          * @return      newly created enum value
  52          */
  53         public EnumValue.with_value (string name, Expression value, SourceReference? source_reference = null) {
  54                 this (name, source_reference);
  55                 this.value = value;
  56         }
  57
  58         /**
  59          * Returns the string literal of this signal to be used in C code.
  60          * (FIXME: from vlaasignal.vala)
  61          *
  62          * @return string literal to be used in C code
  63          */
  64         public CCodeConstant get_canonical_cconstant () {
  65                 var str = new StringBuilder ("\"");
  66
  67                 string i = name;
  68
  69                 while (i.len () > 0) {
  70                         unichar c = i.get_char ();
  71                         if (c == '_') {
  72                                 str.append_c ('-');
  73                         } else {
  74                                 str.append_unichar (c.tolower ());
  75                         }
  76
  77                         i = i.next_char ();
  78                 }
  79
  80                 str.append_c ('"');
  81
  82                 return new CCodeConstant (str.str);
  83         }
  84
  85         public override void accept (CodeVisitor visitor) {
  86                 visitor.visit_enum_value (this);
  87         }
  88
  89         public override void accept_children (CodeVisitor visitor) {
  90                 if (value != null) {
  91                         value.accept (visitor);
  92                 }
  93         }
  94
  95         /**
  96          * Process all associated attributes.
  97          */
  98         public void process_attributes () {
  99                 foreach (Attribute a in attributes) {
 100                         if (a.name == "CCode" && a.has_argument("cname")) {
 101                                 cname = a.get_string ("cname");
 102                         }
 103                 }
 104         }
 105
 106         /**
 107          * Returns the name of this enum value as it is used in C code.
 108          *
 109          * @return the name to be used in C code
 110          */
 111         public string get_cname () {
 112                 if (cname == null) {
 113                         cname = get_default_cname ();
 114                 }
 115                 return cname;
 116         }
 117
 118         public string get_default_cname () {
 119                 var en = (Enum) parent_symbol;
 120                 return "%s%s".printf (en.get_cprefix (), name);
 121         }
 122
 123         /**
 124          * Sets the name of this enum value to be used in C code.
 125          *
 126          * @param cname the name to be used in C code
 127          */
 128         public void set_cname (string cname) {
 129                 this.cname = cname;
 130         }
 131
 132         public override bool check (SemanticAnalyzer analyzer) {
 133                 if (checked) {
 134                         return !error;
 135                 }
 136
 137                 checked = true;
 138
 139                 process_attributes ();
 140
 141                 if (value != null) {
 142                         value.check (analyzer);
 143                 }
 144
 145                 return !error;
 146         }
 147 }