vala/valaexpression.vala

   1 /* valaexpression.vala
   2  *
   3  * Copyright (C) 2006-2008  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using GLib;
  24 using Gee;
  25
  26 /**
  27  * Base class for all code nodes that might be used as an expression.
  28  */
  29 public abstract class Vala.Expression : CodeNode {
  30         /**
  31          * The static type of the value of this expression.
  32          *
  33          * The semantic analyzer computes this value.
  34          */
  35         public DataType value_type { get; set; }
  36
  37         public DataType? formal_value_type { get; set; }
  38
  39         /*
  40          * The static type this expression is expected to have.
  41          *
  42          * The semantic analyzer computes this value, lambda expressions use it.
  43          */
  44         public DataType target_type { get; set; }
  45
  46         public DataType? formal_target_type { get; set; }
  47
  48         /**
  49          * The symbol this expression refers to.
  50          */
  51         public weak Symbol symbol_reference { get; set; }
  52
  53         /**
  54          * Specifies that this expression is used as lvalue, i.e. the
  55          * left hand side of an assignment.
  56          */
  57         public bool lvalue { get; set; }
  58
  59         /**
  60          * Contains all temporary variables this expression requires for
  61          * execution.
  62          *
  63          * The code generator sets and uses them for memory management.
  64          */
  65         public ArrayList<LocalVariable> temp_vars = new ArrayList<LocalVariable> ();
  66
  67         /**
  68          * Returns whether this expression is constant, i.e. whether this
  69          * expression only consists of literals and other constants.
  70          */
  71         public virtual bool is_constant () {
  72                 return false;
  73         }
  74
  75         /**
  76          * Returns whether this expression is pure, i.e. whether this expression
  77          * is free of side-effects.
  78          */
  79         public abstract bool is_pure ();
  80
  81         /**
  82          * Returns whether this expression is guaranteed to be non-null.
  83          */
  84         public virtual bool is_non_null () {
  85                 return false;
  86         }
  87
  88         public Statement? parent_statement {
  89                 get {
  90                         var expr = parent_node as Expression;
  91                         var stmt = parent_node as Statement;
  92                         var local = parent_node as LocalVariable;
  93                         if (stmt != null) {
  94                                 return stmt;
  95                         } else if (expr != null) {
  96                                 return expr.parent_statement;
  97                         } else if (local != null) {
  98                                 return (Statement) local.parent_node;
  99                         } else {
 100                                 return null;
 101                         }
 102                 }
 103         }
 104
 105         public Block prepare_condition_split (SemanticAnalyzer analyzer) {
 106                 var while_stmt = parent_statement as WhileStatement;
 107                 var do_stmt = parent_statement as DoStatement;
 108                 var for_stmt = parent_statement as ForStatement;
 109
 110                 if (while_stmt != null) {
 111                         return while_stmt.prepare_condition_split (analyzer);
 112                 } else if (do_stmt != null) {
 113                         return do_stmt.prepare_condition_split (analyzer);
 114                 } else if (for_stmt != null) {
 115                         return for_stmt.prepare_condition_split (analyzer);
 116                 }
 117
 118                 return analyzer.insert_block;
 119         }
 120
 121         public void insert_statement (Block block, Statement stmt) {
 122                 block.insert_before (parent_statement, stmt);
 123         }
 124 }