ccode/valaccodewriter.vala

   1 /* valaccodewriter.vala
   2  *
   3  * Copyright (C) 2006-2008  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents a writer to write C source files.
  27  */
  28 public class Vala.CCodeWriter : Object {
  29         /**
  30          * Specifies the file to be written.
  31          */
  32         public string filename {
  33                 get {
  34                         return _filename;
  35                 }
  36                 construct {
  37                         _filename = value;
  38                 }
  39         }
  40
  41         /**
  42          * Specifies whether to emit line directives.
  43          */
  44         public bool line_directives { get; set; }
  45
  46         /**
  47          * Specifies whether the output stream is at the beginning of a line.
  48          */
  49         public bool bol {
  50                 get { return _bol; }
  51         }
  52
  53         private string _filename;
  54         private string temp_filename;
  55         private bool file_exists;
  56
  57         private FileStream stream;
  58
  59         private int indent;
  60
  61         /* at begin of line */
  62         private bool _bol = true;
  63
  64         public CCodeWriter (string _filename) {
  65                 filename = _filename;
  66         }
  67
  68         /**
  69          * Opens the file.
  70          *
  71          * @return true if the file has been opened successfully,
  72          *         false otherwise
  73          */
  74         public bool open () {
  75                 file_exists = FileUtils.test (_filename, FileTest.EXISTS);
  76                 if (file_exists) {
  77                         temp_filename = "%s.valatmp".printf (_filename);
  78                         stream = FileStream.open (temp_filename, "w");
  79                 } else {
  80                         stream = FileStream.open (_filename, "w");
  81                 }
  82
  83                 return (stream != null);
  84         }
  85
  86         /**
  87          * Closes the file.
  88          */
  89         public void close () {
  90                 stream = null;
  91
  92                 if (file_exists) {
  93                         var changed = true;
  94
  95                         try {
  96                                 var old_file = new MappedFile (_filename, false);
  97                                 var new_file = new MappedFile (temp_filename, false);
  98                                 var len = old_file.get_length ();
  99                                 if (len == new_file.get_length ()) {
 100                                         if (Memory.cmp (old_file.get_contents (), new_file.get_contents (), len) == 0) {
 101                                                 changed = false;
 102                                         }
 103                                 }
 104                                 old_file = null;
 105                                 new_file = null;
 106                         } catch (FileError e) {
 107                                 // assume changed if mmap comparison doesn't work
 108                         }
 109
 110                         if (changed) {
 111                                 FileUtils.rename (temp_filename, _filename);
 112                         } else {
 113                                 FileUtils.unlink (temp_filename);
 114                         }
 115                 }
 116         }
 117
 118         /**
 119          * Writes tabs according to the current indent level.
 120          */
 121         public void write_indent (CCodeLineDirective? line = null) {
 122                 if (line_directives && line != null) {
 123                         line.write (this);
 124                 }
 125
 126                 if (!bol) {
 127                         stream.putc ('\n');
 128                 }
 129
 130                 for (int i = 0; i < indent; i++) {
 131                         stream.putc ('\t');
 132                 }
 133
 134                 _bol = false;
 135         }
 136
 137         /**
 138          * Writes the specified string.
 139          *
 140          * @param s a string
 141          */
 142         public void write_string (string s) {
 143                 stream.printf ("%s", s);
 144                 _bol = false;
 145         }
 146
 147         /**
 148          * Writes a newline.
 149          */
 150         public void write_newline () {
 151                 stream.putc ('\n');
 152                 _bol = true;
 153         }
 154
 155         /**
 156          * Opens a new block, increasing the indent level.
 157          */
 158         public void write_begin_block () {
 159                 if (!bol) {
 160                         stream.putc (' ');
 161                 } else {
 162                         write_indent ();
 163                 }
 164                 stream.putc ('{');
 165                 write_newline ();
 166                 indent++;
 167         }
 168
 169         /**
 170          * Closes the current block, decreasing the indent level.
 171          */
 172         public void write_end_block () {
 173                 assert (indent > 0);
 174
 175                 indent--;
 176                 write_indent ();
 177                 stream.printf ("}");
 178         }
 179
 180         /**
 181          * Writes the specified text as comment.
 182          *
 183          * @param text the comment text
 184          */
 185         public void write_comment (string text) {
 186                 write_indent ();
 187                 stream.printf ("/*");
 188                 bool first = true;
 189
 190                 /* separate declaration due to missing memory management in foreach statements */
 191                 var lines = text.split ("\n");
 192
 193                 foreach (string line in lines) {
 194                         if (!first) {
 195                                 write_indent ();
 196                         } else {
 197                                 first = false;
 198                         }
 199                         stream.printf ("%s", line);
 200                 }
 201                 stream.printf ("*/");
 202                 write_newline ();
 203         }
 204 }