vala/valaaddressofexpression.vala

   1 /* valaaddressofexpression.vala
   2  *
   3  * Copyright (C) 2007-2008  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24
  25 /**
  26  * Represents an address-of expression in the source code, e.g. `&foo'.
  27  */
  28 public class Vala.AddressofExpression : Expression {
  29         /**
  30          * The variable whose address is to be computed.
  31          */
  32         public Expression inner {
  33                 get {
  34                         return _inner;
  35                 }
  36                 set {
  37                         _inner = value;
  38                         _inner.parent_node = this;
  39                 }
  40         }
  41
  42         private Expression _inner;
  43
  44         /**
  45          * Creates a new address-of expression.
  46          *
  47          * @param inner variable whose address is to be computed
  48          * @return      newly created address-of expression
  49          */
  50         public AddressofExpression (Expression inner, SourceReference? source_reference = null) {
  51                 this.source_reference = source_reference;
  52                 this.inner = inner;
  53         }
  54
  55         public override void accept (CodeVisitor visitor) {
  56                 inner.accept (visitor);
  57
  58                 visitor.visit_addressof_expression (this);
  59
  60                 visitor.visit_expression (this);
  61         }
  62
  63         public override void replace_expression (Expression old_node, Expression new_node) {
  64                 if (inner == old_node) {
  65                         inner = new_node;
  66                 }
  67         }
  68
  69         public override bool is_pure () {
  70                 return inner.is_pure ();
  71         }
  72
  73         public override bool check (SemanticAnalyzer analyzer) {
  74                 if (checked) {
  75                         return !error;
  76                 }
  77
  78                 checked = true;
  79
  80                 if (!inner.check (analyzer)) {
  81                         error = true;
  82                         return false;
  83                 }
  84                 if (!(inner.value_type is ValueType
  85                       || inner.value_type is ObjectType
  86                       || inner.value_type is PointerType)) {
  87                         error = true;
  88                         Report.error (source_reference, "Address-of operator not supported for this expression");
  89                         return false;
  90                 }
  91
  92                 if (inner.value_type.is_reference_type_or_type_parameter ()) {
  93                         value_type = new PointerType (new PointerType (inner.value_type));
  94                 } else {
  95                         value_type = new PointerType (inner.value_type);
  96                 }
  97
  98                 return !error;
  99         }
 100 }