vala/valaexpressionstatement.vala

   1 /* valaexpressionstatement.vala
   2  *
   3  * Copyright (C) 2006-2008  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23 using Gee;
  24
  25 /**
  26  * A code statement that evaluates a given expression. The value computed by the
  27  * expression, if any, is discarded.
  28  */
  29 public class Vala.ExpressionStatement : CodeNode, Statement {
  30         /**
  31          * Specifies the expression to evaluate.
  32          */
  33         public Expression expression {
  34                 get {
  35                         return _expression;
  36                 }
  37                 set {
  38                         _expression = value;
  39                         _expression.parent_node = this;
  40                 }
  41         }
  42
  43         private Expression _expression;
  44
  45         /**
  46          * Creates a new expression statement.
  47          *
  48          * @param expr   expression to evaluate
  49          * @param source reference to source code
  50          * @return       newly created expression statement
  51          */
  52         public ExpressionStatement (Expression expression, SourceReference? source_reference = null) {
  53                 this.source_reference = source_reference;
  54                 this.expression = expression;
  55         }
  56
  57         public override void accept (CodeVisitor visitor) {
  58                 visitor.visit_expression_statement (this);
  59         }
  60
  61         public override void accept_children (CodeVisitor visitor) {
  62                 expression.accept (visitor);
  63         }
  64
  65         public override void replace_expression (Expression old_node, Expression new_node) {
  66                 if (expression == old_node) {
  67                         expression = new_node;
  68                 }
  69         }
  70
  71         /**
  72          * Returns the property this statement sets, if any.
  73          *
  74          * @return the property this statement sets, or null if it doesn't set
  75          *         a property
  76          */
  77         public Property? assigned_property () {
  78                 if (expression is Assignment) {
  79                         var assign = (Assignment) expression;
  80                         if (assign.left is MemberAccess) {
  81                                 var ma = (MemberAccess) assign.left;
  82                                 if (ma.symbol_reference is Property) {
  83                                         return (Property) ma.symbol_reference;
  84                                 }
  85                         }
  86                 }
  87
  88                 return null;
  89         }
  90
  91         public override bool check (SemanticAnalyzer analyzer) {
  92                 if (checked) {
  93                         return !error;
  94                 }
  95
  96                 checked = true;
  97
  98                 if (!expression.check (analyzer)) {
  99                         // ignore inner error
 100                         error = true;
 101                         return false;
 102                 }
 103
 104                 add_error_types (expression.get_error_types ());
 105
 106                 return !error;
 107         }
 108
 109         public override void get_defined_variables (Collection<LocalVariable> collection) {
 110                 expression.get_defined_variables (collection);
 111         }
 112
 113         public override void get_used_variables (Collection<LocalVariable> collection) {
 114                 expression.get_used_variables (collection);
 115         }
 116 }