vala/valaunaryexpression.vala

   1 /* valaunaryexpression.vala
   2  *
   3  * Copyright (C) 2006-2011  Jürg Billeter
   4  *
   5  * This library is free software; you can redistribute it and/or
   6  * modify it under the terms of the GNU Lesser General Public
   7  * License as published by the Free Software Foundation; either
   8  * version 2.1 of the License, or (at your option) any later version.
   9
  10  * This library is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13  * Lesser General Public License for more details.
  14
  15  * You should have received a copy of the GNU Lesser General Public
  16  * License along with this library; if not, write to the Free Software
  17  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
  18  *
  19  * Author:
  20  *      Jürg Billeter <j@bitron.ch>
  21  */
  22
  23
  24 /**
  25  * Represents an expression with one operand in the source code.
  26  *
  27  * Supports +, -, !, ~, ref, out.
  28  */
  29 public class Vala.UnaryExpression : Expression {
  30         /**
  31          * The unary operator.
  32          */
  33         public UnaryOperator operator { get; set; }
  34
  35         /**
  36          * The operand.
  37          */
  38         public Expression inner {
  39                 get {
  40                         return _inner;
  41                 }
  42                 set {
  43                         _inner = value;
  44                         _inner.parent_node = this;
  45                 }
  46         }
  47
  48         private Expression _inner;
  49
  50         /**
  51          * Creates a new unary expression.
  52          *
  53          * @param op     unary operator
  54          * @param inner  operand
  55          * @param source reference to source code
  56          * @return       newly created binary expression
  57          */
  58         public UnaryExpression (UnaryOperator op, Expression _inner, SourceReference source) {
  59                 operator = op;
  60                 inner = _inner;
  61                 source_reference = source;
  62         }
  63
  64         public override void accept (CodeVisitor visitor) {
  65                 visitor.visit_unary_expression (this);
  66
  67                 visitor.visit_expression (this);
  68         }
  69
  70         public override void accept_children (CodeVisitor visitor) {
  71                 inner.accept (visitor);
  72         }
  73
  74         public override void replace_expression (Expression old_node, Expression new_node) {
  75                 if (inner == old_node) {
  76                         inner = new_node;
  77                 }
  78         }
  79
  80         private string get_operator_string () {
  81                 switch (_operator) {
  82                 case UnaryOperator.PLUS: return "+";
  83                 case UnaryOperator.MINUS: return "-";
  84                 case UnaryOperator.LOGICAL_NEGATION: return "!";
  85                 case UnaryOperator.BITWISE_COMPLEMENT: return "~";
  86                 case UnaryOperator.INCREMENT: return "++";
  87                 case UnaryOperator.DECREMENT: return "--";
  88                 case UnaryOperator.REF: return "ref ";
  89                 case UnaryOperator.OUT: return "out ";
  90                 default: assert_not_reached ();
  91                 }
  92         }
  93
  94         public override string to_string () {
  95                 return get_operator_string () + _inner.to_string ();
  96         }
  97
  98         public override bool is_constant () {
  99                 if (operator == UnaryOperator.INCREMENT || operator == UnaryOperator.DECREMENT) {
 100                         return false;
 101                 }
 102
 103                 if (operator == UnaryOperator.REF || operator == UnaryOperator.OUT) {
 104                         var field = inner.symbol_reference as Field;
 105                         if (field != null && field.binding == MemberBinding.STATIC) {
 106                                 return true;
 107                         } else {
 108                                 return false;
 109                         }
 110                 }
 111
 112                 return inner.is_constant ();
 113         }
 114
 115         public override bool is_pure () {
 116                 if (operator == UnaryOperator.INCREMENT || operator == UnaryOperator.DECREMENT) {
 117                         return false;
 118                 }
 119
 120                 return inner.is_pure ();
 121         }
 122
 123         bool is_numeric_type (DataType type) {
 124                 if (!(type.data_type is Struct)) {
 125                         return false;
 126                 }
 127
 128                 var st = (Struct) type.data_type;
 129                 return st.is_integer_type () || st.is_floating_type ();
 130         }
 131
 132         bool is_integer_type (DataType type) {
 133                 if (!(type.data_type is Struct)) {
 134                         return false;
 135                 }
 136
 137                 var st = (Struct) type.data_type;
 138                 return st.is_integer_type ();
 139         }
 140
 141         MemberAccess? find_member_access (Expression expr) {
 142                 if (expr is MemberAccess) {
 143                         return (MemberAccess) expr;
 144                 }
 145
 146                 return null;
 147         }
 148
 149         public override bool check (CodeContext context) {
 150                 if (checked) {
 151                         return !error;
 152                 }
 153
 154                 checked = true;
 155
 156                 if (operator == UnaryOperator.REF || operator == UnaryOperator.OUT) {
 157                         inner.lvalue = true;
 158                         inner.target_type = target_type;
 159                 }
 160
 161                 if (!inner.check (context)) {
 162                         /* if there was an error in the inner expression, skip type check */
 163                         error = true;
 164                         return false;
 165                 }
 166
 167                 if (inner.value_type is FieldPrototype) {
 168                         error = true;
 169                         Report.error (inner.source_reference, "Access to instance member `%s' denied".printf (inner.symbol_reference.get_full_name ()));
 170                         return false;
 171                 }
 172
 173                 if (operator == UnaryOperator.PLUS || operator == UnaryOperator.MINUS) {
 174                         // integer or floating point type
 175                         if (!is_numeric_type (inner.value_type)) {
 176                                 error = true;
 177                                 Report.error (source_reference, "Operator not supported for `%s'".printf (inner.value_type.to_string ()));
 178                                 return false;
 179                         }
 180
 181                         value_type = inner.value_type;
 182                 } else if (operator == UnaryOperator.LOGICAL_NEGATION) {
 183                         // boolean type
 184                         if (!inner.value_type.compatible (context.analyzer.bool_type)) {
 185                                 error = true;
 186                                 Report.error (source_reference, "Operator not supported for `%s'".printf (inner.value_type.to_string ()));
 187                                 return false;
 188                         }
 189
 190                         value_type = inner.value_type;
 191                 } else if (operator == UnaryOperator.BITWISE_COMPLEMENT) {
 192                         // integer type
 193                         if (!is_integer_type (inner.value_type) && !(inner.value_type is EnumValueType)) {
 194                                 error = true;
 195                                 Report.error (source_reference, "Operator not supported for `%s'".printf (inner.value_type.to_string ()));
 196                                 return false;
 197                         }
 198
 199                         value_type = inner.value_type;
 200                 } else if (operator == UnaryOperator.INCREMENT ||
 201                            operator == UnaryOperator.DECREMENT) {
 202                         // integer type
 203                         if (!is_integer_type (inner.value_type)) {
 204                                 error = true;
 205                                 Report.error (source_reference, "Operator not supported for `%s'".printf (inner.value_type.to_string ()));
 206                                 return false;
 207                         }
 208
 209                         var ma = find_member_access (inner);
 210                         if (ma == null) {
 211                                 error = true;
 212                                 Report.error (source_reference, "Prefix operators not supported for this expression");
 213                                 return false;
 214                         }
 215
 216                         var old_value = new MemberAccess (ma.inner, ma.member_name, inner.source_reference);
 217                         var bin = new BinaryExpression (operator == UnaryOperator.INCREMENT ? BinaryOperator.PLUS : BinaryOperator.MINUS, old_value, new IntegerLiteral ("1"), source_reference);
 218
 219                         var assignment = new Assignment (ma, bin, AssignmentOperator.SIMPLE, source_reference);
 220                         assignment.target_type = target_type;
 221                         context.analyzer.replaced_nodes.add (this);
 222                         parent_node.replace_expression (this, assignment);
 223                         assignment.check (context);
 224                         return true;
 225                 } else if (operator == UnaryOperator.REF || operator == UnaryOperator.OUT) {
 226                         var ea = inner as ElementAccess;
 227                         if (inner.symbol_reference is Field || inner.symbol_reference is Parameter || inner.symbol_reference is LocalVariable ||
 228                             (ea != null && ea.container.value_type is ArrayType)) {
 229                                 // ref and out can only be used with fields, parameters, local variables, and array element access
 230                                 lvalue = true;
 231                                 value_type = inner.value_type;
 232                         } else {
 233                                 error = true;
 234                                 Report.error (source_reference, "ref and out method arguments can only be used with fields, parameters, local variables, and array element access");
 235                                 return false;
 236                         }
 237                 } else {
 238                         error = true;
 239                         Report.error (source_reference, "internal error: unsupported unary operator");
 240                         return false;
 241                 }
 242
 243                 return !error;
 244         }
 245
 246         public override void emit (CodeGenerator codegen) {
 247                 inner.emit (codegen);
 248
 249                 codegen.visit_unary_expression (this);
 250
 251                 codegen.visit_expression (this);
 252         }
 253
 254         public override void get_defined_variables (Collection<LocalVariable> collection) {
 255                 inner.get_defined_variables (collection);
 256                 if (operator == UnaryOperator.OUT || operator == UnaryOperator.REF) {
 257                         var local = inner.symbol_reference as LocalVariable;
 258                         if (local != null) {
 259                                 collection.add (local);
 260                         }
 261                 }
 262         }
 263
 264         public override void get_used_variables (Collection<LocalVariable> collection) {
 265                 if (operator != UnaryOperator.OUT) {
 266                         inner.get_used_variables (collection);
 267                 }
 268         }
 269 }
 270
 271 public enum Vala.UnaryOperator {
 272         NONE,
 273         PLUS,
 274         MINUS,
 275         LOGICAL_NEGATION,
 276         BITWISE_COMPLEMENT,
 277         INCREMENT,
 278         DECREMENT,
 279         REF,
 280         OUT
 281 }